topic-28288

Posts: 17

Joined: Sat Nov 05, 2011 08:56 AM

Ambiente Metro.
Posted: Sat Apr 05, 2014 11:55 PM

No ambiente metro, existe a possibilidade de não mostrar a barra de scroll horizontal na parte de baixo da window ?

In the metro environment, there is the possibility of not showing the horizontal scroll bar at the bottom of the window? (google translator)

SAOliveira

Lins/SP - Brasil

Antonio Linares

Posts: 44158

Joined: Thu Oct 06, 2005 05:47 PM

Re: Ambiente Metro.
Posted: Sun Apr 06, 2014 06:30 AM

In the Class TMetroPanel (used from FWH samples/touch.prg) we simulate an horizontal scrollbar.

Where do you need to use it ? Just a standalone horizontal scrollbar ?

regards, saludos

Antonio Linares
www.fivetechsoft.com

SAOliveira

Posts: 17

Joined: Sat Nov 05, 2011 08:56 AM

Re: Ambiente Metro.
Posted: Mon Apr 07, 2014 09:44 AM

Antonio,

Grateful for your answer.

What I really want to do is not show the horizontal scroll bar in the main window.

.

SAOliveira

Lins/SP - Brasil

SAOliveira

Posts: 17

Joined: Sat Nov 05, 2011 08:56 AM

Re: Ambiente Metro.
Posted: Sun Apr 13, 2014 10:02 AM

Antônio.

Did unable to explain?

SAOliveira

Lins/SP - Brasil

cnavarro

Posts: 6755

Joined: Wed Feb 15, 2012 08:25 PM

Re: Ambiente Metro.
Posted: Sun Apr 13, 2014 11:24 AM

SAOliveira

MetroPnel, por defecto, pone el Scroll Horizontal si el número de botones ocupa más espacio que el ancho de pantalla
MetroPnel, by default, puts the Horizontal Scroll if the number of buttons occupies more space than the screen width

Usando el ejemplo de ..\Samples\metrptst.prg
Using the example .. \ Samples \ metrptst.prg

Yo lo he conseguido modificando la clase MetroPnel de la siguiente forma:
I've gotten modifying MetroPnel class as follows:

Crear una nueva DATA
Create a new DATA

Code (fw): Select all Collapse

DATA  lMHScroll  INIT .T.

In the Paint METHOD, modify

Code (fw): Select all Collapse

METHOD Paint() CLASS TMetroPanel

   local aInfo
   local oRect    := ::GetCliRect()
   local hScrollBrush, hThumbBrush
   local nBarTotal

   aInfo := ::DispBegin()

   FillRect( ::hDC, oRect:aRect, ::oBrush:hBrush )
   ::Say( ( ::nBtnSize - ::oFont:nHeight ) / 2, ::nMetroTop, ::cTitle,,, ::oFont, .t., .t. )

   if !::lMHScroll                                   // Aqui
      ::nScrollRange := 0
   endif

   if ::nScrollRange > 0
      hScrollBrush      := CreateSolidBrush( ::nClrScroll )
      hThumbBrush       := CreateSolidBrush( ::nClrThumb  )
      ::nThumbWidth     := Int( ::nThumbSize * ( oRect:nWidth - 120 ) )
      nBarTotal         := oRect:nWidth - 120 - ::nThumbWidth
      ::nThumbPos       := Int( Abs( ::nOffSet / ::nScrollRange ) * nBarTotal ) + 60
      oRect:nTop        := oRect:nBottom - SCRLB_HEIGHT
      oRect:nHeight     := SCRLB_HEIGHT
      ::nScrollBarTop   := oRect:nTop
      ::nScrollRatio    := ( ::nScrollRange / nBarTotal )

      FillRect( ::hDC, oRect:aRect, hScrollBrush )
      FillRect( ::hDC, { oRect:nTop, oRect:nLeft + ::nThumbPos, oRect:nBottom, ;
            oRect:nLeft + ::nThumbPos + ::nThumbWidth }, hThumbBrush )
      DeleteObject( hScrollBrush )
      DeleteObject( hThumbBrush )

      MoveTo( ::hDC, oRect:nLeft + 32, oRect:nTop +  4 )
      LineTo( ::hDC, oRect:nLeft + 24, oRect:nTop + 10, ::hPen )
      LineTo( ::hDC, oRect:nLeft + 32, oRect:nTop + 16, ::hPen )

      MoveTo( ::hDC, oRect:nRight - 32, oRect:nTop +  4 )
      LineTo( ::hDC, oRect:nRight - 24, oRect:nTop + 10, ::hPen )
      LineTo( ::hDC, oRect:nRight - 32, oRect:nTop + 16, ::hPen )

   else
      if ::lMHScroll                                                  // Aqui
         ::nScrollBarTop   := oRect:nBottom + 2
      endif
   endif

.../...

and the METHOD Arrange, modify

Code (fw): Select all Collapse

.../...

   next nGroup

   ::nMetroWidth     := nGrpRight - ::nOffSet

   if ::lMHScroll                                               // Aqui
      ::nScrollRange    := Max(( ::nMetroWidth - ScreenWidth() ), ::nScrollRange )
      ::nScrollRange    := Max( 0, ::nScrollRange )
   endif

   ::nThumbSize      := 1 - ( ::nScrollRange / ::nMetroWidth )
   ::lArranged := .t.

return Self

Instructions for use ( Using the example .. \ Samples \ metrptst.prg )

Code (fw): Select all Collapse

function Main( cParam )

   local oWnd, oBar, oMetro, oBrush
   local cTitle := "Start"

   SET DATE ITALIAN
   SET CENTURY ON

   DEFINE WINDOW oWnd TITLE cTitle STYLE nOr( WS_POPUP, WS_MAXIMIZE );
      COLOR CLR_WHITE, CLR_GREEN

   oMetro   := MakeMetroPanel( oWnd )

   oMetro:lMHScroll := .F.         // Aqui

   .../....

Cristobal Navarro

Hay dos tipos de personas: las que te hacen perder el tiempo y las que te hacen perder la noción del tiempo

El secreto de la felicidad no está en hacer lo que te gusta, sino en que te guste lo que haces

SAOliveira

Posts: 17

Joined: Sat Nov 05, 2011 08:56 AM

Re: Ambiente Metro.
Posted: Mon Apr 14, 2014 01:40 PM

Very good.

Tanks

SAOliveira

Lins/SP - Brasil

Antonio Linares

Posts: 44158

Joined: Thu Oct 06, 2005 05:47 PM

Re: Ambiente Metro.
Posted: Mon Apr 14, 2014 05:01 PM

Cristobal,

many thanks for your help as usual :-)

regards, saludos

Antonio Linares
www.fivetechsoft.com

FiveTech Support Forums

Continue the discussion