FiveTech Support Forums

#include "FiveWin.ch"
#include "Splitter.ch"

static oWnd
static oLbx1, oLbx2, oHSplit1
#define COLOR_BTNFACE   15

FUNCTION Main()
LOCAL cTitle := "Testing Splitter on Dialog in Child-Window"

DEFINE WINDOW oWnd FROM 50, 50 TO 650, 700 PIXEL ;
TITLE cTitle MDI

SET MESSAGE OF oWnd TO cTitle KEYBOARD CLOCK DATE NOINSET
  
ACTIVATE WINDOW  oWnd  ;
ON INIT BuildChild() ;

RETURN NIL

// ---------- Container for the Dialog ----------

FUNCTION BuildChild()
LOCAL oChild
   
DEFINE WINDOW oChild TITLE "A Child Window / Dialog" MDICHILD  MENU TMenu():New() ;
      COLOR 0, GetSysColor( COLOR_BTNFACE )
      
ACTIVATE WINDOW oChild ;
      ON INIT Dialog( oChild )
   
RETURN NIL

// ------- Dialog embedded inside the Child-Window -----------------------------

FUNCTION Dialog(oChild)
LOCAL oDlg

DEFINE DIALOG oDlg FROM 80, 50 TO 600, 500 TITLE "A Dialog Box"  PIXEL OF oWnd

SELECT 1
USE EJEMPLO1.DBF

@ 10,15 LISTBOX oLbx1 FIELDS SIZE 115,150 PIXEL OF oDlg

SELECT 2
USE EJEMPLO2.DBF

@ 160,15 LISTBOX oLbx2 FIELDS SIZE 115,150 PIXEL OF oDlg

@ 155,15 SPLITTER oHSplit1 ;
            HORIZONTAL ;
            PREVIOUS CONTROLS oLbx1 ;
            HINDS CONTROLS oLbx2 ;
            TOP MARGIN 20 ;
            BOTTOM MARGIN 20 ;
            SIZE 450, 4 PIXEL ;
            OF oDlg ;
            _3DLOOK ;
            UPDATE

ACTIVATE DIALOG oDlg ;
NOWAIT ;
ON INIT ChangeParent( oDlg, oChild )
      
oDlg:End()   
oChild:bResized = { || oLbx1:SetSize( oChild:nWidth, oChild:nHeight / 2 + 40 ),;
                                    oLbx2:SetSize( oChild:nWidth, oChild:nHeight / 2 ) }
oChild:SetSize( 600, 500 ) //  Dialog-Size

RETURN NIL

// -----------------------------------

FUNCTION ChangeParent( oDlg, oChild )
LOCAL n
   
FOR n = 1 to Len( oDlg:aControls )
      SetParent( oDlg:aControls[ n ]:hWnd, oChild:hWnd )
      AAdd( oChild:aControls, oDlg:aControls[ n ] )
      oDlg:aControls[ n ]:oWnd = oChild
NEXT
   
RETURN NIL