Good Morning Mr. Rao:
Dou you have, or where can I find, a sample using xBrowse with FASTEDIT (ADD, DELETE, CHANGE), ADO
and MySql?.
Thanks and Regards
Antonio:
Muchas gracias, voy a "echarles un ojo", si alguien más tiene
otro ejemplo pues bienvenido.
Saludos
#include "fivewin.ch"
#include "adodef.ch"
REQUEST DBFCDX
static cDbf := "c:\\fwh\\samples\\customer.dbf" //
// Substitute your
static cServer := "localhost" // values
static cDatabase := "FWH" //
static cUser := "root" //
static cPassword := "secret" //
static cTable := "CUSTOMER" //
//----------------------------------------------------------------------------//
function Main()
local uTable
SET DATE ITALIAN
SET CENTURY ON
SET DELETED ON
FWNumFormat( "E", .t. )
uTable := OpenTable()
BrowseTable( uTable )
CloseTable( uTable )
return nil
//----------------------------------------------------------------------------//
// This XBrowse Code is exactly the same for DBF, ADO, etc
// Works the same way for browse with all features and also
// Add/Edit Dialogs irrespective of the datasource ( DBF/ADO/etc )
//----------------------------------------------------------------------------//
static function BrowseTable( uTable )
local oWnd, oFont, oBrw
DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
DEFINE WINDOW oWnd
oWnd:SetFont( oFont )
DEFINE BUTTONBAR oWnd:oBar SIZE 80,32 2007
DEFINE BUTTON OF oWnd:oBar PROMPT "Add" ACTION oBrw:EditSource( .t. )
DEFINE BUTTON OF oWnd:oBar PROMPT "Edit" ACTION oBrw:EditSource()
DEFINE BUTTON OF oWnd:oBar PROMPT "Delete" ACTION oBrw:Delete()
DEFINE BUTTON OF oWnd:oBar PROMPT "Report" ACTION oBrw:Report() GROUP
DEFINE BUTTON OF oWnd:oBar PROMPT "Excel" ACTION oBrw:ToExcel()
@ 0,0 XBROWSE oBrw OF oWnd DATASOURCE uTable AUTOCOLS ;
CELL LINES FOOTERS FASTEDIT AUTOSORT
WITH OBJECT oBrw
:SetChecks()
:nEditTypes := EDIT_GET
:CreateFromCode()
END
oWnd:oClient := oBrw
ACTIVATE WINDOW oWnd MAXIMIZED
RELEASE FONT oFont
return nil
//----------------------------------------------------------------------------//
// The above code is all that is required for a full table maintenance
//----------------------------------------------------------------------------//
static function OpenTable()
local oCn, uTable
local nDataSource := Alert( "Select DataSource", { "MYSQL", "DBF" } )
if nDataSource == 1 // MYSQL
ADOCONNECT oCn TO MYSQL SERVER ( cServer ) DATABASE ( cDatabase ) USER ( cUser ) PASSWORD ( cPassword )
if oCn != nil
uTable := FW_OpenRecordSet( oCn, cTable )
if uTable == nil
oCn:Close()
? "Table Open Error"
QUIT
endif
endif
else
USE ( cDbf ) SHARED NEW VIA "DBFCDX"
if USED()
uTable := Alias()
else
? "Table Open Error"
QUIT
endif
endif
return uTable
//----------------------------------------------------------------------------//
static function CloseTable( uTable )
if ValType( uTable ) == 'C'
CLOSE ( uTable )
else
uTable:Close()
uTable:ActiveConnection:Close()
endif
return nil
//----------------------------------------------------------------------------//
Mr. Rao:
Thanks a lot for your sample, It's very clear, I'l try it, although I was thinking in FASTEDIT
xBrowse sample, however this example can help me.
My tools are, FWH1312, BCC582, Harbour/xHarbour and MySql 5.1
Best regards
Armando wrote:Mr. Rao:
Thanks a lot for your sample, It's very clear, I'l try it, although I was thinking in FASTEDIT
xBrowse sample, however this example can help me.
My tools are, FWH1312, BCC582, Harbour/xHarbour and MySql 5.1
Best regards
#include "fivewin.ch"
#include "adodef.ch"
REQUEST DBFCDX
static cDbf := "c:\\fwh\\samples\\customer.dbf" // substitute your dbf na,e
// Replace this with your connection string
static cConnStr := "Driver={MySQL ODBC 5.3 ANSI Driver};Server=localhost;Database=FWH;User=root;Password=secret;Option=3;"
static cTable := "CUSTOMER" // Substitute your table name
//----------------------------------------------------------------------------//
function Main()
local uTable
SET DATE ITALIAN
SET CENTURY ON
SET DELETED ON
FWNumFormat( "E", .t. )
uTable := OpenTable()
BrowseTable( uTable )
CloseTable( uTable )
return nil
//----------------------------------------------------------------------------//
// This XBrowse Code is exactly the same for DBF, ADO, etc
// Works the same way for browse with all features and also
// Add/Edit Dialogs irrespective of the datasource ( DBF/ADO/etc )
//----------------------------------------------------------------------------//
static function BrowseTable( uTable )
local oWnd, oFont, oBrw
DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
DEFINE WINDOW oWnd
oWnd:SetFont( oFont )
DEFINE BUTTONBAR oWnd:oBar SIZE 80,32 2007
DEFINE BUTTON OF oWnd:oBar PROMPT "Add" ACTION oBrw:EditSource( .t. )
DEFINE BUTTON OF oWnd:oBar PROMPT "Edit" ACTION oBrw:EditSource()
DEFINE BUTTON OF oWnd:oBar PROMPT "Delete" ACTION oBrw:Delete()
DEFINE BUTTON OF oWnd:oBar PROMPT "Report" ACTION oBrw:Report() GROUP
DEFINE BUTTON OF oWnd:oBar PROMPT "Excel" ACTION oBrw:ToExcel()
@ 0,0 XBROWSE oBrw OF oWnd DATASOURCE uTable AUTOCOLS ;
CELL LINES FOOTERS FASTEDIT AUTOSORT
WITH OBJECT oBrw
AEval( :aCols, { |o| If( o:cDataType == 'L', o:SetCheck(), nil ) } )
:nEditTypes := EDIT_GET
:CreateFromCode()
END
oWnd:oClient := oBrw
ACTIVATE WINDOW oWnd MAXIMIZED
RELEASE FONT oFont
return nil
//----------------------------------------------------------------------------//
// The above code is all that is required for a full table maintenance
//----------------------------------------------------------------------------//
static function OpenTable()
local oCn, uTable, cStr
local nDataSource := Alert( "Select DataSource", { "MYSQL", "DBF" } )
if nDataSource == 1 // MYSQL
oCn := FW_OpenadoConnection( cConnStr, .t. )
if oCn != nil
uTable := FW_OpenRecordSet( oCn, cTable )
endif
if uTable == nil
? "Table Open Error"
QUIT
endif
else
USE ( cDbf ) SHARED NEW VIA "DBFCDX"
if USED()
uTable := Alias()
else
? "Table Open Error"
QUIT
endif
endif
return uTable
//----------------------------------------------------------------------------//
static function CloseTable( uTable )
if ValType( uTable ) == 'C'
CLOSE ( uTable )
else
uTable:Close()
uTable:ActiveConnection:Close()
endif
return nil
//----------------------------------------------------------------------------//nageswaragunupudi wrote:I modified the program for 13.12.
I suggest you give your full working connection string in the static variable at the beginning of the program.
After you test this sample, you may ask how to handle more complex situations and we shall be glad to support you.