topic-28990

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Outlook Express / Windows Live Mail
Posted: Tue Aug 05, 2014 03:24 PM

Señores, necesito un poco de ayuda, por favor.

Outlook Express / Windows Live Mail:

Si usted no tiene instalado Outlook Express o Windows Live Mail, ¿cómo hacer para enviar correo electrónico, por ejemplo, mi ERRSYSW.PRG, se prepara para en caso de rotura, envíe un correo electrónico a mí en silencio sin que el usuario lo sepa. Pero si: Outlook Express o Windows Live Mail no se instalan por defecto, y el programa no envía.

¿Cómo debo hacer?

Gracias de colaboraciones anticipadas.

Saludos.

En Português:

Senhores, Necessito de uma ajuda, por favor.

Outlook Express/Windows Live Mail:

Se não tem Outlook Express ou Windows Live Mail Instalado, como que vocês fazem para ENVIAR EMAIL, por exemplo, meu ERRSYSW.PRG, está preparado para em caso de quebra, enviar um email silencioso para mim, sem que o usuário saiba. Mas, se: Outlook Express ou Windows Live Mail não estiverem instalados e como padrão, o programa não envia.

Como devo fazer?

Agradeço desde já as colaborações.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

hmpaquito

Posts: 1515

Joined: Thu Oct 30, 2008 02:37 PM

Re: Outlook Express / Windows Live Mail
Posted: Tue Aug 05, 2014 03:40 PM

Karinha,

Use cdosys: le sorprenderá ! En el foro hay innumerables ejemplos de ello.

Saludos

karinha

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Re: Outlook Express / Windows Live Mail
Posted: Tue Aug 05, 2014 06:48 PM

Gracias hmpaquito, sabeis donde puedo bajar CDOSYS.CH?

No tiens un ejemplo autocontenido?

Saludos.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

Enrrique Vertiz

Posts: 582

Joined: Fri Oct 07, 2005 02:17 PM

Re: Outlook Express / Windows Live Mail
Posted: Tue Aug 05, 2014 09:34 PM

Saludos Karinha

Puedes usar GMAIL, aqui un ejemplo :

Code (fw): Select all Collapse

//----------------------------------- Envio de Mails via GMAIL o Mail SMTP del Cliente ------------------------------------//
Function sendmail(cDestino,cSubject,cMessage,cFile1,cFile2)
Local oEmailCfg, oEmailMsg, oError, cHtml

public cServer:="", cPuerto:="", cUsrMail:="", cUsrPass:="", nPuerto:=0, cCopia:="", cCopiaO:=""

LoadSmtp( ".\Smtp.ini" )  // Levantar valores para la cuenta desde donde se envian mails
MsgOpen("Enviando "+cSubject+" a : "+cDestino,"Desde : "+cServer+" - "+alltrim(str(nPuerto))+" - "+cUsrMail)
cDocs:=""

cHtml:='<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">'
cHtml+='<HTML><HEAD>'
cHtml+='<META content="text/html; charset=iso-8859-1" http-equiv=Content-Type>'
cHtml+='<META name=GENERATOR content="MSHTML 8.00.6001.18783">'
cHtml+='<STYLE></STYLE>'
cHtml+='</HEAD>'
cHtml+='<BODY bgColor=#ffffff>'
cHtml+='<DIV><FONT size=2 face=Arial>'+cDocs+'</FONT></DIV></BODY></HTML>'  // cDocs incluira todo el cuerpo del Mail, ver como llenarlo

TRY
  oEmailCfg := CREATEOBJECT( "CDO.Configuration" )
  WITH OBJECT oEmailCfg:Fields
     :Item( "http://schemas.microsoft.com/cdo/configuration/smtpserver" ):Value := alltrim(cServer)
     :Item( "http://schemas.microsoft.com/cdo/configuration/smtpserverport" ):Value := nPuerto       // Donde 465 es paga GMAIL y 25 es (por ejemplo) para mail.xxxx.com
     :Item( "http://schemas.microsoft.com/cdo/configuration/sendusing" ):Value := 2   // Remote SMTP = 2, local = 1
     :Item( "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate" ):Value := .T.
     if AT("gmail",lower(alltrim(cUsrMail))) > 0  // Si es gmail
        :Item( "http://schemas.microsoft.com/cdo/configuration/smtpusessl" ):Value := .T.
     else                                         // Si NO es gmail
        :Item( "http://schemas.microsoft.com/cdo/configuration/smtpusessl" ):Value := .F.
     end if
     :Item( "http://schemas.microsoft.com/cdo/configuration/sendusername" ):Value := alltrim(cUsrMail)
     :Item( "http://schemas.microsoft.com/cdo/configuration/sendpassword" ):Value := alltrim(cUsrPass) // Password
     :Item( "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"):Value := 30
     :Update()
  END WITH
CATCH oError
  MsgInfo( "Could not send message" + ";"  + ;
         "Error: " + TRANSFORM(oError:GenCode, NIL) + ";" + ;
         "SubC: " + TRANSFORM(oError:SubCode, NIL) + ";" + ;
         "OSCode: " + TRANSFORM(oError:OsCode, NIL) + ";" + ;
         "SubSystem: " + TRANSFORM(oError:SubSystem, NIL) + ";" + ;
         "Message: " + oError:Description )
END
oError:=NIL

TRY
    oEmailMsg := CREATEOBJECT ( "CDO.Message" )  // 
    WITH OBJECT oEmailMsg
        :Configuration = oEmailCfg
        :From = chr(34)+"Mi Mail "+chr(34)+ "<"+alltrim(cUsrMail)+">" // This will be displayed in the From (The email id does not appear)
        :To   = cDestino    // <-----   Mail de destino
        :CC   = cCopia      // Mail si queremos copia
        :BCC  = cCopiaO     // Mail si queremos copia Oculta
        :Subject = alltrim(cSubject)
        :HTMLBody = cHtml
        :AddAttachment(cFile1)    //  Incluir adjuntos
        :AddAttachment(cFile2)
    END WITH
    oEmailMsg:Send()
CATCH oError
    MsgInfo("Could not send message" + ";"  + CRLF+ ;
            "Error: " + TRANSFORM(oError:GenCode, NIL) + ";" + CRLF+;
            "SubC: "  + TRANSFORM(oError:SubCode, NIL) + ";" + CRLF+ ;
            "OSCode: "+ TRANSFORM(oError:OsCode, NIL) + ";" + CRLF +;
            "SubSystem: " + TRANSFORM(oError:SubSystem, NIL) + ";" +CRLF+ ;
            "Message: " + oError:Description )
END
MsgClose()
retu .t.

Enrrique Vertiz Pitta

Lima-Peru

xHb 1.23.1026X, Fwh 25.01, BCC74, MySQL 8.0.X, SQLLIB 1.9m

FiveTech Support Forums

Continue the discussion