FiveTech Support Forums

     oCon := TOLEAUTO():new("adodb.connection")
   oCon:ConnectionString:="Driver={MySQL ODBC 3.51 Driver};Server="+cHost+";Port=3306;Database="+cDataBase+";User="+cUser+"; Password="+cPassWord+";Option=3;"
     oCon:ConnectionTimeout:=3600
   //oCon:ConnectionString:="Driver={MySQL ODBC 3.51 Driver};Server="+cHost+";Port=3306;Database=portalphpnuke;User=user; Password=password;Option=3;"

     TRY
       oCon:Open()
     CATCH
        MSGSTOP("NO SE CONECTO")
            RETURN NIL
     END
     oCmd := TOLEAUTO():New("adodb.command")
     oCmd :ActiveConnection(oCon)
     oRS := TOleAuto():New("adodb.recordset")
     oRS :CursorLocation := adUseClient
     oRS :LockType       := adLockOptimistic
     oRS :CursorType     := adOpenKeyset
   oRs:ActiveConnection(oCon)
     oRs:Source := "SELECT * FROM articulos ORDER BY descripcion"
     oRS:Open()

   /*IF oRS:Supports(adSeek)   // Aqui Indexamos el RecordSet Para poder buscar, en este caso por codigo
      oRS:Index := "codigo"
            msginfo("index")
   ENDIF*/

     DEFINE DIALOG ODLG resource "ODLG_MANART" TITLE "TABLA DE ARTICULOS"

     REDEFINE METER oMeter VAR nParte TOTAL nTotal ID 300 OF oDlg UPDATE // BARCOLOR RGB(0,0,128),RGB(0,0,128)

     REDEFINE GET oG340 VAR cBuscar ID 340 OF oDlg UPDATE PICTURE "@!" ;
     VALID (FILTRA_MAR(cBuscar,oRS,oLBx),.T.)

     oRS:MoveFirst()

     REDEFINE LISTBOX oLbx FIELDS oRS:Fields("codigo"):value,;
                                                               oRS:Fields("descripcion"):value,;
                                                               oRS:Fields("Precioventa"):value;
        SIZES 40,250,20;
                                                 HEADERS "Código",;
                                                                 "Descripcion",;
                                                                 "Precio";
                                                id 135 of Odlg  UPDATE ON DBLCLICK(EDITA_MAR(.f.,oRS),oLbx:REFRESH())
   oLbx:aJustify := {.F.,.f.,.t.,.t.}
     oLbx:bLogicLen := { || oRs:RecordCount }
   oLbx:bGoTop    := { || oRs:MoveFirst() }
   oLbx:bGoBottom := { || oRs:MoveLast() }
   oLbx:bSkip     := { | nSkip | Skipper( oRs, nSkip ) }
   oLbx:cAlias    := "ARRAY"

    oLbx:bKeyDown :={|nKey|IIF(nKey == VK_RETURN,(EDITA_MAR(.F.,oRS),oLbx:bGOTOP(),olbx:refresh(),OLBX:SETFOCUS()),;
  IIF(nKey == VK_DELETE ,ELIM_MAR(oRS,oLBx),;
    IIF(nKey == VK_INSERT ,(EDITA_MAR(.T.,oRS),oLbx:bGOTOP(),olbx:refresh(),OLBX:SETFOCUS()) ,.T.)))}

   REDEFINE BUTTONBMP ob136 ID 136 of oDlg BITMAP "NUEVO" ;
     action(EDITA_MAR(.T.,oRS),olbx:refresh(),oLbx:SetFocus())  WHEN VALIACCE("A01")>2
     ob136:cTooltip := "Crea nuevo registro"

   REDEFINE BUTTONBMP ob137 ID 137 of oDlg BITMAP "EDITAR" ;
     action(EDITA_MAR(.F.,oRS),olbx:refresh(),oLbx:SetFocus())
     ob137:cTooltip:= "modifica registro"

     REDEFINE BUTTONBMP ob138 ID 138 of ODLG BITMAP "ELIMINA" ACTION(ELIM_MAR(oRS,oLBx))
     ob138:cTooltip:= "Elimina registro"

     REDEFINE BUTTONBMP ob139 ID 139 of ODLG BITMAP "IMPRESORA";
     action(olbx:gotop(),olbx:report(),olbx:gobottom())
     ob139:cTooltip:= "Imprime"

     REDEFINE BUTTONBMP ob139 ID 140 of ODLG BITMAP "EXCEL" ACTION(EXCEL_MAR(oRS,oMeter))
     ob139:cTooltip:= "Listado Articulos a Excel"

     REDEFINE BUTTON oB450 ID 450 OF oDlg ACTION (odlg:end())

     ACTIVATE dialog ODLG centered // VALID LSALE
   oRS:Close()
     oCon:Close()
