XBROWSE: No me aparecen los separadores de celdas. OK!

Board index FiveWin para Harbour/xHarbour XBROWSE: No me aparecen los separadores de celdas. OK!

Posts: 257

Joined: Tue May 16, 2006 04:46 PM

XBROWSE: No me aparecen los separadores de celdas. OK!
Posted: Thu May 16, 2013 11:29 PM

Jovenes, un nuevo reto:

Al actualizar FWH1103 a 1303 ahora no me aparecen los separadores de columnas y renglones usando XBrowse dentro de una ventana pero si cuando lo uso en un dialogo.

En ambos casos uso:
oBrw:nColDividerStyle:=4 ; oBrw:nRowDividerStyle:=4

Alguna idea?

RodolfoRBG
FWH 1307, xHarbour123 BCC582
rodolfoerbg@gmail.com

cnavarro

Posts: 6755

Joined: Wed Feb 15, 2012 08:25 PM

Re: XBROWSE: No me aparecen los separadores de celdas
Posted: Fri May 17, 2013 08:24 AM

Rodolfo,
Si el Browse contiene datos

oBrw:lColDividerComplete = .T.

http://forums.fivetechsupport.com/viewtopic.php?f=3&t=26334#p144872

Saludos

Cristobal Navarro

Hay dos tipos de personas: las que te hacen perder el tiempo y las que te hacen perder la noción del tiempo

El secreto de la felicidad no está en hacer lo que te gusta, sino en que te guste lo que haces

RodolfoRBG

Posts: 257

Joined: Tue May 16, 2006 04:46 PM

Re: XBROWSE: No me aparecen los separadores de celdas
Posted: Fri May 17, 2013 06:13 PM

Cristobal,

Gracias por contestar nuevamente. Ya tengo incluida esa instruccion junto con las siguientes al utilzar la siguiente funcion despues de crear un xBrowse:

Code (fw): Select all Collapse

//Define los colores y otras caracteristicas del Browse
FUNCTION DefColoBrw(oBrowse) //Objeto Browse
 oBrowse:lColDividerComplete:=.T. ; oBrowse:lRecordSelector:=.F.
 oBrowse:nHeaderLines:=1 ; oBrowse:nHeaderHeight:=20 ; oBrowse:nRowHeight:=18
 oBrowse:lHScroll:=.T. ; oBrowse:lVScroll:=.T.
 oBrowse:nMarqueeStyle:=5
 oBrowse:nColDividerStyle:=4 ; oBrowse:nRowDividerStyle:=4
 oBrowse:bClrSelFocus:={||{CLR_WHITE,CLR_CYAN}}
 oBrowse:bClrSel:={||{CLR_BLACK,CLR_HGRAY}}
RETURN(NIL)

Esta funcion la uso tanto cuando ejecuto un xBrowse en un Dialogo como en una Ventana. Lo raro es que al usar xBrowse en un dialogo si aparecen la lineas divisorias pero al usarlo en una Ventana no me aparecen.

Con la version de FWH 1103 la ventana se mostraba asi:

Ahora con FWH 1303, sin haber modificado el codigo, me aparece asi:

Ya he hecho muchas pruebas cambiando valores y no logro que se muestre como antes. Que mas se les ocurre que pueda hacer?

Salu2

RodolfoRBG
FWH 1307, xHarbour123 BCC582
rodolfoerbg@gmail.com

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: XBROWSE: No me aparecen los separadores de celdas
Posted: Sat May 18, 2013 08:22 AM

I tried to reproduce your problem here with FWH 13.03.
But I am able to see the lines in both Window and Dialog.
This is the test program I used. I just copied and pasted your function for the settings.

Code (fw): Select all Collapse

#include "fivewin.ch"
#include "xbrowse.ch"

function Main()

   local n

   USE CUSTOMER SHARED NEW // or any other DBF

   if ( n := Alert( "XBrowse in", { "Window", "Dialog" } ) ) == 1
      XbrInWindow()
   elseif n == 2
      XbrInDialog()
   endif

return 0

static function XbrInWindow()

   local oWnd, oBrw

   DEFINE WINDOW oWnd TITLE FWVERSION
   @ 0,0 XBROWSE oBrw OF oWnd DATASOURCE Alias() AUTOCOLS NOBORDER
   DefColoBrw( oBrw )
   oBrw:CreateFromCode()
   oWnd:oClient := oBrw

   ACTIVATE WINDOW oWnd

return nil

static function XbrInDialog()

   local oDlg, oBrw

   DEFINE DIALOG oDlg SIZE 600,300 PIXEL TITLE FWVERSION
   @ 10,10 XBROWSE oBrw SIZE -10, -10 PIXEL OF oDlg DATASOURCE Alias() AUTOCOLS NOBORDER
   DefColoBrw( oBrw )
   oBrw:CreateFromCode()

   ACTIVATE DIALOG oDlg CENTERED

return nil

FUNCTION DefColoBrw(oBrowse) //Objeto Browse
 oBrowse:lColDividerComplete:=.T. ; oBrowse:lRecordSelector:=.F.
 oBrowse:nHeaderLines:=1 ; oBrowse:nHeaderHeight:=20 ; oBrowse:nRowHeight:=18
 oBrowse:lHScroll:=.T. ; oBrowse:lVScroll:=.T.
 oBrowse:nMarqueeStyle:=5
 oBrowse:nColDividerStyle:=4 ; oBrowse:nRowDividerStyle:=4
 oBrowse:bClrSelFocus:={||{CLR_WHITE,CLR_CYAN}}
 oBrowse:bClrSel:={||{CLR_BLACK,CLR_HGRAY}}
RETURN(NIL)

These are the screen-shots:

DIALOG

WINDOW

Can you please test the sample I posted above as it is and provide feedback?

Regards

G. N. Rao.

Hyderabad, India

RodolfoRBG

Posts: 257

Joined: Tue May 16, 2006 04:46 PM

XBROWSE: No me aparecen los separadores de celdas.
Posted: Sat May 18, 2013 04:06 PM

G. N. Rao,

Muchas, muchas gracias por tu paciencia. YA FUNCIONO!!!

El problema estaba en que yo corria DefColoBrw(oBrw) despues de oBrw:CreateFromCode(). Lo puse antes, como en tu ejemplo, y ya funciono perfectamente.

Cosa rara pues en la version 1103 no era necesario eso. Gracias de nuevo.

Salu2

RodolfoRBG
FWH 1307, xHarbour123 BCC582
rodolfoerbg@gmail.com

FiveTech Support Forums

Continue the discussion