FiveTech Support Forums

Hi i have a xbrowse like this:

oBrw := TXBrowse():New( oDlg )
oBrw:nMarqueeStyle := MARQSTYLE_HIGHLROW
oBrw:CreateFromResource( 109 )
oBrw:nColDividerStyle := 5 //LINESTYLE_BLACK // COLUNAS
oBrw:lColDividerComplete := .T.
oBrw:nHeaderHeight :=30
oBrw:nStretchCol := STRETCHCOL_LAST
oCol := oBrw:AddCol()
oCol:bStrData := { || ARQEMP->SIGLA }
oCol:cHeader := "SIGLA"
oCol := oBrw:AddCol()
oCol:bStrData := { || ARQEMP->FANTASIA }
oCol:cHeader := "FANTASIA"
oCol := oBrw:AddCol()
oCol:bStrData := { || Substr(ARQEMP->CIDADE,1,28) }
oCol:cHeader := "CIDADE"
oCol := oBrw:AddCol()
oCol:bStrData := { || ARQEMP->UF }
oCol:cHeader := "UF"

But they display just the same records in all browser area. If i put Sele ARQEMP and Set Order to 1 and Go Top before this definitions runs ok, but i use Dabase object how i set txbrowse alias with a Database object and how i link the columns? oCol:bStrData := { || oArqEmp:SIGLA } This is correct?
Thanks in advance.

...but i use Dabase object how i set txbrowse alias with a Database object and how i link the columns? oCol:bStrData := { || oArqEmp:SIGLA } This is correct?

:SetoDbf( oArqEmp, { "SIGLA", "FANTASIA", "CIDADE", "UF" }, .t. )

Thanks James works great!

nageswaragunupudi wrote:Please do not forget to specify the alias in the above case when you are coding for DBF.

Code (fw): Select all Collapse

oBrw   := TXBrowse():New( oDlg )
oBrw:cAlias := "ARQEMP"   // important

Instead of coding oCol := oBrw:AddCol(), oBrw:bStrData := ... for each column, it is easier and more useful to code oBrw:SetRDD( lAddCols, lAutoSort, aFieldNames )
The entire above code can be written as:

Code (fw): Select all Collapse

oBrw   := TXBrowse():New( oDlg )
WITH OBJECT oBrw
   // If using DBF include these two lines
   :cAlias := "ARQEMP" 
   :SetRDD( .f., .t., { "SIGLA", "FANTASIA", "CIDADE", "UF" } )
   // If using TDataBase object, include the following one line and remove the above 2 lines
   :SetoDbf( oArqEmp, { "SIGLA", "FANTASIA", "CIDADE", "UF" }, .t. )
   
   // next lines are common for both
   :nColDividerStyle := LINESTYLE_BLACK
   :lColDividerComplete := .t.
   :nHeaderHeight := 30
   :nStretchCol   := STRETCHCOL_LAST
   :CreateFromResource( 109 )
END
ACTIVATE DIALOG oDlg