FiveTech Support Forums

FiveWin / Harbour / xBase community
Board indexActive topicsAll discussionsLogin (GitHub)
Board index FiveWin for Harbour/xHarbour BUG: error in Invoices.prg sample
mgsoft
Posts: 422
Joined: Mon Aug 17, 2009 12:18 PM
BUG: error in Invoices.prg sample
Posted: Fri Oct 29, 2010 02:43 PM

Hi,

I compile the sample and I click on the menu items (archivo, edici贸n, etc) and the program crashes.

Any clue?

Thank you :D

Saludos,



Eduardo
ukservice
Posts: 417
Joined: Tue Feb 23, 2010 03:09 PM
Re: error in Invoices.prg sample
Posted: Sun Oct 31, 2010 10:26 AM

Yes, I confirm this problem

FWH 11.11, Harbour 3.1 and Borland C++ 5.82
James Bott
Posts: 4840
Joined: Fri Nov 18, 2005 04:52 PM
Re: error in Invoices.prg sample
Posted: Mon Nov 01, 2010 06:41 PM

This is probably because there are no actions defined for the menu items. It is just a dummy menu.

Regards,
James

FWH 18.05/xHarbour 1.2.3/BCC7/Windows 10
mgsoft
Posts: 422
Joined: Mon Aug 17, 2009 12:18 PM
Re: error in Invoices.prg sample
Posted: Mon Nov 01, 2010 06:59 PM

James,

I created a full menu with items and actions and the error happen too;)

Saludos,



Eduardo
James Bott
Posts: 4840
Joined: Fri Nov 18, 2005 04:52 PM
Re: error in Invoices.prg sample
Posted: Mon Nov 01, 2010 08:46 PM

Mgsoft,

What is the error?

FWH 18.05/xHarbour 1.2.3/BCC7/Windows 10
James Bott
Posts: 4840
Joined: Fri Nov 18, 2005 04:52 PM
Re: error in Invoices.prg sample
Posted: Mon Nov 01, 2010 08:58 PM
OK, I see that it is an unknown error generated by Windows.

I made a simiple test and it runs without error, so there is something different with invoices.prg.

James

Test program:

Code (fw): Select all Collapse
// Test dummy menu erroring out


#include "fivewin.ch"

function main()

   TApplication():new()

return nil

class TApplication
   data oMenu
   method new()
   method buildMenu()
endclass

method new() CLASS TApplication
   local oWnd
   define window oWnd menu ::BuildMenu()
   activate window oWnd
return nil

//----------------------------------------------------------------------------//

METHOD BuildMenu() CLASS TApplication

   MENU ::oMenu 2007
      MENUITEM "&Archivo"
      MENUITEM "&Edici贸n"
      MENUITEM "&Ver"
      MENUITEM "&Datos"
      MENUITEM "&Procesos"
   ENDMENU

return ::oMenu
FWH 18.05/xHarbour 1.2.3/BCC7/Windows 10
mgsoft
Posts: 422
Joined: Mon Aug 17, 2009 12:18 PM
Re: error in Invoices.prg sample
Posted: Wed Mar 16, 2011 03:35 PM

Hi,

Any clue on this bug?

Thank you.

Saludos,



Eduardo
Daniel Garcia-Gil
Posts: 2365
Joined: Wed Nov 02, 2005 11:46 PM
Re: BUG: error in Invoices.prg sample
Posted: Wed Mar 16, 2011 11:02 PM
Hello...

mgsoft wrote:Any clue on this bug?
Thank you.


i thinks is not a bug... maybe a incompatibility in MDI enviroment

this a same sample using panel
Code (fw): Select all Collapse
// Demo of a Menu + ButtonBar + ExplorerBar + Splitter + Titles + Browses

#include "FiveWin.ch"
#include "Splitter.ch"
#include "TTitle.ch"
#include "xbrowse.ch"

//----------------------------------------------------------------------------//

function Main()

   local oApp := TApplication():New()
   
   oApp:Run()
   
return nil   

//----------------------------------------------------------------------------//

CLASS TApplication

   DATA   oWndMain, oMenu, oExBar, oSplit
   DATA   oWndBrief
   
   METHOD New()
   METHOD BuildMenu()
   METHOD BuildButtonBar()
   METHOD BuildExplorerBar()
   METHOD Run()
   
ENDCLASS

//----------------------------------------------------------------------------//

