FiveTech Support Forums

*****************************************************************************************
#xcommand @ <nRow>, <nCol> FWDCHECKBOX [ <oCbx> VAR ] <lVar> ;
              [ PROMPT <cCaption> ] ;
              [ <of:OF, WINDOW, DIALOG> <oWnd> ] ;
              [ SIZE <nWidth>, <nHeight> ] ;
              [ <help:HELPID, HELP ID> <nHelpId> ] ;
              [ FONT <oFont> ] ;
              [ <change: ON CLICK, ON CHANGE> <uClick> ] ;
              [ VALID   <ValidFunc> ] ;
              [ <color: COLOR, COLORS> <nClrFore> [,<nClrBack>] ] ;
              [ <design: DESIGN> ] ;
              [ <pixel: PIXEL> ] ;
              [ MESSAGE <cMsg> ] ;
              [ <update: UPDATE> ] ;
              [ WHEN <WhenFunc> ] ;
              [<left: LEFT>] ;
              [<button: LIKEBUTTON>] ;
        => ;
          [ <oCbx> := ] TFWDCheckBox():New( <nRow>, <nCol>, <cCaption>,;
              [bSETGET(<lVar>)], <oWnd>, <nWidth>, <nHeight>, <nHelpId>,;
              [<{uClick}>], <oFont>, <{ValidFunc}>, <nClrFore>, <nClrBack>,;
              <.design.>, <.pixel.>, <cMsg>, <.update.>, <{WhenFunc}>, <.left.>, <.button.> )

*****************************************************************************************
@ 128.50,9.00 FWDCHECKBOX oFWDCk VAR uFWDCk PROMPT "Tots els fitxers" OF ;
    oindex00 SIZE 123.00,12.00 FONT J02FONTSAY ON CHANGE FWDCkChange(AMPAarra, ;
    oFWDCk, oLbIndex) COLORS J02CLRTEXTO,J02CLRWND PIXEL UPDATE LIKEBUTTON //FIVEWIDI

*****************************************************************************************

/* Left/Button CheckBox
   -------------*/
#include "FiveWin.ch"

#define BS_LEFTTEXT      32
#define BS_PUSHLIKE    4096

#ifndef __XPP__
   #define BM_SETCHECK   ( WM_USER + 1 )
#else
   #define BM_SETCHECK   241
#endif

#define CB_RESETCONTENT   ( WM_USER + 11 )

#ifdef __XPP__
   //#define Super ::TControl
   #define Super ::TCheckBox
   #define New   _New
#endif

//----------------------------------------------------------------------------//

CLASS TFWDCheckBox FROM TCheckBox

   CLASSDATA lRegistered AS LOGICAL

   METHOD New( nRow, nCol, cCaption, bSetGet, oWnd, nWidth, nHeight,;
               nHelpTopic, bChange, oFont, bValid, nClrFore, nClrBack,;
               lDesign, lPixel, cMsg, lUpdate, bWhen, lLeft, lButton ) CONSTRUCTOR

ENDCLASS

//----------------------------------------------------------------------------//

METHOD New( nRow, nCol, cCaption, bSetGet, oWnd, nWidth, nHeight, nHelpTopic,;
            bChange, oFont, bValid, nClrFore, nClrBack, lDesign, lPixel,;
            cMsg, lUpdate, bWhen, lLeft, lButton ) CLASS TFWDCheckBox

#ifdef __XPP__
   #undef New
#endif

   local lTemp := .f.

   DEFAULT nRow       := 0, nCol := 0,;
           cCaption   := "&CheckBox",;
           oWnd       := GetWndDefault(),;
           oFont      := If( oWnd:oFont != nil, oWnd:oFont, TFont():New( "System", 8, 9 )),;
           nWidth     := Len( cCaption ) * oFont:nWidth,;
           nHeight    := oFont:nHeight + Int( oFont:nHeight / 2 ),;
           nHelpTopic := 100,;
           nClrFore   := oWnd:nClrText, nClrBack := oWnd:nClrPane,;
           lPixel     := .f., lDesign := .f., lUpdate := .f.,;
           bSetGet    := bSETGET( lTemp ),;
           lLeft      := .F.,;
           lButton    := .F.

   if ValType( Eval( bSetGet ) ) != "L"
      Eval( bSetGet, .f. )
   endif

   ::nTop       = nRow * If( lPixel, 1,;
                             ( oFont:nHeight + Int( oFont:nHeight / 2 ) ) )
   ::nLeft      = nCol * If( lPixel, 1, oFont:nWidth ) + If( lPixel, 0, 3 )
   ::nBottom    = ::nTop + nHeight
   ::nRight     = ::nLeft + nWidth - If( lPixel, 0, 24 )
   ::cCaption   = cCaption
   ::nStyle     = nOR( WS_CHILD, WS_VISIBLE, BS_AUTOCHECKBOX,;
                       WS_TABSTOP,;
                       If( lDesign, WS_CLIPSIBLINGS, 0 ), ;
                       If( lLeft, BS_LEFTTEXT, If( lButton, BS_PUSHLIKE, 0) ) )
   ::nId        = ::GetNewId()
   ::nHelpId    = nHelpTopic
   ::bSetGet    = bSetGet
   ::bChange    = bChange
   ::oWnd       = oWnd
   ::oFont      = oFont
   ::bValid     = bValid
   ::lDrag      = lDesign
   ::lCaptured  = .f.
   ::cMsg       = cMsg
   ::lUpdate    = lUpdate
   ::bWhen      = bWhen

   ::SetColor( nClrFore, nClrBack )

   if ValType( Eval( bSetGet ) ) != "L"
      Eval( bSetGet, .f. )
   endif

   if ! Empty( oWnd:hWnd )
      ::Create( "BUTTON" )
      ::Default()
      oWnd:AddControl( Self )
   else
      oWnd:DefControl( Self )
   endif

   if lDesign
      ::CheckDots()
   endif

return Self

//----------------------------------------------------------------------------//