topic-14665

dobfivewin

Posts: 325

Joined: Sun Feb 03, 2008 11:04 PM

Tamaño de Imagen según la Resolucion
Posted: Sat Feb 21, 2009 09:22 AM

Estimados

Es posible que se ajuste una imagen de fondo colocado en DEFINE BRUSH, seg'un la Resolucion de la pantalla?

Ya que me cambia la forma de visializarce según la resolucion de la misma

Gracias

david
argentina

jrestojeda

Posts: 601

Joined: Wed Jul 04, 2007 03:51 PM

Re: Tamaño de Imagen según la Resolucion
Posted: Sat Feb 21, 2009 10:18 PM

Hola amigo...
Yo lo solucioné de la siguiente manera.

Code (fw): Select all Collapse

DEFINE BRUSH oBrush1 RESOURCE "FONDO1" // Imagen para  800 x 600
DEFINE BRUSH oBrush2 RESOURCE "FONDO2" // Imagen para 1024 x 768

ResH:=oWnd:nHorzRes()
ResV:=oWnd:nVertRes()

IF ResH=800 .AND. ResV=600
   SET BRUSH OF oWnd TO oBrush1
ENDIF
IF ResH=1024 .AND. ResV=768
   SET BRUSH OF oWnd TO oBrush2
ENDIF

No es precisamente la respuesta a lo que preguntas pero soluciona el problema.
Espero te sirva.
Saludos desde Argentina, Esteban.

Ojeda Esteban Eduardo.

Buenos Aires - Argentina.

FWH - PellesC - DBF/CDX - ADS - Gloriosos .Bat - MySql - C# .net - FastReport

Skype: jreduojeda

dobfivewin

Posts: 325

Joined: Sun Feb 03, 2008 11:04 PM

Re: Tamaño de Imagen según la Resolucion
Posted: Sun Feb 22, 2009 12:40 PM

Amigo....

buen opcion

muchas gracias

david

Daniel Garcia-Gil

Posts: 2365

Joined: Wed Nov 02, 2005 11:46 PM

Re: Tamaño de Imagen según la Resolucion
Posted: Sun Feb 22, 2009 04:02 PM

Hola dobfivewin

te pregunto, necesitas hacerlo con Brush necesiariamente?

tienes esta forma de hacerlo tambien, aqui tienes un ejemplo...

Code (fw): Select all Collapse

#include "fivewin.ch"

#define SM_CXSCREEN       0
#define SM_CYSCREEN       1

function main()

   local oWnd1, oWnd2

   DEFINE WINDOW oWnd1 TITLE "oWnd1" ;
      FROM 5, 5 TO 24, 64

   ACTIVATE WINDOW oWnd1 on paint( AdjustImg( oWnd1, "MI_IMAGEN_AQUI.bmp" ) ) //<===== AQUI COLOCAS TU RECURSO O BMP FILE

return nil

Function AdjustImg( oWnd, cBmp )
local nWdt := GetSysMetrics(SM_CXSCREEN)
local nHt  := GetSysMetrics(SM_CYSCREEN)
local hBmp

   if valtype( cBmp ) == "C"
      if '.' $ cBmp
         if upper( right( cBmp, 3 ) ) == "BMP"
            if file( cBmp )
               hBmp := ReadBitmap( 0, cBmp )
            else
               msgstop( "File " + cBmp + " not Found" )
               return nil
            endif
         else
            msgstop( "Bad BMP File format" )
            return nil
         endif
      else
         if ( hBmp := LoadBitmap( GetResources(), cBmp ) ) == 0
            msgstop( "Resource " + cBmp + " No Found" )
            return nil
         endif
      endif
   else
      msgstop( "Only BMP File or Resource" )
      return nil
   endif

   PalBmpDraw( oWnd:hDC, 0, 0,  hBmp,, oWnd:nWidth, oWnd:nHeight )
   DeleteObject( hBmp )

return nil

our best documentation is the source code
Isla de Margarita Venezuela.
danielgarciagil@gmail.com
http://tdolphin.blogspot.com/
https://www.dropbox.com/referrals/NTI5Njk4MDc1OQ?src=global9

FiveTech Support Forums

Continue the discussion