RETURN .T.

STATIC FUNCTION SKIPPER( oRsx, nSkip )
 LOCAL nRec := oRsx:AbsolutePosition
 oRsx:Move( nSkip )
 IF oRsx:EOF; oRsx:MoveLast(); ENDIF
 IF oRsx:BOF; oRsx:MoveFirst(); ENDIF
RETURN( oRsx:AbsolutePosition - nRec )

FUNCTION FILTRA_MAR(cBuscar,oRS,oLBx)
 IF LEN(ALLTRIM(cBuscar))>0
     oRs:Filter:= "descripcion LIKE" + "  '*" + ALLTRIM(cBuscar) + "*' "
 ELSE
     oRs:Filter:= ""
 ENDIF
 oRs:Refresh()
 oLBx:Refresh()
RETURN NIL

FUNCTION EDITA_MAR(lNuevo,oRS)
 LOCAL oG114,oG102,lGraba:=.F.,oDlg,oB308,oB502,nBookMark,;
 cCodigo := SPACE(20),;
 cDescri := SPACE(50),;
 nPrecio := 0,;
 nMaximo := 0

 IF !lnuevo
        cCodigo := oRS:Fields("codigo"):value
        cDescri := oRS:Fields("descripcion"):value
 ENDIF

 DEFINE DIALOG oDlg RESOURCE "ODLG_ARTEDIMYSQL" TITLE "DATOS ARTICULO "

 REDEFINE GET oG114 VAR cCodigo ID 101 OF oDlg WHEN lNuevo UPDATE PICTURE "@!" ;
 valid (IIF(EXISTE_CODIGO(cCodigo,oRS),(cCodigo:=SPACE(20),oG114:oJump:=oG114,oG114:REFRESH()),.T.),.T.)
// valid (IIF(!EXISTE_CODIGO(cCodigo,oRS),oDlg:END(),.T.),.T.)

 REDEFINE GET oG102 VAR cDescri ID 102 OF oDlg UPDATE PICTURE "@!"

 REDEFINE BUTTONBMP oB308 ID 501 OF oDlg BITMAP "GRABAR" WHEN !EMPTY(cCodigo) ACTION; // .AND. (VALIACCE("A01")=3 .AND. lNuevo .OR. VALIACCE("A01")=4)
 (lGraba:=.T.,oDlg:END())
 oB308:cTOOLTIP:= "Grabar"

 REDEFINE BUTTONBMP oB502  ID 502  OF oDlg BITMAP "SALIR" ACTION(oDlg:END())

 ACTIVATE DIALOG oDlg

 IF lGraba
    IF lNuevo
             oRS:AddNew()
        ENDIF
    nBookMark:=oRs:BookMark                         // Marcamos el puntero del nuevo Registro y...>
        oRS:Fields("codigo"):value      := cCodigo
        oRS:Fields("descripcion"):value := cDescri
        oRS:Sort:="descripcion"
        oRs:BookMark:=nBookMark                          //  ...posicionamos el puntero en el nuevo registro para mostrarlo en el listbox ordenado
                                                         //  Esto solo cuando queremos mostrar el lisbox ordenado, en este caso por descripción
        oRS:Update()
  ENDIF
RETURN NIL

///////////////  VALIDAMOS SI EXISTE EL CODIGO INGRESADO //////////////////
FUNCTION EXISTE_CODIGO(cCodigo,oRS)
 LOCAL nBookMark,oRsExis,lBusca:=.F.
 IF EMPTY(cCodigo)
        RETURN .F.
 ENDIF
 nBookMark:=oRs:BookMark // guardamos el puntero actual del recordset para reestaablecerlo cuando el registro no existe
 oRS:MoveFirst()
 oRS:Find:="codigo LIKE" + " '%" + ALLTRIM(cCodigo) + "%' "
 IF !oRS:EOF()
    MSGINFO("Código ya registrado")
    lBusca:=.T.
 ENDIF
 oRs:BookMark:=nBookMark   // aqui se reestablece el puntero del recordset
RETURN lBusca

FUNCTION ELIM_MAR(oRS,oLbx)
 IF MSGYESNO("esta seguro de eliminar este registro?","Elimina")
        oRS:Delete()
        IF !oRs:EOF()
           oRs:MoveNext()
        ELSE
             oRs:MovePrevious()
        ENDIF
        oRS:Update()
        oLbx:Refresh()
 ENDIF
RETURN NIL