FiveTech Support Forums

   try
      cSql := "bla bbla bla"

    catch oError
        ::oConnection:RollBackTrans()
        MsgInfo ("ERROR. Se ha realizado ROLLBACK." )
        if Empty( ::oConnection:oError:aErrors ) // No son errores de ADO, errores Harbour
           MsgStop( oError:Operation + CRLF + oError:Description, "" )
        else
           MsgStop( "Falla: "+ CRLF +  cSql )
        endif
        ::oConnection:oError:ShowErrors()    // Muestra el error que nos dá el SQL

    end

/*
 * Proyecto: adolib
 * Fichero: adoConn.prg
 * Descripción: Objeto Conexión de ADO
 * Autor: José Luis Capel - <!-- m --><a class="postlink" href="http://www.capelblog.com">http://www.capelblog.com</a><!-- m -->
 * Fecha: 13/11/2005
 * CopyRight: José Luis Capel - 2005 Todos los derechos reservados al autor
 * Adaptaciones menores por Rafa Carmona
 */

#define CRLF chr(13)+chr(10)
#xcommand DEFAULT <x1> TO <v1> [, <xn> TO <vn> ] => ;
          IF <x1> == Nil ; <x1> := <v1> ; ENDIF     ;
          [; IF <xn> == Nil ; <xn> := <vn> ; ENDIF ]

#include "hbclass.ch"
#include "ado.ch"


CLASS tAdoConn

      DATA aObjects     AS ARRAY  INIT {}  //Diferentes Objectos creados con tAdoConn
      DATA oConnection  AS OBJECT
      DATA oError

      // ----------------------------------> Para la conexión
      DATA cConnectionString  AS CHARACTER
      DATA cUserId            AS CHARACTER
      DATA cPassword          AS CHARACTER
      // ----------------------------------> Para la conexión

      METHOD New()

      METHOD Open( cConnString, cUserId, cPassword, nOptions )
      METHOD Close()
      METHOD Execute( cCommand, nRecords, nOptions )
      METHOD RollBackTrans()
      METHOD CommitTrans()
      METHOD BeginTrans()

ENDCLASS


METHOD New() CLASS tAdoConn

       LOCAL oError
       LOCAL lResult

       ::oError := TAdoError():New()

       lResult := .T.

       TRY
          ::oConnection := CreateObject("ADODB.Connection")
       CATCH oError
          lResult := .F.
          MsgStop( oError:Operation, "Ado Connection" )
       END

       // ------------------------> Valores por defecto!!
       IF lResult
          ::oConnection:CommandTimeOut       := 5
          ::oConnection:ConnectionTimeOut    := 10
          ::oConnection:CursorLocation       := adUseClient
       ENDIF
       // ------------------------> Valores por defecto!!


RETURN Self


METHOD Open ( cConnString, cUserId, cPassword, nOptions ) CLASS tAdoConn

       LOCAL oError
       LOCAL lResult

       DEFAULT cUserId   TO NIL
       DEFAULT cPassword TO NIL
       DEFAULT nOptions  TO NIL

       lResult := .T.

       TRY
         ::oConnection:Open( cConnString, cUserId, cPassword, nOptions)
       CATCH oError
          lResult := .F.
          MsgStop( oError:Operation+CRLF+oError:Description,"Ado Connection")
          ::oError:Connection( ::oConnection )
          ::oError:ShowErrors()
       END

RETURN lResult

METHOD BeginTrans() CLASS tAdoConn
   LOCAL oError
   LOCAL lResult

   lResult := .T.

   TRY
     ::oConnection:BeginTrans()
   CATCH oError
      lResult := .F.
      MsgStop(oError:Operation+CRLF+oError:Description,"Ado Connection")
      ::oError:Connection( ::oConnection )
      ::oError:ShowErrors()
   END

RETURN lResult

METHOD CommitTrans() CLASS tAdoConn
   LOCAL oError
   LOCAL lResult

   lResult := .T.

   TRY
     ::oConnection:CommitTrans()
   CATCH oError
      lResult := .F.
      MsgStop(oError:Operation+CRLF+oError:Description,"Ado Connection")
      ::oError:Connection( ::oConnection )
      ::oError:ShowErrors()
   END

RETURN lResult

METHOD RollBackTrans() CLASS tAdoConn
   LOCAL oError
   LOCAL lResult

   lResult := .T.

   TRY
     ::oConnection:RollBackTrans()
   CATCH oError
      lResult := .F.
      MsgStop(oError:Operation+CRLF+oError:Description,"Ado Connection")
      ::oError:Connection( ::oConnection )
      ::oError:ShowErrors()
   END

RETURN lResult



METHOD Close() CLASS tAdoConn

       LOCAL oError
       LOCAL lResult

       lResult := .T.

       TRY
          ::oConnection:Close()
       CATCH oError
          lResult := .F.
          MsgStop(oError:Operation+CRLF+oError:Description,"Ado Connection")
          ::oError:Connection( ::oConnection )
          ::oError:ShowErrors()
       END

RETURN lResult


