topic-30411

Posts: 555

Joined: Wed Jul 31, 2013 01:14 PM

Datasource con bitmap para seleccionar
Posted: Fri Mar 20, 2015 12:55 AM

Estimados quisiera poder seleccionar 2 registros.

REDEFINE XBROWSE MBrw ID 110 OF xDlg8 ;
DATASOURCE DBLISTA AUTOSORT CELL LINES NOBORDER ;
COLUMNS " ", "P_NR" , "P_NOM", "P_UBI"

mBrw:nMarqueeStyle := MARQSTYLE_HIGHLROW
for nFor := 1 to len(aCols)
mBrw:aCols[ nFor ]:bRClickData := {|| (ESeleccionar(),mBrw:refresh() ) }
mBrw:aCols[ nFor ]:bRClickHeader := {|r,c,f,o| NIL }
next

With OBJECT mBrw
mBrw:aCols[1] := { || IIF(ASCAN(aSeleccion, Str((DBLISTA)->(RecNo()) )+"-"+(DBLISTA)->p_nr) = 0,1,2 ) }
End

Gracias.

Ruben Dario Fernandez

Dario Fernandez

FWH 2501, Harbour, MVS2022 Community, MySql & MariaDB, Dbf/Cdx VSCode.

Maldonado - Uruguay

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: Datasource con bitmap para seleccionar
Posted: Fri Mar 20, 2015 02:28 PM

Please try this test program

Code (fw): Select all Collapse

function testxbr()

   local oDlg, oFont, oBrw
   local cFwhFolder  := "c:\fwh\"
   local aSelected := {}

   USE ( cFwhFolder + "SAMPLES\STATES" ) NEW SHARED

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 400,400 PIXEL FONT oFont

   @ 10,10 XBROWSE oBrw SIZE -10,-10 PIXEL OF oDlg ;
      DATASOURCE "STATES" ;
      COLUMNS { || AScan( aSelected, RECNO() ) > 0 }, ;
              "CODE", "NAME" ;
      HEADERS " " ;
      LINES NOBORDER

   oBrw:nMarqueeStyle := MARQSTYLE_HIGHLROW

   oBrw:bRClicked := { |x| x := AScan( aSelected, oBrw:BookMark ), ;
                          If( x == 0, AAdd( aSelected, oBrw:BookMark ), ;
                                      ADel( aSelected, x, .t. ) ), ;
                          oBrw:RefreshCurrent() }

   oBrw:aCols[ 1 ]:SetCheck( { cFwhFolder + "bitmaps\16x16\yes.bmp", cFwhFolder + "bitmaps\16x16\cancel.bmp" } )
   oBrw:aCols[ 1 ]:nHeadBmpNo := 2

   oBrw:CreateFromCode()

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

Regards

G. N. Rao.

Hyderabad, India

D.Fernandez

Posts: 555

Joined: Wed Jul 31, 2013 01:14 PM

Re: Datasource con bitmap para seleccionar
Posted: Sat Mar 21, 2015 03:10 AM

Excelente Rao, muchas gracias.

Saludos
Ruben Dario Fernandez

Dario Fernandez

FWH 2501, Harbour, MVS2022 Community, MySql & MariaDB, Dbf/Cdx VSCode.

Maldonado - Uruguay

FiveTech Support Forums

Continue the discussion