topic-16328

Board index FiveWin for Harbour/xHarbour TXbrowse() display problem?

Posts: 1598

Joined: Fri Oct 07, 2005 05:56 PM

TXbrowse() display problem?
Posted: Sun Aug 09, 2009 05:49 AM

Dear All,

I've got the problem with TXBrowse(), the ::bBmpData has display incorrectly.
When I use this data and focus the Bitmap will not display.
oBrw:nMarqueeStyle := MARQSTYLE_HIGHLROW

Code (fw): Select all Collapse

     REDEFINE XBROWSE oBrw FIELDS str(SPR->PAR_NO,2) , ;
                                  SPR->PAR_DESC, ;
                                  SPR->PAR_VAR, ;
                                  '' ;
            FONT oFnt ;
            FIELDSIZES 30,300,100,50 ;
            HEADERS 'No.', 'Description', 'Variable', 'Status' ;
            ID 101 ;
            OF oDlg ;
            ALIAS 'SPR' ;
            ON DBLCLICK ( ChngStatus(oBrw) )

//   oBrw:nMarqueeStyle      := MARQSTYLE_HIGHLROW
   oBrw:nRowDividerStyle   := LINESTYLE_LIGHTGRAY
   oBrw:nColDividerStyle   := LINESTYLE_LIGHTGRAY
   oBrw:nHeaderHeight      := 25
   oBrw:nRowHeight         := 22
   oBrw:lHScroll           := .F.
   oBrw:nStretchCol        := STRETCHCOL_LAST
   oBrw:lAllowRowSizing    := .F.
   oBrw:lColDividerComplete:= .T.

   oBrw:aCols[4]:AddResource("RIGHT")
   oBrw:aCols[4]:bBmpData   := { || iif(SPR->PAR_STATUS, 1, 0) }
   oBrw:aCols[4]:nDataBmpAlign := AL_CENTER

I think it has effected from 9.07 (not sure)

Regards,
Dutch

Regards,

Dutch

FWH 2304 / xHarbour Simplex 1.2.3 / BCC73 / Pelles C / UEStudio

FWPPC 10.02 / Harbour for PPC (FTDN)

ADS V.9 / MySql / MariaDB

R&R 12 Infinity / Crystal Report XI R2

(Thailand)

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: TXbrowse() display problem?
Posted: Sun Aug 09, 2009 07:02 AM

>>
I think it has effected from 9.07 (not sure)
>>
Your observation is correct. Hope a fix will be published quickly.

Regards

G. N. Rao.

Hyderabad, India

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: TXbrowse() display problem?
Posted: Sun Aug 09, 2009 07:33 AM

I suggest a temporary quick fix to your problem, by replacing the new 9.07 code with the old 9.06 code.

Instead of the present code from lines 8120 to 8126 in xbrowse.prg

Code (fw): Select all Collapse

         else
            nOldColor := SetBkColor( hDC, nRGB( 255, 255, 255 ) )
            TransBmp( aBitmap[ BITMAP_HANDLE ], aBitmap[ BITMAP_WIDTH ], aBitmap[ BITMAP_HEIGHT ],;
                     aBitmap[ BITMAP_ZEROCLR ], hDC, nBmpCol, nBmpRow, aBitmap[ BITMAP_WIDTH ], ;
                     aBitmap[ BITMAP_HEIGHT ] )
            SetBkColor( hDC, nOldColor )
         endif

Please substitute

Code (fw): Select all Collapse

         else
            if ::oBrw:lTransparent // transparent bitmaps with brush
                nOldColor := SetBkColor( hDC, nRGB( 255, 255, 255 ) )

                TransBmp( aBitmap[ BITMAP_HANDLE ], aBitmap[ BITMAP_WIDTH ], aBitmap[ BITMAP_HEIGHT ],;
                         aBitmap[ BITMAP_ZEROCLR ], hDC, nBmpCol, nBmpRow, aBitmap[ BITMAP_WIDTH ], ;
                         aBitmap[ BITMAP_HEIGHT ] )

                SetBkColor( hDC, nOldColor )
             else
                PalBmpDraw( hDC, nBmpRow, nBmpCol,;
                           aBitmap[ BITMAP_HANDLE ],;
                           aBitmap[ BITMAP_PALETTE ],;
                           aBitmap[ BITMAP_WIDTH ],;
                           aBitmap[ BITMAP_HEIGHT ];
                           ,, ::lBmpTransparent, aColors[ 2 ] )

            endif
         endif

It should work for you now.

Regards

G. N. Rao.

Hyderabad, India

Antonio Linares

Posts: 44158

Joined: Thu Oct 06, 2005 05:47 PM

Re: TXbrowse() display problem?
Posted: Sun Aug 09, 2009 10:48 AM

Dutch,

We are going to provide a fix for it asap :-)

regards, saludos

Antonio Linares
www.fivetechsoft.com

dutch

Posts: 1598

Joined: Fri Oct 07, 2005 05:56 PM

Re: TXbrowse() display problem?
Posted: Mon Aug 10, 2009 04:08 AM

Dear Rao&Antonioi,

Thanks all,

Rao : It's work fine now.

Regards,
Dutch

Regards,

Dutch

FWH 2304 / xHarbour Simplex 1.2.3 / BCC73 / Pelles C / UEStudio

FWPPC 10.02 / Harbour for PPC (FTDN)

ADS V.9 / MySql / MariaDB

R&R 12 Infinity / Crystal Report XI R2

(Thailand)

FiveTech Support Forums

Continue the discussion