Saludos ,
Tomado Igual del Foro, con correo saliente de gmail. a mi me funciona OK,
Local loCfg, loMsg, oError
TRY
loCfg := CREATEOBJECT( "CDO.Configuration" )
WITH OBJECT loCfg:Fields
:Item( "http://schemas.microsoft.com/cdo/configuration/smtpserver" ):Value := "smtp.gmail.com"
:Item( "http://schemas.microsoft.com/cdo/configuration/smtpserverport" ):Value := 465
:Item( "http://schemas.microsoft.com/cdo/configuration/sendusing" ):Value := 2
:Item( "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate" ):Value := .T.
:Item( "http://schemas.microsoft.com/cdo/configuration/smtpusessl" ):Value := .T.
:Item( "http://schemas.microsoft.com/cdo/configuration/sendusername" ):Value := "aquitucorreogmail@gmail.com" // tu cuenta de correo de salida
:Item( "http://schemas.microsoft.com/cdo/configuration/sendpassword" ):Value := "aquituclavegmail" //con tu clave gmail. en este caso
:Update()
END WITH
loMsg := CREATEOBJECT ( "CDO.Message" )
WITH OBJECT loMsg
:Configuration = loCfg
:From = "aquitucorreogmail@gmail.com"
:To = "aquienleenviaselcorreo@hotmail.com" // <----- Coloca aqui a quien va dirigido el correo
:Subject = "titulo del correo"
:TextBody = "Texto lo que enviaras en el correo el cuerpo"
:Send()
ENDWITH
CATCH oError
Alert( "No se pudo enviar el mensaje" + ";" +CRLF+ ;
"Error: " + TRANSFORM(oError:GenCode, NIL) + ";" +CRLF+ ;
"SubC: " + TRANSFORM(oError:SubCode, NIL) + ";" +CRLF+ ;
"OSCode: " + TRANSFORM(oError:OsCode, NIL) + ";" +CRLF+ ;
"SubSystem: " + TRANSFORM(oError:SubSystem, NIL) + ";" +CRLF+CRLF+ ;
"Mensaje: " + oError:Description )
END