METHOD New() CLASS TApplication

   DEFINE WINDOW ::oWndMain TITLE "Facturaci贸n";
      MENU ::BuildMenu() COLOR "N/W*"
      
   ::BuildButtonBar()
   ::BuildExplorerBar()

   ::oWndBrief = TWndBrief():New( ::oWndMain )


   @ 0, 800 SPLITTER ::oSplit ;
      VERTICAL _3DLOOK ;  
      PREVIOUS CONTROLS ::oWndBrief:oWnd; 
      HINDS CONTROLS ::oExBar ;
      SIZE 4, ::oWndMain:nHeight - 70 PIXEL ;
      OF ::oWndMain


   SET MESSAGE OF ::oWndMain ;
      TO "Demo of a Menu + ButtonBar + ExplorerBar + Splitter + Titles + Browses" ;
      CENTERED CLOCK KEYBOARD 2007
         
return Self

//----------------------------------------------------------------------------//

METHOD Run() CLASS TApplication

   ACTIVATE WINDOW ::oWndMain MAXIMIZED ;
      ON RESIZE ::oSplit:Adjust()

return nil

//----------------------------------------------------------------------------//

METHOD BuildMenu() CLASS TApplication

   MENU ::oMenu 2007
      MENUITEM "&Archivo"
      MENUITEM "&Edici贸n"
      MENUITEM "&Ver"
      MENUITEM "&Datos"
      MENUITEM "&Procesos"
      MENUITEM "&Impresiones"
      MENUITEM "&Herramientas"
      MENUITEM "Inte&rnet"
      MENUITEM "&Ventanas"
      MENUITEM "&?"
   ENDMENU
   
return ::oMenu      

//----------------------------------------------------------------------------//

METHOD BuildButtonBar() CLASS TApplication

   local oBar

   DEFINE BUTTONBAR oBar OF ::oWndMain SIZE 125, 60 2007

   DEFINE BUTTON OF oBar ACTION MsgInfo( "presupuesto" ) ;
      FILENAME "..\bitmaps\32x32\case.bmp" PROMPT "Nuevo presupuesto" TOOLTIP "Attach"

   DEFINE BUTTON OF oBar ACTION MsgInfo( "factura" ) ;
      FILENAME "..\bitmaps\32x32\graphics.bmp" PROMPT "Nueva factura" TOOLTIP "Calendar"

   DEFINE BUTTON OF oBar ACTION MsgInfo( "venta" ) ;
      FILENAME "..\bitmaps\32x32\edit.bmp" PROMPT "Documentos de venta" TOOLTIP "Calendar"

   DEFINE BUTTON OF oBar ACTION MsgInfo( "compra" ) ;
      FILENAME "..\bitmaps\32x32\new.bmp" PROMPT "Documentos de compra" TOOLTIP "Calendar"

   DEFINE BUTTON OF oBar ACTION MsgInfo( "stock" ) GROUP ;
      FILENAME "..\bitmaps\32x32\graphics.bmp" PROMPT "Documentos de stock" ;
      TOOLTIP "Calendar"

   DEFINE BUTTON OF oBar ACTION MsgInfo( "cobros" ) GROUP ;
      FILENAME "..\bitmaps\32x32\case.bmp" PROMPT "Cobros" TOOLTIP "Calendar"
      
   DEFINE BUTTON OF oBar ACTION MsgInfo( "clientes" ) GROUP ;
      FILENAME "..\bitmaps\32x32\people.bmp" PROMPT "Clientes y clientes potenciales" ;
      TOOLTIP "Clientes"

   DEFINE BUTTON OF oBar ACTION MsgInfo( "articulos" ) GROUP ;
      FILENAME "..\bitmaps\32x32\edit.bmp" PROMPT "Art铆culos" TOOLTIP "Calendar"

return oBar

//----------------------------------------------------------------------------//

