FiveTech Support Forums

STATIC cStrSql1  := "SELECT nombre, apellidos FROM tabla1"
STATIC cStrSql2  := "SELECT parcela, edad FROM tabla2"

function Main()

REDEFINE XBROWSE oXbr ;
   RECSET oRs ID ID_BRW OF oDlg

// Ver tabla1
REDEFINE BTNBMP oBtn1 ID ID_BTN1 OF oDlg ;
   RESOURCE "BTN1" ;
   ACTION ( oRs:Close(),;
            oRs:Source := cStrSql1,;
            oRs:Open(),;
            oXbr:Refresh() )

// Ver tabla2
REDEFINE BTNBMP oBtn2 ID ID_BTN2 OF oDlg ;
   RESOURCE "BTN2" ;
   ACTION ( oRs:Close(),;
            oRs:Source := cStrSql2,;
            oRs:Open(),;
            oXbr:Refresh() )

#include 'fivewin.ch'
#include 'xbrowse.ch'

static nSelect := 1

function Main()

   local oDlg, oBrw1, oBrw2, oRs1, oRs2, oCn

   XBrNumFormat( 'E', .t. )

   oCn   := TOleAuto():New( 'ADODB.Connection' )
   // Set correct path for fwh folder
   oCn:Open( "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" + ;
             "c:\fwh\samples\xbrtest.mdb;User Id=admin;Password=;" )

   if oCn:State < 1
      MsgInfo( 'Connection Fail' )
      return ( 1 )
   endif

   oRs1  := TOleAuto():New( 'ADODB.RecordSet' )
   WITH OBJECT oRs1
      :ActiveConnection := oCn
      :Source           := 'SELECT FIRST,CITY,AGE FROM CUSTOMER'
      :CursorLocation   := 3  // adUseClient
      :Open()
   END

   oRs2  := TOleAuto():New( 'ADODB.RecordSet' )
   WITH OBJECT oRs2
      :ActiveConnection := oCn
      :Source           := 'SELECT LAST,SALARY FROM CUSTOMER'
      :CursorLocation   := 3  // adUseClient
      :Open()
   END

   DEFINE DIALOG oDlg SIZE 540,360 PIXEL TITLE 'XBrowse Swap on the Fly'

   @ 10,10 XBROWSE oBrw2 OF oDlg SIZE 250,150 PIXEL ;
      AUTOCOLS RECSET oRs2 AUTOSORT

   WITH OBJECT oBrw2
      :nStretchCol   := 1
      :CreateFromCode()
      :Hide()
      :Disable()
   END

   @ 10,10 XBROWSE oBrw1 OF oDlg SIZE 250,150 PIXEL ;
      AUTOCOLS RECSET oRs1 AUTOSORT

   oBrw1:nStretchCol := 2
   oBrw1:CreateFromCode()

   @ 165, 10 BUTTON 'Brw-1' SIZE 40,12 PIXEL OF oDlg ;
      WHEN nSelect == 2 ACTION SwapBrw( { oBrw1, oBrw2 }, 1 )

   @ 165, 60 BUTTON 'Brw-2' SIZE 40,12 PIXEL OF oDlg ;
      WHEN nSelect == 1 ACTION SwapBrw( { oBrw1, oBrw2 }, 2 )

   @ 165,220 BUTTON 'Close' SIZE 40,12 PIXEL OF oDlg ACTION oDlg:End()

   ACTIVATE DIALOG oDlg CENTERED

   oRs1:Close()
   oRs2:Close()
   oCn:Close()

return nil

static function SwapBrw( aBrw, nShow )

   local nHide := nXor( nShow, 3 )

   WITH OBJECT aBrw[ nHide ]
      :Hide()
      :Disable()
   END

   WITH OBJECT aBrw[ nShow ]
      :Enable()
      :Show()
   END

   nSelect  := nShow
   aBrw[ 1 ]:oWnd:aEvalWhen()

return nil