FiveTech Support Forums

FiveWin / Harbour / xBase community
Board indexActive topicsAll discussionsLogin (GitHub)
Board index FiveWin para Harbour/xHarbour ERROR TOLEAUTO/-1 UNKNOWN ERROR: TOLEAUTO:NEW
karinha
Posts: 8523
Joined: Tue Dec 20, 2005 07:36 PM
ERROR TOLEAUTO/-1 UNKNOWN ERROR: TOLEAUTO:NEW
Posted: Tue Mar 17, 2015 02:56 PM
Code (fw): Select all Collapse
   Descricao do Erro: ERROR TOLEAUTO/-1  UNKNOWN ERROR: TOLEAUTO:NEW
   Argumentos:
     [   1] = C   InternetExplorer.Application

Lista dos Erros
===============
   Erro em:  => THROW(0)
   Erro em: win32ole.prg => TOLEAUTO:NEW(309)
   Erro em: win32ole.prg => CREATEOBJECT(67)
   Erro em: DBMANUT2.prg => NFE_CHECAPORTAL(977)


Linha 977 quebra quando eu clicko pela segunda vez para entrar no portal???

Linea 977:

Code (fw): Select all Collapse
 oOle:= CreateObject("InternetExplorer.Application")  // quebra aqui


Codigo usado:

Code (fw): Select all Collapse
FUNCTION NFe_ChecaPortal( f_cChave, f_nPortal )

   LOCAL oOle, oOleDoc := Array(2)

   Default f_nPortal := 1, f_cChave := ""

   HB_GCALL( .F. )

   oOle:= CreateObject("InternetExplorer.Application")  // quebra aqui
   oOle:Visible   := .T. // Apresenta o Browser
   oOle:ToolBar   := .F. // Desativa a barra de ferramentas
   oOle:StatusBar := .F. // Desativa a barra de status
   oOle:MenuBar   := .F. // desativa a barra de menu

   If f_nPortal == 1

      oOle:Navigate2("http://www.nfe.fazenda.gov.br/portal/consulta.aspx?tipoConsulta=completa&tipoConteudo=XbSeqxE8pl8=")

   Else  // Portal Estadual

      oOle:Navigate("http://nfe.fazenda.sp.gov.br/ConsultaNFe/consulta/publica/ConsultarNFe.aspx") // Abre o site

   EndIf

   // Maximiza o Internet explorer
   hWnd:=oOle:hWnd

   //ShowWindow(hWnd, 3 )         //SW_MAXIMIZE=3 SW_NORMAL=1 SW_MINIMIZE=6
   ShowWindow(hWnd, 1 )         //SW_MAXIMIZE=3 SW_NORMAL=1 SW_MINIMIZE=6

   BringWindowToTop(hWnd)

   WHILE oOle:Busy

      SysWait(.5)

   END

   If f_nPortal == 1  // Portal Nacional

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentPlaceHolder1$txtChaveAcessoCompleta",0):Value := f_cChave

   Else  // portal de Sao Paulo

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentMain$tbxIdNFe"):Value := f_cChave

   EndIf

   SysRefresh()

   oOle:Close()

return( .T. )


Obg. abs.

Saludos
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
Antonio Linares
Posts: 44162
Joined: Thu Oct 06, 2005 05:47 PM
Re: ERROR TOLEAUTO/-1 UNKNOWN ERROR: TOLEAUTO:NEW
Posted: Tue Mar 17, 2015 03:32 PM

Joao,

En vez de usar CreateObject( "InternetExplorer.Application" ) usa FWGetOleObject( "InternetExplorer.Application" )

oOle := FWGetOleObject("InternetExplorer.Application")

regards, saludos

Antonio Linares
www.fivetechsoft.com
karinha
Posts: 8523
Joined: Tue Dec 20, 2005 07:36 PM
Re: ERROR TOLEAUTO/-1 UNKNOWN ERROR: TOLEAUTO:NEW
Posted: Tue Mar 17, 2015 03:58 PM
Antonio Linares wrote:Joao,

En vez de usar CreateObject( "InternetExplorer.Application" ) usa FWGetOleObject( "InternetExplorer.Application" )

oOle := FWGetOleObject("InternetExplorer.Application")



Master estoy usando una version antigua de FWH(FWH2.7) para unos clientes que aún usam WINDOWS XP con poca memória.

No tengo está funcion:

Code (fw): Select all Collapse
'_HB_FUN_FWGETOLEOBJECT' referenced from C:\PLENOXP2


Mismo asi, muchas gracias.

Saludos.
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
Antonio Linares
Posts: 44162
Joined: Thu Oct 06, 2005 05:47 PM
Re: ERROR TOLEAUTO/-1 UNKNOWN ERROR: TOLEAUTO:NEW
Posted: Tue Mar 17, 2015 04:02 PM
Basicamente haz esto:

Code (fw): Select all Collapse
      TRY
         oObj  := GetActiveObject( "InternetExplorer.Application" )
      CATCH
         TRY
            oObj  := CreateObject( "InternetExplorer.Application" )
         CATCH
         END
      END
regards, saludos

Antonio Linares
www.fivetechsoft.com
karinha
Posts: 8523
Joined: Tue Dec 20, 2005 07:36 PM
Re: ERROR TOLEAUTO/-1 UNKNOWN ERROR: TOLEAUTO:NEW
Posted: Tue Mar 17, 2015 04:13 PM
Master:

