Un Pequeño Aporte: Font en redefine Folder 8.09

Posts: 57

Joined: Tue Nov 04, 2008 02:08 PM

Un Pequeño Aporte: Font en redefine Folder 8.09
Posted: Wed Sep 02, 2009 08:53 PM

Un pequeño aporte para FWH 8.09, Se trata de el Font en Redefine de la Class TFolder, Espero les sirva, y si aún no existe en las versiones posteriores, espero que lo añadan.

Primero en Class TFolder

Code (fw): Select all Collapse

CLASS TFolder FROM TControl

   CLASSDATA lRegistered AS LOGICAL

   DATA   aPrompts, aDialogs
   DATA   nOption, nTabSize, nFdHeight
   DATA   oFont2
   DATA   aEnable
   DATA   lAllWidth AS LOGICAL INIT .t.
   DATA   lWin95Look AS LOGICAL
   DATA   oImageList

   CLASSDATA aProperties ;
      INIT { "aPrompts", "cVarName", "nClrText",;
             "nClrPane", "nAlign", "nTop", "nLeft",;
             "nWidth", "nHeight", "nOption", "Cargo" }

   METHOD New( nTop, nLeft, aPrompts, aDialogs, oWnd, nOption, nClrFore,;
               nClrBack, lPixel, lDesign, nWidth, nHeight,;
               cMsg, lAllWidth, oFont ) CONSTRUCTOR

   METHOD ReDefine( nId, aPrompts, aDialogs, oWnd, nOption, nClrFore,;
                    nClrBack, bChange, lAllWidth,oFont ) CONSTRUCTOR

En Method ReDefine, el último parámetro es <oFont>.

Luego en METHOD ReDefine

Code (fw): Select all Collapse

METHOD ReDefine( nId, aPrompts, aDialogs, oWnd, nOption, ;
                 nClrFore, nClrBack, bChange, lAllWidth,oFont ) CLASS TFolder

   ::oFont2     = ::SetFont( oFont ) //TFont():New( GetSysFont(), 0, -9,, .t. ) ->Aquí hay un cambio
   ::bChange    = bChange
   ::nClrPane   = GetSysColor( COLOR_BTNFACE )
   ::lAllWidth  = lAllWidth
   ::nFdHeight  = If( LargeFonts(), 25 , 22 )
   ::lWin95Look = GetVersion()[ 1 ] > 3 .or. GetVersion()[ 2 ] > 51 .or. ;
                  IsWinNT()

   ::Register()
*Código Nuevo
   if oFont != nil
      ::SetFont( oFont )
   elseif oWnd != nil .and. oWnd:oFont != nil
      ::SetFont( oWnd:oFont )
   else
      ::GetFont()
   endif
* Fin Código Nuevo

Quiero hacer facturación electrónica...

Leon Valenzuela.

Santiago - Chile.

Leon Valenzuela

Posts: 57

Joined: Tue Nov 04, 2008 02:08 PM

Re: Un Pequeño Aporte: Font en redefine Folder 8.09
Posted: Wed Sep 02, 2009 09:13 PM

Luego, para evitar porblemas nos vamos al Method Destroy()

Code (fw): Select all Collapse

METHOD Destroy() CLASS TFolder

   local n

* Código Nuevo
   IF ::oFont2 != Nil
       ::oFont2:End()
   ENDIF
* Fin Código Nuevo

   if ::oFont != nil
      ::oFont:End()
   endif

   for n = 1 to Len( ::aDialogs )
      ::aDialogs[ n ]:bValid = { || .t. }
      ::aDialogs[ n ]:End()
   next

return Super:Destroy()

Luego en la Cabecera Folder.Ch Hacer la siguiente modificación

Code (fw): Select all Collapse

#xcommand REDEFINE FOLDER [<oFolder>] ;
             [ ID <nId> ] ;
             [ <of: OF, WINDOW, DIALOG> <oWnd> ] ;
             [ <prm: PROMPT, PROMPTS, ITEMS> <cPrompt,...> ] ;
             [ <dlg: DIALOG, DIALOGS, PAGE, PAGES> <cDlgName1> [,<cDlgNameN>] ] ;
             [ <color: COLOR, COLORS> <nClrFore> [,<nClrBack>] ] ;
             [ OPTION <nOption> ] ;
             [ ON CHANGE <uChange> ] ;
             [ <lAdjust: ADJUST> ] ;
         [ FONT <oFont> ];
       => ;
          [<oFolder> := ] TFolder():ReDefine( <nId>, [\{<cPrompt>\}],;
             \{ <cDlgName1> [,<cDlgNameN>] \}, <oWnd>,;
             <nOption>, <nClrFore>, <nClrBack>,;
             [{|nOption,nOldOption| <uChange>}], <.lAdjust.>,<oFont> )

Y eso es todo, una vez compiladas las modificaciones en la lib, podremos definir Fonts para la Folder y los diálogos contenidos en la folder con el método ReDefine. Espero sea de utilidad mi aporte.

Quiero hacer facturación electrónica...

Leon Valenzuela.

Santiago - Chile.

FiveTech Support Forums

Continue the discussion