FiveTech Support Forums

#Include "Fivewin.ch"
#include 'xbrowse.ch'
#include "constant.ch"


Function Test()

   Local nBottom   := 35.7
   Local nRight    := 105
   Local nWidth :=  Max( nRight * DLG_CHARPIX_W, 180 )
   Local nHeight := nBottom * DLG_CHARPIX_H
   Local oDlg
   Local oBrw
   local oCol
    local aBrowse:={ },i,k

     USE CLIENTI  ALIAS CLIENTI NEW


     aCampi:={CLIENTI->CODCF,CLIENTI->RAGSOC ,CLIENTI->RAGSOC1,CLIENTI->INDIR  }
     aNomi:={"Codice","Ragione Sociale","Ragione Sociale2","Indirizzo Legale"}
     aSizes:= {50,250 ,200,100  }

  FOR k := 1 TO Len(aCampi)
             AADD(  aBrowse,{aCampi[k],aNomi[k],aSizes[k]})
         NEXT


      DEFINE DIALOG oDlg        ;
   TITLE "test with xbrowse "   ;
   SIZE nWidth, nHeight 



     @ 15.6, 0 XBROWSE  oBrw OF oDlg ;
      SIZE -1,-20 PIXEL


     
  FOR i := 1 TO Len(aBrowse)
      oCol := oBrw:AddCol()
       oCol:bEditValue := aBrowse[ i, 1 ]
       oCol:cHeader  := aBrowse[ i, 2 ]
      oCol:nWidth   := aBrowse[ i, 3 ]
    
   NEXT


      oBrw:SetRDD()
      oBrw:CreateFromCode()


      ACTIVATE DIALOG oDlg center


      RETURN NIL

#Include "Fivewin.ch"
#include 'xbrowse.ch'
#include "constant.ch"


Function Test()

   Local nBottom   := 35.7
   Local nRight    := 105
   Local nWidth :=  Max( nRight * DLG_CHARPIX_W, 180 )
   Local nHeight := nBottom * DLG_CHARPIX_H
   Local oDlg
   Local oBrw
   local oCol
   local aBrowse:={ },i,k

   USE CLIENTI  ALIAS CLIENTI NEW


//   aCampi:={CLIENTI->CODCF,CLIENTI->RAGSOC ,CLIENTI->RAGSOC1,CLIENTI->INDIR  } // see next line
   aCampi := { "CODCF", "RAGSOC", "RAGSOC1", "INDIR" } // Field names in quotes : GNR
   aNomi:= {"Codice","Ragione Sociale","Ragione Sociale2","Indirizzo Legale"}
   aSizes:= {50,250 ,200,100  }

/*
  // not necessary
  
  FOR k := 1 TO Len(aCampi)
             AADD(  aBrowse,{aCampi[k],aNomi[k],aSizes[k]})
         NEXT
*/


   DEFINE DIALOG oDlg TITLE "test with xbrowse " SIZE nWidth, nHeight 

   @ 15.6, 0 XBROWSE  oBrw OF oDlg SIZE -1,-20 PIXEL ; // next lines added by GNR
      DATASOURCE "CLIENTI" ; // Very Important. Never forget this
      COLUMNS aCampi ;
      HEADERS aNomi ;
      COLSIZES aSizes 

/*
  // Not this way. We already included this info correctly in the Xbrowse statement
     
  FOR i := 1 TO Len(aBrowse)
      oCol := oBrw:AddCol()
       oCol:bEditValue := aBrowse[ i, 1 ]
       oCol:cHeader  := aBrowse[ i, 2 ]
      oCol:nWidth   := aBrowse[ i, 3 ]
    
   NEXT
*/

//      oBrw:SetRDD()  // Omit this. XBrowse DATASOURCE clause already called SetRDD()

      oBrw:CreateFromCode()


      ACTIVATE DIALOG oDlg center


      RETURN NIL

#Include "Fivewin.ch"
#include 'xbrowse.ch'

Function Test()

   Local nBottom   := 35.7
   Local nRight    := 105
   Local nWidth :=  Max( nRight * DLG_CHARPIX_W, 180 )
   Local nHeight := nBottom * DLG_CHARPIX_H
   Local oDlg, oBrw

   USE CLIENTI  ALIAS CLIENTI NEW

   aCampi := { "CODCF", "RAGSOC", "RAGSOC1", "INDIR" } // Field names in quotes : GNR
   aNomi:= {"Codice","Ragione Sociale","Ragione Sociale2","Indirizzo Legale"}
   aSizes:= {50,250 ,200,100  }

   DEFINE DIALOG oDlg TITLE "test with xbrowse " SIZE nWidth, nHeight 

   @ 15.6, 0 XBROWSE  oBrw OF oDlg SIZE -1,-20 PIXEL ; 
      DATASOURCE "CLIENTI" ; // Very Important. Never forget this
      COLUMNS aCampi  HEADERS aNomi  COLSIZES aSizes 

   oBrw:CreateFromCode()

   ACTIVATE DIALOG oDlg center

   RETURN NIL