Code (fw): Select all Collapse
   Descricao do Erro: ERROR BASE/1005  CLASS: 'NIL' HAS NO PROPERTY: TOOLBAR
   Argumentos:
     [   1] = L   .F.

Lista dos Erros
===============
   Erro em:  => _TOOLBAR(0)
   Erro em: DBMANUT2.prg => NFE_CHECAPORTAL(989)
   Erro em: DBMANUT.prg => (b)MOSTRA_CHAVE_NFE(7217)



Code (fw): Select all Collapse
FUNCTION NFe_ChecaPortal( f_cChave, f_nPortal )  // VEM DE DBMANUT.PRG

   LOCAL oOle, oOleDoc := Array(2)

   Default f_nPortal := 1, f_cChave := ""

   HB_GCALL( .F. )

   // oOle:= CreateObject("InternetExplorer.Application")  // Quebrando aqui
   // oOle := FWGetOleObject("InternetExplorer.Application")

   TRY
      oObj  := GetActiveObject( "InternetExplorer.Application" )
   CATCH
      TRY
         oObj  := CreateObject( "InternetExplorer.Application" )
      CATCH
      END
   END

   oOle:ToolBar   := .F. // Desativa a barra de ferramentas
   oOle:StatusBar := .F. // Desativa a barra de status
   oOle:MenuBar   := .F. // desativa a barra de menu

   If f_nPortal == 1

      oOle:Navigate2("http://www.nfe.fazenda.gov.br/portal/consulta.aspx?tipoConsulta=completa&tipoConteudo=XbSeqxE8pl8=")

   Else  // Portal Estadual

      oOle:Navigate("http://nfe.fazenda.sp.gov.br/ConsultaNFe/consulta/publica/ConsultarNFe.aspx") // Abre o site

   EndIf

   // Maximiza o Internet explorer
   hWnd:=oOle:hWnd

   //ShowWindow(hWnd, 3 )         //SW_MAXIMIZE=3 SW_NORMAL=1 SW_MINIMIZE=6
   ShowWindow(hWnd, 1 )         //SW_MAXIMIZE=3 SW_NORMAL=1 SW_MINIMIZE=6

   BringWindowToTop(hWnd)

   WHILE oOle:Busy

      SysWait(.5)

   END

   If f_nPortal == 1  // Portal Nacional

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentPlaceHolder1$txtChaveAcessoCompleta",0):Value := f_cChave

   Else  // portal de Sao Paulo

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentMain$tbxIdNFe"):Value := f_cChave

   EndIf

   SysRefresh()

   oOle := Nil

return( .T. )


Saludos.
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
karinha
Posts: 8523
Joined: Tue Dec 20, 2005 07:36 PM
Re: ERROR TOLEAUTO/-1 UNKNOWN ERROR: TOLEAUTO:NEW
Posted: Tue Mar 17, 2015 06:35 PM
Gracias Master, Resuelto.

Code (fw): Select all Collapse
FUNCTION NFe_ChecaPortal( f_cChave, f_nPortal )  // VEM DE DBMANUT.PRG

   LOCAL oOle, oOleDoc := Array(2)

   Default f_nPortal := 1, f_cChave := ""

   HB_GCALL( .F. )

   TRY

      oOLE := GetActiveObject( "InternetExplorer.Application" )

   CATCH

      TRY
         oOLE := CreateObject( "InternetExplorer.Application" )

      CATCH

         MsgInfo( "ERRO no Internet Explorer", "Erro no IE" )

         RETURN NIL

      END

   END

   oOLE:Visible   := .F.
   oOle:ToolBar   := .F. // Desativa a barra de ferramentas
   oOle:StatusBar := .F. // Desativa a barra de status
   oOle:MenuBar   := .F. // desativa a barra de menu

   If f_nPortal == 1  // Portal do Governo Federal

      oOle:Navigate2("http://www.nfe.fazenda.gov.br/portal/consulta.aspx?tipoConsulta=completa&tipoConteudo=XbSeqxE8pl8=")

   Else  // Portal do Estado de Sao Paulo

      oOle:Navigate("http://nfe.fazenda.sp.gov.br/ConsultaNFe/consulta/publica/ConsultarNFe.aspx") // Abre o site

   EndIf

   // Maximiza o Internet explorer
   hWnd := oOle:hWnd

   ShowWindow( hWnd, 1 )  // SW_MAXIMIZE=3 SW_NORMAL=1 SW_MINIMIZE=6

   BringWindowToTop(hWnd)

   WHILE oOLE:Busy

      HB_IDLESLEEP( .5 )

   ENDDO

   If f_nPortal == 1  // Portal Nacional

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentPlaceHolder1$txtChaveAcessoCompleta",0):Value := f_cChave

   Else  // portal de Sao Paulo

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentMain$tbxIdNFe"):Value := f_cChave

   EndIf

   SysRefresh()

   //oOle:Quit()
   oOle := Nil

RETURN NIL


Saludos.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
Antonio Linares
Posts: 44162
Joined: Thu Oct 06, 2005 05:47 PM
Re: ERROR TOLEAUTO/-1 UNKNOWN ERROR: TOLEAUTO:NEW
Posted: Wed Mar 18, 2015 07:48 AM

Muy bien :-)

regards, saludos

Antonio Linares
www.fivetechsoft.com

Continue the discussion

Static archive · New replies & topics via GitHub Discussions