FiveTech Support Forums

FUNCTION CON100()
   LOCAL oItem:=oMOpc, oBtnB:=oBBar, aX[7], cHelp, nClrB
   LOCAL oWChld, oIcon, oDlg, nW, nH, nI, nMes
   aX[1]:=LoadBitMap(GetResources(),"C_Ind")
   aX[2]:=LoadBitMap(GetResources(),"C_Nor")
   aX[3]:=LoadBitMap(GetResources(),"C_Pal")
   aX[4]:=LoadBitMap(GetResources(),"C_Roj")
   aX[5]:=LoadBitMap(GetResources(),"C_Pen")
   aX[6]:=LoadBitMap(GetResources(),"C_Atn")
   aX[7]:=LoadBitMap(GetResources(),"C_PxR")
   nClrB:=LightColor(215,nClrM)
   cHelp:=GetHelpTopic()
   HelpSetTopic("Registro de Pólizas")
   oT:=RC_100():New()
   Inicia()
   oDPol:=Open_Dbf("Polizas")
   (oDPol)->(DbGoBottom())
   nMes:=IF(Month((oDPol)->FecPol)<>0,Month((oDPol)->FecPol),1)
   (oDPol)->(OrdSetFocus(3))
   DEFINE ICON oIcon RESOURCE "IconSys"
   DEFINE WINDOW oWChld MDIChild FROM 1,2 TO 2,2 OF oWnd TITLE "Registro y Consulta de Pólizas" NOZOOM ICON oIcon
   DEFINE DIALOG oDlg RESOURCE "CON100" FONT oWnd:oFont OF oWChld
   REDEFINE BTNBMP ID 101 OF oDlg RESOURCE "B_New" NOBORDER;
      TOOLTIP "Agregar Póliza"    ACTION Sol_Datos(.T.)
   REDEFINE BTNBMP ID 102 OF oDlg RESOURCE "B_Del" NOBORDER;
      TOOLTIP "Borrar"            ACTION Baja_Pol()
   REDEFINE BTNBMP ID 103 OF oDlg RESOURCE "B_Chg" NOBORDER;
      TOOLTIP "Consultar"         ACTION Sol_Datos(.F.)
   REDEFINE BTNBMP ID 104 OF oDlg RESOURCE "B_Cla" NOBORDER;
      TOOLTIP "Clasificar por... (F4)" ACTION Alterna()
   REDEFINE BTNBMP ID 105 OF oDlg RESOURCE "B_Bus" NOBORDER;
      TOOLTIP "Buscar (Ctrl+B)"   ACTION Buscar()
   REDEFINE BTNBMP ID 106 OF oDlg RESOURCE "B_Prt" NOBORDER;
      TOOLTIP "Imprimir póliza (Ctrl+I)"  ACTION Imprimir(.T.,.F.)
   REDEFINE BTNBMP ID 107 OF oDlg RESOURCE "B_Prv" NOBORDER;
      TOOLTIP "Vista preliminar (Ctrl+P)" ACTION Imprimir(.T.,.T.)
   REDEFINE SAY oT:oRef PROMPT oT:cRef ID 110 OF oDlg COLOR CLR_BLUE
   REDEFINE FOLDER oFld ID 100 OF oDlg;
      PROMPT  " &Enero    ", " &Febrero  ", " &Marzo      ", " &Abril    "," &Mayo       ", " &Junio     ",;
              " Ju&lio    ", " A&gosto   ", " &Septiembre ", " &Octubre  " , "&Noviembre ", " &Diciembre " ;
      DIALOGS "CON100_FL", "CON100_FL", "CON100_FL","CON100_FL","CON100_FL","CON100_FL" ,;
              "CON100_FL", "CON100_FL", "CON100_FL","CON100_FL","CON100_FL","CON100_FL"  ;
      ON CHANGE Val_Pant()
   oFld:oFont2:=TFont():New("MS Sans Serif",0,-10,.F.,.T.)

   FOR nI=1 TO 12
      REDEFINE LISTBOX oBrw[nI] ;
         FIELDS Desp_Fld1(), Desp_Fld2(), Desp_Fld3(),                ;
                (oDPol)->ConCor, DesI_Deb(), DesI_Hab(), Desp_Sta(aX) ;
         HEADER "Tipo", "Número", "Fecha", "Concepto", "Debe", "Haber", "S" ;
         SIZES   50, 50, 80,279,100,100, 15 ;
         ALIAS (oDPol)->(Alias()) ID 110 OF oFld:aDialogs[nI]
      oBrw[nI]:lCellStyle  :=.T.
      oBrw[nI]:lAdjLastCol :=.F.
      oBrw[nI]:lDrawFooters:=.T.
      oBrw[nI]:nHeaderHeight:=15
      oBrw[nI]:nFooterHeight:=15
      oBrw[nI]:nClrForeHead:=CLR_BLUE
      oBrw[nI]:aJustify  :={0,2,2,0,1,1,2}
      oBrw[nI]:aFJustify :={2,0,1,0,1,1,2}
      oBrw[nI]:bChange   :={|| Refr_Ref()}
      oBrw[nI]:bLDblClick:={|| Sol_Datos(.F.)}
      oBrw[nI]:bKeyDown  :={|nKey| Val_nKey(nKey)}
      oBrw[nI]:bRClicked :={|nRow,nCol| Pop_Menu(nRow,nCol,oDlg)}
      oBrw[nI]:aFooters  :={|| {"","",Tran(oT:aTot[1],"9999 ")," Póliza(s) ", ;
                                Tran(oT:aTot[2],"9999,999,999.99"),Tran(oT:aTot[3],"9999,999,999.99")}}
      oBrw[nI]:bTextColor:={|nRow,nCol,nStyle| IF(nCol=4 .AND. nStyle=0 .AND. (oDPol)->ConCor="VERIFICAR MOVIMIENTOS",CLR_HRED,)}
      IF DbSetDriver()="DBFCDX"
         oBrw[nI]:nClrPane:={|| IF((oDPol)->(OrdKeyNo())%2==0,nClrB,CLR_LGRAY)}
      ENDIF
   NEXT nI

   nW:=IF(IsWinNT(), 8, 8)   // para tema clasico de Windows
   nH:=IF(IsWinNT(),33,27)
   oWChld:bGotFocus:={|| oBrw[1]:SetFocus() }
   ACTIVATE DIALOG oDlg NOWAIT ;
      ON INIT (oFld:SetOption(nMes),Val_Pant()) VALID (oWChld:End(),.T.)
   ACTIVATE WINDOW oWChld ;
      ON INIT   oDlg:Move(0,0) ;
      ON RESIZE oWChld:SetSize(oDlg:nWidth+nW,oDlg:nHeight+nH,.T.) ;
      VALID     Finaliza(oItem,oBtnB,cHelp,aX)
RETURN (NIL)

STAT FUNC Finaliza(oItem,oBtnB,cHelp,aX)
   AEval(aX,{|x| DeleteObject(x)})
   Close_Dbf("Polizas",oDPol)
   HelpSetTopic(cHelp)
   oItem:Enable()
   oBtnB:Enable()
RETURN (.T.)