METHOD BuildExplorerBar() CLASS TApplication

   local oPanel1, oPanel2, oPanel3, oPanel4
   local bClick

   @ 0, 805 EXPLORERBAR ::oExBar OF ::oWndMain SIZE 200, 400

   oPanel1 = ::oExBar:AddPanel( "One", "..\bitmaps\32x32\people.bmp" )
   oPanel1:lSpecial = .T.
   oPanel1:AddLink( "First item", bClick, "..\bitmaps\16x16\additem.bmp" )
   oPanel1:AddLink( "Second item", bClick, "..\bitmaps\16x16\copy.bmp" )
      
   oPanel2 = ::oExBar:AddPanel( "Two", "..\bitmaps\32x32\case.bmp" )
   oPanel2:AddLink( "First item", bClick, "..\bitmaps\16x16\adddbf.bmp" )
   oPanel2:AddLink( "Second item", bClick, "..\bitmaps\16x16\delete0.bmp" )
   oPanel2:AddLink( "Third item", bClick, "..\bitmaps\16x16\envelope.bmp" )
   oPanel2:AddLink( "Fourth item", bClick, "..\bitmaps\16x16\copy.bmp" )

   oPanel3 = ::oExBar:AddPanel( "Three", "..\bitmaps\32x32\graphics.bmp" )
   oPanel3:AddLink( "First item", bClick, "..\bitmaps\16x16\adddbf.bmp" )
   oPanel3:AddLink( "Second item", bClick, "..\bitmaps\16x16\delete0.bmp" )
   oPanel3:AddLink( "Third item", bClick, "..\bitmaps\16x16\envelope.bmp" )
   
   oPanel4 = ::oExBar:AddPanel( "Four" )
   oPanel4:AddLink( "First item", bClick, "..\bitmaps\16x16\additem.bmp" )
   oPanel4:AddLink( "Second item", bClick, "..\bitmaps\16x16\copy.bmp" )

   
return ::oExBar

//----------------------------------------------------------------------------//

CLASS TWndBrief

   DATA   oWnd

   METHOD New( oWndMain )
   METHOD BuildTitles()
   METHOD BuildBrowses()
   
ENDCLASS      
   
//----------------------------------------------------------------------------//

METHOD New( oWndMain ) CLASS TWndBrief
         

   ::oWnd = TPanel():New( 60, 0, 400, 800, oWndMain )

   ::BuildTitles() 
   ::BuildBrowses()

   
return self

//----------------------------------------------------------------------------//

METHOD BuildTitles() CLASS TWndBrief

   local oTitle1, oTitle2, oTitle3, oTitle4, oTitle5, oTitle6, oTitle7, oFont1

   DEFINE FONT oFont1 NAME "Blackoak Std" SIZE 0, -20

   @ 0, 0 TITLE oTitle1 SIZE 800, 30 OF ::oWnd SHADOWSIZE 0
    
   oTitle1:aGrdBack = { { 1, nRGB( 87, 130, 199 ), nRGB( 25, 69, 159 ) } }
   
   @ 5, 10 TITLETEXT OF oTitle1 TEXT "Panel de resumen" FONT oFont1 ;
      COLOR nRGB( 255, 255, 255 )

   @ 8, 777 TITLEIMG OF oTitle1 BITMAP "..\bitmaps\16X16\close.bmp" TRANSPARENT   
      
   @ 60, 10 TITLE oTitle2 SIZE 385, 30 OF ::oWnd SHADOWSIZE 0
    
   oTitle2:aGrdBack = { { 1, nRGB( 87, 130, 199 ), nRGB( 25, 69, 159 ) } }
   
   @ 5, 35 TITLETEXT OF oTitle2 TEXT "脷ltimos Documentos de venta" FONT oFont1 ;
      COLOR nRGB( 255, 255, 255 )

   @ 8, 8 TITLEIMG OF oTitle2 BITMAP "..\bitmaps\16X16\favorite.bmp" TRANSPARENT   

   @ 60, 410 TITLE oTitle3 SIZE 385, 30 OF ::oWnd SHADOWSIZE 0
    
   oTitle3:aGrdBack = { { 1, nRGB( 87, 130, 199 ), nRGB( 25, 69, 159 ) } }
   
   @ 5, 35 TITLETEXT OF oTitle3 TEXT "Seguimiento Presupuesto" FONT oFont1 ;
      COLOR nRGB( 255, 255, 255 )

   @ 8, 8 TITLEIMG OF oTitle3 BITMAP "..\bitmaps\16X16\favorite.bmp" TRANSPARENT   

   @ 250, 10 TITLE oTitle4 SIZE 385, 30 OF ::oWnd SHADOWSIZE 0
    
   oTitle4:aGrdBack = { { 1, nRGB( 87, 130, 199 ), nRGB( 25, 69, 159 ) } }
   
   @ 5, 35 TITLETEXT OF oTitle4 TEXT "Vencimientos impagados" FONT oFont1 ;
      COLOR nRGB( 255, 255, 255 )

   @ 8, 8 TITLEIMG OF oTitle4 BITMAP "..\bitmaps\16X16\favorite.bmp" TRANSPARENT   

   @ 250, 410 TITLE oTitle5 SIZE 385, 30 OF ::oWnd SHADOWSIZE 0
    
   oTitle5:aGrdBack = { { 1, nRGB( 87, 130, 199 ), nRGB( 25, 69, 159 ) } }
   
   @ 5, 35 TITLETEXT OF oTitle5 TEXT "Estad铆sticas de venta" FONT oFont1 ;
      COLOR nRGB( 255, 255, 255 )

   @ 8, 8 TITLEIMG OF oTitle5 BITMAP "..\bitmaps\16X16\favorite.bmp" TRANSPARENT   

   @ 440, 10 TITLE oTitle6 SIZE 385, 30 OF ::oWnd SHADOWSIZE 0
    
   oTitle6:aGrdBack = { { 1, nRGB( 87, 130, 199 ), nRGB( 25, 69, 159 ) } }
   
   @ 5, 35 TITLETEXT OF oTitle6 TEXT "Ultimos documentos de compra" FONT oFont1 ;
      COLOR nRGB( 255, 255, 255 )

   @ 8, 8 TITLEIMG OF oTitle6 BITMAP "..\bitmaps\16X16\favorite.bmp" TRANSPARENT   

   @ 440, 410 TITLE oTitle7 SIZE 385, 30 OF ::oWnd SHADOWSIZE 0
    
   oTitle7:aGrdBack = { { 1, nRGB( 87, 130, 199 ), nRGB( 25, 69, 159 ) } }
   
   @ 5, 35 TITLETEXT OF oTitle7 TEXT "Estad铆sticas de compra" FONT oFont1 ;
      COLOR nRGB( 255, 255, 255 )

   @ 8, 8 TITLEIMG OF oTitle7 BITMAP "..\bitmaps\16X16\favorite.bmp" TRANSPARENT   

