FiveTech Support Forums

When my dialog is defined i do this:

oDlg:bCommNotify := { | nComm, nStatus | get_card( nComm, nStatus ) }

And on the ON INIT of the dialog, i have the following:

EnableCommNotification( nComm, oDlg:hWnd, 1, -1 ))

My Get_Card function:

FUNCTION get_card(m_port,stat)
                LOCAL startstr, buffer, sensorstr := ""
	buffer := SPACE(100)
	//turn off comm notification for this function
 	EnableCommNotification( m_port, wbent:hWnd, -1, -1 )
	FlushComm( m_port, 0 )						  
	//wait long enough for port to fill
	
	waitseconds(1)                        //Doesnt matter how long i increase this
	? ReadComm(m_port,@buffer) //Always returns 8

EnableCommNotification( m_port, 0, 1, -1 )

EnableCommNotification( m_port, wbent:hWnd, 1, -1 )

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oDlg

    LOCAL oGet, cTxt := ""

    LOCAL nCom

    DEFINE DIALOG oDlg;
           SIZE 500, 500;
           TITLE "Terminale"

    @ 0, 0 GET oGet VAR cTxt MEMO READONLY

    oGet:bKeyDown = { | nKey | Tasti( nCom, nKey ) }

    ACTIVATE DIALOG oDlg;
             ON INIT ( oGet:AdjClient(),;
                       nCom := APRICOM( oDlg, oGet ),;
                       IF( nCom < 0, oDlg:End(), ) );
             CENTER

    IF nCom >= 0; CLOSECOMM( nCom ); ENDIF

    RETURN NIL


STATIC FUNCTION TASTI( nCom, nKey )

    SENDSTR( nCom, CHR( nKey ) )

    RETURN NIL


STATIC FUNCTION APRICOM( oDlg, oGet )

    LOCAL nCom, cDcb

    BEGIN SEQUENCE
        nCom = OPENCOMM( "COM1", 16384, 16384 )

        IF nCom < 0
            ? "Errore di apertura della porta di comunicazione."
            BREAK
        ENDIF

        BUILDCOMMDCB( "COM1:115200,N,8,1", @cDcb )

        IF !SETCOMMSTATE( nCom, cDcb )
            ? "Errore di impostazione della porta di comunicazione."
            BREAK
        ENDIF

        oDlg:bCommNotify = { | nCom | Connect( nCom, oGet ),;
                                      EnableCommNotification( nCom, oDlg:hWnd, 1, -1 ) }

        IF !ENABLECOMMNOTIFICATION( nCom, oDlg:hWnd, 1, -1 )
            ? "Errore di abilitazione della notifica."
            BREAK
        ENDIF
    RECOVER
        nCom = -1
    END SEQUENCE

    RETURN nCom


STATIC FUNCTION CONNECT( nCom, oGet )

    LOCAL cStr

    ENABLECOMMNOTIFICATION( nCom, 0, 1, -1 )

    cStr = RECEIVESTR( nCom )

    cStr = STRTRAN( cStr, CHR( 13 ), "" )
    cStr = STRTRAN( cStr, CHR( 10 ), CRLF )

    oGet:Append( cStr )

    RETURN NIL


STATIC FUNCTION SENDSTR( nCom, cString )

    LOCAL nBytes := WRITECOMM( nCom, cString )

    RETURN nBytes = LEN( cString )


STATIC FUNCTION RECEIVESTR( nCom )

    LOCAL cBuf := SPACE( 1000 )

    RETURN LEFT( cBuf, READCOMM( nCom, @cBuf ) )

#include "FiveWin.ch"

STATIC oDlg, nComm
STATIC cGet, oGet

function Main()
	cGet := Space(10)
   	SET _3DLOOK ON

   	DEFINE DIALOG oDlg TITLE "Test" 

   	@ 1,    2 SAY "Text..:" OF oDlg
   	@ 1,    6 GET oGet VAR cGet OF oDlg SIZE 60, 10 COLOR "W/G" PICTURE "@K"

   	@ 3,    7 BUTTON "&Ok" OF oDlg SIZE 30, 12 ACTION oDlg:End()
   	@ 3,   16 BUTTON "&Cancel" SIZE 30, 12 OF oDlg ACTION oDlg:End() CANCEL
	
	oDlg:bCommNotify := { | nComm, nStatus | get_card( nComm, nStatus ) }
	
   	ACTIVATE DIALOG oDlg CENTERED ON INIT ;
   	 	(openport(),;
		EnableCommNotification( nComm, oDlg:hWnd, 1, -1 ))
return nil

FUNCTION openport
	LOCAL  cDcb , initok , str_send, mScale, mComPort
	mComPort := "COM1"

	nComm    := OpenComm(mComPort,1024,128)
	IF nComm >= 0  
		str_send :=	mComPort+":9600,E,7,1"
		initok := BuildCommDcb(str_send , @cDcb )
		SetCommState( nComm, cDcb )
		EscapeCommFunction( nComm, "SETRTS")
		FlushComm( nComm, 0 )
	ELSE
		? "Port not functioning "
	ENDIF
RETURN NIL

FUNCTION get_card(m_port,stat)
	LOCAL startstr, buffer, sensorstr := ""
 	EnableCommNotification( m_port, oDlg:hWnd, 0, -1 )
	FlushComm( m_port, 0 )						  
	waitseconds(2)

	? ReadComm(m_port,@buffer)	
	EnableCommNotification( nComm, oDlg:hWnd, 1, -1 )
RETURN .T.

STATIC oDlg, nComm
STATIC cGet, oGet

function Main()
	cGet := Space(10)
   	SET _3DLOOK ON

   	DEFINE DIALOG oDlg TITLE "Test" 

   	@ 1,    2 SAY "Text..:" OF oDlg
   	@ 1,    6 GET oGet VAR cGet OF oDlg SIZE 60, 10 COLOR "W/G" PICTURE "@K"

   	@ 3,    7 BUTTON "&Ok" OF oDlg SIZE 30, 12 ACTION oDlg:End()
   	@ 3,   16 BUTTON "&Cancel" SIZE 30, 12 OF oDlg ACTION oDlg:End() CANCEL
	
	oDlg:bCommNotify := { | nComm, nStatus | get_card( nComm, nStatus ) }
	
   	ACTIVATE DIALOG oDlg CENTERED ON INIT ;
   	 	(openport(),;
		EnableCommNotification( nComm, oDlg:hWnd, 1, -1 ))
return nil

FUNCTION openport
	LOCAL  cDcb , initok , str_send, mScale, mComPort
	mComPort := "COM1"

	nComm    := OpenComm(mComPort,1024,128)
	IF nComm >= 0  
		str_send :=	mComPort+":9600,E,7,1"
		initok := BuildCommDcb(str_send , @cDcb )
		SetCommState( nComm, cDcb )
		EscapeCommFunction( nComm, "SETRTS")
		FlushComm( nComm, 0 )
	ELSE
		? "Port not functioning "
	ENDIF
RETURN NIL

FUNCTION get_card(m_port,stat)
	LOCAL startstr, buffer, sensorstr := ""
 	EnableCommNotification( m_port, 0, 1, -1 )
	FlushComm( m_port, 0 )						  
	waitseconds(2)

	//? ReadComm(m_port,@buffer)	
	
	Buffer := RECEIVESTR( m_port )
	? Buffer
	EnableCommNotification( nComm, oDlg:hWnd, 1, -1 )
RETURN .T.

STATIC FUNCTION RECEIVESTR( nCom )

    LOCAL cBuf := SPACE( 1000 )

RETURN LEFT( cBuf, READCOMM( nCom, @cBuf ) )