REDEFINE XBROWSE obrw ALIAS (customers)->cAlias ID 100 OF oDlg AUTOCOLS

oBrw:SetTree( ::buildTree() )

#include "FiveWin.Ch"
#include "adodef.ch"
#include "ord.ch"
#include "xbrowse.ch"

//----------------------------------------------------------------------------//

REQUEST DBFCDX

//----------------------------------------------------------------------------//

function Main()

   OpenData()
   BrowseTree( MakeTree() )

return (0)

//----------------------------------------------------------------------------//

init procedure PrgInit

   SET DATE ITALIAN
   SET CENTURY ON
   SET TIME FORMAT TO "HH:MM:SS"
   SET EPOCH TO YEAR(DATE())-50

   SET DELETED ON
   SET EXCLUSIVE OFF

   RDDSETDEFAULT( "DBFCDX" )

   XbrNumFormat( 'E', .t. )
   SetKinetic( .f. )
   SetGetColorFocus()

return

//----------------------------------------------------------------------------//

exit procedure PrgExit

   SET RESOURCES TO

return

//----------------------------------------------------------------------------//

static function OpenData()

   field STATE

   if ! File( "C:\FWH\SAMPLES\CUSTOMER.CDX" )
      USE C:\FWH\SAMPLES\CUSTOMER EXCLUSIVE
      INDEX ON STATE TAG STATE
      USE
   endif

   USE C:\FWH\SAMPLES\STATES NEW ALIAS PARNT
   USE C:\FWH\SAMPLES\CUSTOMER NEW ALIAS CHILD
   SET ORDER TO TAG STATE
   GO TOP

return nil

//----------------------------------------------------------------------------//

static function MakeTree()

   local oTree
   local nRecs    := PARNT->( OrdKeyCount() )
   local n

   TREE oTree

   for n := 1 to nRecs

      TREEITEM STR( n, 2 ) CARGO { -n, .f. }

   next n

   ENDTREE

return oTree

//----------------------------------------------------------------------------//

static function BrowseTree( oTree )

   local oWnd, oBrw, oFont, oBold
   local aBmp     := { "c:\fwh\bitmaps\16x16\folder3.bmp", ;
                       "c:\fwh\bitmaps\16x16\folder.bmp",  ;
                       "c:\fwh\bitmaps\16array.bmp" }

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE FONT oBold NAME "TAHOMA" SIZE 0,-14 BOLD

   DEFINE WINDOW oWnd
   oWnd:SetFont( oFont )

   @ 0, 0 XBROWSE oBrw OF oWnd CELL LINES

   WITH OBJECT oBrw
      :SetTree( oTree, aBmp, { || OnSkip( oBrw ) } )
      //
      WITH OBJECT :aCols[ 1 ]
         :cHeader       := "State/City"
         :bStrData      := ;
         :bEditValue    := { || If( oBrw:oTreeItem:nLevel == 1, PARNT->NAME, CHILD->CITY ) }
         :oDataFont     := { || If( oBrw:oTreeItem:nLevel == 1, oBold, oFont ) }
         :bBmpData      := { || BmpData( oBrw ) }
         :bLDClickData  := { || OnDblClick( oBrw ) }
      END
      //
      WITH OBJECT :AddCol()
         :cHeader    := "Name"
         :bEditValue := { || If( oBrw:oTreeItem:nLevel == 1, Space( 30 ), CHILD->FIRST - ( " " + CHILD->LAST ) ) }
      END
      //
      WITH OBJECT :AddCol()
         :cHeader       := "Salary"
         :bEditValue    := { || If( oBrw:oTreeItem:nLevel == 1, 0, CHILD->SALARY ) }
         :cEditPicture  := NumPict( 12, 2 )
      END
      //
      WITH OBJECT :AddCol()
         :cHeader       := "HireDate"
         :bEditValue    := { || If( oBrw:oTreeItem:nLevel == 1, CTOD( '' ), CHILD->HIREDATE ) }
         :cEditPicture  := "dd-mmm-yyyy"
      END
      //
      :lVThumbTrack     := .t.
      :lDisplayZeros    := .f.
      :bKeyChar         := { |nKey| If( nKey == 32 , OnDblClick( oBrw ), nil ) }
      //
      :CreateFromCode()
   END

   oWnd:oClient   := oBrw

   ACTIVATE WINDOW oWnd MAXIMIZED

return nil

//----------------------------------------------------------------------------//

static function OnSkip( oBrw )

   WITH OBJECT oBrw:oTreeItem
      if :nLevel == 1
         if :Cargo[ 1 ] < 0
            PARNT->( OrdKeyGoTo( - :Cargo[ 1 ] ) )
            :Cargo[ 1 ]    := PARNT->( RecNo() )
         else
            PARNT->( DbGoTo( :Cargo[ 1 ] ) )
         endif
      else
         CHILD->( DbGoTo( :Cargo ) )
      endif
   END

return nil

//----------------------------------------------------------------------------//

static function BmpData( oBrw )

   local nBmp  := 1

   WITH OBJECT oBrw:oTreeItem
      if :nLevel == 1
         if :oTree == nil
            nBmp  := If( :Cargo[ 2 ], 3, 2 )
         else
            nBmp  := If( :lOpened, 1, 2 )
         endif
      else
         nBmp     := 3
      endif
   END

return nBmp

//----------------------------------------------------------------------------//

static function OnDblClick( oBrw )

   local oItem    := oBrw:oTreeItem

   if oItem:nLevel == 1
      if oItem:oTree == nil .and. ! oItem:Cargo[ 2 ]
         AddSubTree( oItem )
         oItem:Cargo[ 2 ] := .t.
      endif
      if oItem:oTree != nil
         oItem:Toggle()
      endif
      oBrw:Refresh()
   endif

return nil


//----------------------------------------------------------------------------//

static function AddSubTree( oItem )

   local cSeek    := PARNT->CODE
   local nSaveRec := CHILD->( RecNo() )
   local oTree

   if CHILD->( DbSeek( cSeek ) )
      TREE oTree
      do while ! CHILD->( eof() ) .and. CHILD->STATE == cSeek
         TREEITEM CHILD->CITY CARGO CHILD->( RecNo() )
         CHILD->( DbSkip( 1 ) )
      enddo
      ENDTREE
      oItem:SetTree( oTree )
   endif

   CHILD->( DbGoTo( nSaveRec ) )

return nil

//----------------------------------------------------------------------------//