topic-26532

Posts: 652

Joined: Wed Oct 19, 2005 12:03 PM

xbrNumFormat
Posted: Mon Jun 10, 2013 11:00 PM

Hola en su momento consulte sobre xbrowse y Mr. Nageswaragunupudi me recomento utilizar esta función cuando usase xBrowse, pero el programa me muestra los resultados en formato Americano y sin los separadores de mil y sí el decimal. Aquí muestro todo el código para ver si me pueden ayudar con esto. Los ejemplos de fwh funcionan bien, pero aquí hay algo que no funciona.

Code (fw): Select all Collapse

#include "Fivewin.ch"
#include "xbrowse.ch"
#include "splitter.ch"
#include "report.ch"

STATIC octae

FUNCTION xBrwgen()

   LOCAL odlgx
   LOCAL oBrw, oSpli
   LOCAL nProa := 0
   LOCAL napea
   LOCAL aMae := Array( 0 )
   LOCAL oGet := Array( 7 )
   LOCAL beval  := {|| aMae := iif( Empty( nproa ), buspro(), buspro( nproa ) ), iif( Len( aMae ) > 0, ( nproa := aMae[ 1 ],napea := aMae[ 2 ],odlgx:update(),filtro(nproa,oBrw,oGet,oDlgx ), .T. ), odlgx:end() ) }
   LOCAL aSelGrad := { { .5, RGB( 255, 255, 251 ), RGB( 255, 237, 178 ) }, ;
      { .5, RGB( 255, 218, 103 ), RGB( 255, 233, 162 ) } }
   LOCAL aGradBarSel := { { .5,RGB( 255,255,251 ), RGB( 255, 196, 178 ) }, ;
      { .5, RGB( 255, 218, 103 ), RGB( 255, 233, 162 ) } }

   LOCAL nSaldo := 0
   LOCAL z := 0
   
   xbrNumFormat( "E", .t. )
    

   IF !pasaje( "CTAEXPO" );RETURN nil; ENDIF
   DATABASE oCtae
   oCtae:setorder( 1 )
   oCtae:beof := {|| nil }
   oCtae:bBoF := {|| nil }
   oCtae:setfilter( {|| ( oCtae:cAlias )->npro = 0 } )
   //oCtae:setfilter( "(oCtae:cAlias)->npro = 0 " )



   DEFINE DIALOG oDlgx resource "dia_xbrowse"


   REDEFINE GET oGet[ 1 ] VAR nproa id 121 of odlgx update VALID Eval( beval )
   REDEFINE GET oGet[ 2 ] VAR napea id 120 of odlgx update

   REDEFINE BTNBMP oGet[ 3 ] id 101 of oDlgx resource "btngastos", "btnastos1" ACTION ctaexpo( oCtae, oBrw, nproa, .T., .T. ) update
   REDEFINE BTNBMP oGet[ 4 ] id 102 of oDlgx resource "btnpagos", "btnpagos1" ACTION ctaexpo( oCtae, oBrw, nproa, .F., .T. ) update
   REDEFINE BTNBMP oGet[ 5 ] id 103 of oDlgx resource "btncambiar", "btncambiar1" ACTION ctaexpo( oCtae, oBrw, nproa, .T., .F. ) update
   REDEFINE BTNBMP oGet[ 6 ] id 104 of odlgx resource "BTNIMPRI", "BTNIMPRI1" ACTION Reporte( nProa, octae ) update
   REDEFINE BTNBMP oGet[ 7 ] id 105 of odlgx resource "BTNELIMINA", "BTNELIMINA1" ACTION BORRAR( nProa, octae, oBrw, odlgx ) update
   REDEFINE BTNBMP oGet[7] id 105 of oDlgx resource "BTNELIMINA","BTNELIMINA1" ACTION borrar(nProa,oCtae)

   FOR z = 3 TO 7
      oGet[ z ]:disable()
   NEXT

   REDEFINE SPLITTER oSpli ID 111 COLOR rgb( 234, 234, 234 )  of odlgx _3DLOOK



   REDEFINE XBROWSE oBrw ID 110 OF oDlgx DATASOURCE oCtae;
      COLUMNS ;
      { {|| If( oCtae:npro = nproa, oCtae:fecha,  "" ) } },  ;
      { {|| If( oCtae:npro = nproa, oCtae:factura, "" ) } },  ;
      { {|| If( oCtae:npro = nproa, oCtae:opera, "" ) } },  ;
      { {|| If( octae:npro = nProa .AND.   octae:lsumo, octae:importe, "" ) } },  ;
      { {|| If( octae:npro = nProa .AND.  !octae:lsumo, octae:importe, "" ) } },  ;
      { {|| If( oCtae:npro = nproa, oCtae:saldo, "" ) } } ;
      HEADERS "Fecha", "Comprobante", "Descripción", "Debe", "Haber", "Total";
      COLSIZES 80, 90, 190, 100, 100, 100;
      LINES CELL UPDATE
      
      oBrw:lDisplayZeros := .f.
      
 

   WITH OBJECT oBrw
      :lDisplayZeros := .F.
      :nMarqueeStyle := MARQSTYLE_HIGHLROWRC
      :nStretchCol := STRETCHCOL_WIDEST
      :bClrSel := {|| { nRGB(  0,  0,255 ),aGradBarSel } }
      :bClrSelFocus  := {|| { CLR_BLACK, aSelGrad } }
      :lColDividerComplete := .F.
      :lAllowColHiding := .F.
   END WITH

   WITH OBJECT oBrw:aCols[ 1 ]
      :bStrData := {|| oCtae:fecha }
      :nDataStrAlign := AL_RIGHT
   END WITH

   WITH OBJECT oBrw:aCols[ 2 ]
      :bStrData := {|| oCtae:factura }
      :nDataStrAlign := AL_RIGHT
   END WITH

   WITH OBJECT oBrw:aCols[ 3 ]
      :bStrData := {|| oCtae:opera }
      :nDataStrAlign := AL_LEFT
   END WITH

   WITH OBJECT oBrw:aCols[ 4 ]
      :bStrData := {|| iif( octae:lsumo, octae:importe,0)   }
      :nDataStrAlign := AL_RIGHT
   END WITH

   WITH OBJECT oBrw:aCols[ 5 ]
      :bStrData := {|| iif( !octae:lsumo, octae:importe, 0)  }
      :nDataStrAlign := AL_RIGHT
   END WITH

   WITH OBJECT oBrw:aCols[ 6 ]
      :bStrData := {|| octae:saldo }
      :nDataStrAlign := AL_RIGHT
   END WITH


   activate dialog odlgx

   cierroalias( oCtae:cAlias, oCtae )