return nil

//----------------------------------------------------------------------------//

METHOD BuildBrowses() CLASS TWndBrief

   local oBrw1, oBrw2, oBrw3, oBrw4, oBrw5, oBrw6

   USE Customer ALIAS "One" SHARED
   
   @ 90, 10 XBROWSE oBrw1 FIELDS One->First, One->Last ;
      SIZE 385, 155 OF ::oWnd PIXEL ALIAS "One"
      
   oBrw1:CreateFromCode()   

   USE Customer NEW ALIAS "Two" SHARED
   
   @ 90, 410 XBROWSE oBrw2 FIELDS Two->First, Two->Last ;
      SIZE 385, 155 OF ::oWnd PIXEL ALIAS "Two"
      
   oBrw2:CreateFromCode()   

   USE Customer NEW ALIAS "Three" SHARED
   
   @ 280, 10 XBROWSE oBrw3 FIELDS Three->First, Three->Last ;
      SIZE 385, 155 OF ::oWnd PIXEL ALIAS "Three"
      
   oBrw3:CreateFromCode()   

   USE Customer NEW ALIAS "Four" SHARED
   
   @ 280, 410 XBROWSE oBrw4 FIELDS Four->First, Four->Last ;
      SIZE 385, 155 OF ::oWnd PIXEL ALIAS "Four"
      
   oBrw4:CreateFromCode()   

   USE Customer NEW ALIAS "Five" SHARED
   
   @ 470, 10 XBROWSE oBrw5 FIELDS Five->First, Five->Last ;
      SIZE 385, 140 OF ::oWnd PIXEL ALIAS "Five"
      
   oBrw5:CreateFromCode()   

   USE Customer NEW ALIAS "Six" SHARED
   
   @ 470, 410 XBROWSE oBrw6 FIELDS Six->First, Six->Last ;
      SIZE 385, 140 OF ::oWnd PIXEL ALIAS "Six"
      
   oBrw6:CreateFromCode()   

return nil

//----------------------------------------------------------------------------//
our best documentation is the source code
Isla de Margarita Venezuela.
danielgarciagil@gmail.com
http://tdolphin.blogspot.com/
https://www.dropbox.com/referrals/NTI5Njk4MDc1OQ?src=global9

Continue the discussion

Static archive 路 New replies & topics via GitHub Discussions