METHOD Execute( cCommand, nRecords, nOptions ) CLASS tAdoConn
       LOCAL oError, cError, oErr
       LOCAL lResult

       DEFAULT nRecords  TO 0
       DEFAULT nOptions  TO NIL

       lResult := .T.

       TRY
         ::oConnection:Execute( cCommand, @nRecords, nOptions)
       CATCH oErr
          ::oError:Connection( ::oConnection )
          lResult := .F.
          Throw( oErr )
       END

RETURN lResult


CLASS TAdoError
      DATA aErrors
      DATA oErrorDB
      METHOD New()
      METHOD Clean() INLINE ::aErrors := {}
      METHOD Connection( oConnection )
      METHOD ShowErrors()
END CLASS

METHOD New( lCreateError ) CLASS TAdoError

   ::aErrors := {}
   /* TODO: Pendiente de I+D
   if lCreateError
      ::oErrorDB := CreateObject( "ADODB.Error")
   endif
   */
RETURN Self

METHOD Connection( oConnection ) CLASS TAdoError

    Local oError, cError := ""

    ::Clean()

    For Each oError In oConnection:Errors
        cError := "Error #" + cValtoChar( oError:Number ) + CRLF +;
                  "   "  + oError:Description + CRLF +;
                  "   (Source: " + oError:Source + ")" + CRLF +;
                  "   (SQL State: " + oError:SQLState + ")" + CRLF +;
                  "   (NativeError: " + cValToChar( oError:NativeError ) + ")"
        AADD( ::aErrors, cError )
    Next

RETURN NIL

METHOD ShowErrors( ) CLASS TAdoError
    Local cError := ""

    For Each cError In ::aErrors
        MsgStop( cError )
    next

RETURN NIL


//---------------------------------------------------------------------
//---------------------------------------------------------------------
CLASS tAdoCommand
    DATA oCmd          //Objeto ADO Command
    DATA oParameters
    DATA oError
    DATA oConnection

    METHOD New( oConnection ) CONSTRUCTOR
    METHOD Type( nType ) INLINE ::oCmd:CommandType := nType
    METHOD Text( cText ) INLINE ::oCmd:CommandText := cText
    METHOD GetADOCommand()  INLINE ::oCmd
END CLASS

METHOD New( oConnection ) CLASS tAdoCommand

       LOCAL oHErr

       ::oError := TAdoError():New()
       ::oConnection := oConnection
       TRY
          ::oCmd := CreateObject("ADODB.Command")
       CATCH oHErr
          MsgStop( "ERROR EN tAdoCommand")
          ::oError:Connection( ::oConnection:oConnection )
          Throw( oHErr )
       END

       ::oCmd:ActiveConnection := ::oConnection:oConnection

RETURN Self

//---------------------------------------------------------------------
//---------------------------------------------------------------------
CLASS TAdoStoreProc FROM TAdoCommand
      METHOD New( cText, oConnection ) CONSTRUCTOR
      METHOD Execute()
END CLASS

METHOD New( cText, oConnection ) CLASS tAdoStoreProc
  Local oHErr

  try
    Super:New( oConnection )
    ::Type( adCmdStoredProc )
    ::Text( cText )
    ::oCmd:Parameters:Refresh()
  catch oHErr
    MsgStop( "ERROR EN tAdoStoreProc")
    ::oError:Connection( ::oConnection:oConnection )
    Throw( oHErr )
   end

RETURN Self

METHOD Execute( ) CLASS tAdoStoreProc
       LOCAL oError, cError, oErr
       LOCAL lResult

       lResult := .T.

       TRY
         ::oCmd:Execute()
       CATCH oErr
          MsgStop( "ERROR EN tAdoCommand EXECUTE")
          ::oError:Connection( ::oConnection:oConnection )
          lResult := .F.
          Throw( oErr )
       END

RETURN lResult

  TRY

     ::oRS := ::oConn:Execute( cCommand, @nRecAff, nOptions)

   CATCH oError

     lResult := .F.

     FOR EACH oError IN ::oConn:Errors
         ::cError := TAdoError( oError, ::lMessage )
     NEXT

  END

*-------------------------------------
FUNCTION TAdoError( oError, lMessage )
*-------------------------------------
    LOCAL cError := .T.

    DEFAULT lMessage := .T.

*        MsgStop( 'Error: ' + oError:description + ' => ' + CRLF + ;
*                             oError:operation, 'Sistema'  )

    cError := "Descripci¾n  "  + Chr( VK_TAB) + ": "  + oError:Description + CRLF + CRLF +  ;
              "Error Nativo  " + Chr( VK_TAB) + ": "  + Ltrim(Str(oError:NativeError)) + CRLF + ;
              "N·mero Error  " + Chr( VK_TAB) + ": "  + Ltrim(Str(oError:Number))      + CRLF + ;
              "Origen        " + Chr( VK_TAB) + ": "  + oError:Source + CRLF + ;
              "Estado SQL  "   + Chr( VK_TAB) + ": "  + oError:SQLState

    IF lMessage
       MsgStop( cError, 'Ado Connection' )
    ENDIF

RETU cError