FiveTech Support Forums

oRpt:bStartPage := {|| oCol:nPad := RPT_CENTER } 
oRpt:bStartRecord := {|| oCol:nPad := RPT_RIGHT }

                        Function ImpPadron( aArray )

Local oReporte
Local oFnt1
Local oFnt2
Local oFnt3
Local oFnt4
Local oPen1
Local oPen2
Local i, j
Local nAt := 1
Local oEspera
LocaL dFecha

Define Pen oPen1 Width 1 COLOR RGB( 100, 100, 100 )
Define Pen oPen2 Width 1 COLOR CLR_BLACK

Define Font oFnt1 Name "Arial" Size 0,  - 8
Define Font oFnt2 Name "Arial" SIZE 0,  - 8 Bold
Define Font oFnt3 Name "Arial" Size 0,  -11 Bold
Define Font oFnt4 Name "Tahoma" Size 0, - 8 Bold

If( oVarGlobales : lPrevisualiza )
   Report oReporte Title " ", "**LISTADO DEL PADRON**", ""  ;
            Preview Font oFnt2, oFnt3, oFnt1, oFnt4 ;
            Header Alltrim( oVarGlobales : cColegio ), "Fecha " + DToC( Date() ), "Hora " + Time() ;
            Footer OemToAnsi( "Página Nro " ) + StrZero( oReporte : nPage, 3 ) Center Pen oPen2, oPen1 ;
            Caption "Listado del padron"
Else
   oEspera := TEspera() : New( "Imprimiendo. Espere por favor" )
   Report oReporte Title "Listado de Padron", "", "", ""  ;
            Font oFnt2, oFnt3, oFnt1, oFnt4 ;
            Header Alltrim( oVarGlobales : cColegio ), "Fecha " + DToC( Date() ), "Hora " + Time() ;
            Footer OemToAnsi( "Página Nro " ) + StrZero( oReporte : nPage, 3 ) Center Pen oPen2, oPen1 ;
            Caption "Listado del padron"
End
   Column Title '', "DOC.", " "               Data Alltrim( Str( aArray[ nAt ][ 1 ] ) )   Font 3 Size 10 //Grid 2
   Column Title 'EMPLEADO',"OBRA SOCIAL", " " Data aArray[ nAt ][ 2 ], aArray[ nAt ][ 4 ] Font 3 Size 35 //Grid 2
   Column Title '', "CUIL", " "               Data aArray[ nAt ][ 3 ]                     Font 3 Size 12 //Grid 2
   Column Title '', "ALTA", " "               Data dFecha                                 Font 3 Size 8 Center //Grid 2
   Column Title "COD.", "ACT.", " "           Data aArray[ nAt ][ 6 ]                     Font 3 Size 5 Center //Grid 2
   Column Title "", "MOD.", " "               Data aArray[ nAt ][ 7 ]                     Font 3 Size 5 Center //Grid 2
   Column Title "", "COND.", " "              Data aArray[ nAt ][ 8 ]                     Font 3 Size 5 Center //Grid 2
   Column Title "COD.", "ZONA", " "           Data aArray[ nAt ][ 9 ]                     Font 3 Size 5 Center //Grid 2

   oReporte : nTitleUpLine := RPT_NOLINE
   oReporte : nTitleDnLine := RPT_NOLINE
   oReporte : nTotalLine   := RPT_NOLINE
   oReporte : nDataLine    := RPT_DOUBLELINE
   //Aeval(oReporte : aColumns, {|v| v:Separator(100)})
End Report

If( oReporte : lCreated )
   With Object oReporte
      :nTitleBox     := 3
      :lTitleBoxJoin := .t.
      :nHeaderBox    := 3
      :nBodyBox      := 2
      :nCurve        := 0
      :SetPenColor( CLR_WHITE )
      :bSkip := { || nAt++ }
      :oTitle  : aFont[ 2 ] := { || 2 }
      :oHeader : aFont[ 1 ] := { || 2 }
      :oTitle : aPad[ 1 ]  := RPT_LEFT
      :oTitle : aPad[ 2 ]  := RPT_CENTER
      :oTitle : aPad[ 3 ]  := RPT_LEFT
      :oDevice : SetPortrait()
      :oDevice : lPrvModal  := .t.
   End
End

oReporte : bStartPage   := { || CambiaAlineacion( oReporte, 1 ) }
oReporte : bStartRecord := { || CambiaAlineacion( oReporte, 2 )

Activate Report oReporte On Init ( oReporte : lSeparator := .t. ) ;
   While nAt <= Len( aArray ) ;
   On StartLine( dFecha := If( Valtype( aArray[ nAt ][ 5 ] ) == "U", DToc( CToD( "" ) ), DToc( aArray[ nAt ][ 5 ] ) ) )

oPen1 : End()
oPen2 : End()
oFnt1 : End()
oFnt2 : End()
oFnt3 : End()
oFnt4 : End()
oVarGlobales : oWndMain : SetFocus()
If( !oVarGlobales : lPrevisualiza )
   oEspera : Close()
End
Return 0

                        Function CambiaAlineacion( oReporte, nOpcion )

Local i

Switch nOpcion
   Case 1
      For i := 1 To Len( oReporte : aColumns )
         oReporte : aColumns[ i ] : nPad := RPT_LEFT
         oReporte : aColumns[ i ] : bTitleFont := { || 4 }
      Next i
      Exit
   Case 2
      For i := 1 To Len( oReporte : aColumns )
         If( i == 2 )
            oReporte : aColumns[ i ] : nPad := RPT_LEFT
         Else
            oReporte : aColumns[ i ] : nPad := RPT_CENTER
         End
         oReporte : aColumns[ i ] : bDataFont := { || 3 }
      Next i
      Exit
End
Return 0