RETURN NIL
/***************************************************************************/

Gracias

Luis

surGom

Posts: 652

Joined: Wed Oct 19, 2005 12:03 PM

Re: xbrNumFormat
Posted: Thu Jun 13, 2013 10:42 PM

Bueno ya el Sr Mr. Nageswaragunupudi me había mostrado el camino pero en su momento no lo vi, así funciona bien.

Code (fw): Select all Collapse

   xbrNumFormat( "E", .t. )
   
   DEFINE DIALOG oDlgx resource "dia_xbrowse"


   REDEFINE GET oGet[ 1 ] VAR nproa id 121 of odlgx update VALID Eval( beval )
   REDEFINE GET oGet[ 2 ] VAR napea id 120 of odlgx update

   REDEFINE BTNBMP oGet[ 3 ] id 101 of oDlgx resource "btngastos", "btnastos1" ACTION ctaexpo( oCtae, oBrw, nproa, .T., .T. ) update
   REDEFINE BTNBMP oGet[ 4 ] id 102 of oDlgx resource "btnpagos", "btnpagos1" ACTION ctaexpo( oCtae, oBrw, nproa, .F., .T. ) update
   REDEFINE BTNBMP oGet[ 5 ] id 103 of oDlgx resource "btncambiar", "btncambiar1" ACTION ctaexpo( oCtae, oBrw, nproa, .T., .F. ) update
   REDEFINE BTNBMP oGet[ 6 ] id 104 of odlgx resource "BTNIMPRI", "BTNIMPRI1" ACTION Reporte( nProa, octae ) update
   REDEFINE BTNBMP oGet[ 7 ] id 105 of odlgx resource "BTNELIMINA", "BTNELIMINA1" ACTION BORRAR( nProa, octae, oBrw, odlgx ) update
   //REDEFINE BTNBMP oGet[7] id 105 of oDlgx resource "BTNELIMINA","BTNELIMINA1" ACTION borrar(nProa,oCtae)

   FOR z = 3 TO 7
      oGet[ z ]:disable()
   NEXT

   REDEFINE SPLITTER oSpli ID 111 COLOR rgb( 234, 234, 234 )  of odlgx _3DLOOK



   REDEFINE XBROWSE oBrw ID 110 OF odlgx DATASOURCE octae;
      COLUMNS {1,2,3,4,5,6};
      HEADERS "Fecha", "Comprobante", "Descripción", "Debe", "Haber", "Total";
      COLSIZES 80, 90, 190, 100, 100, 100;
      LINES CELL UPDATE





   WITH OBJECT oBrw
      :lDisplayZeros := .F.
      :nMarqueeStyle := MARQSTYLE_HIGHLROWRC
      :nStretchCol := STRETCHCOL_WIDEST
      :bClrSel := {|| { nRGB(  0,  0,255 ),aGradBarSel } }
      :bClrSelFocus  := {|| { CLR_BLACK, aSelGrad } }
      :lColDividerComplete := .F.
      :lAllowColHiding := .F.
   END WITH

   WITH OBJECT oBrw:aCols[ 1 ]
      :bEditValue := {|| octae:fecha }
      :nDataStrAlign := AL_RIGHT
   END WITH

   WITH OBJECT oBrw:aCols[ 2 ]
      :bEditValue := {|| octae:factura }
   END WITH

   WITH OBJECT oBrw:aCols[ 3 ]
      :bEditValue := {|| octae:opera }
   END WITH

   WITH OBJECT oBrw:aCols[ 4 ]
      :bEditValue :={|| iif( octae:lsumo, octae:importe,0)   }
      :cEditPicture := NumPict( 12, 2 )
    END WITH

   WITH OBJECT oBrw:aCols[ 5 ]
      :bEditValue := {|| iif( !octae:lsumo, octae:importe, 0)  }
      :cEditPicture := NumPict( 12, 2 )
   END WITH

   WITH OBJECT oBrw:aCols[ 6 ]
      :bEditValue := {|| octae:saldo }
      :cEditPicture := NumPict( 12, 2 )
   END WITH


   activate dialog odlgx

   cierroalias( oCtae:cAlias, oCtae )

RETURN NIL

Si no declaro cEditpicture muestra por ej: 100000,00
De la forma correcta 100.000,00

Luis

FiveTech Support Forums

Continue the discussion