FiveTech Support Forums

/*
*  Dialog en Recursos en ejemplo Testxbr3.prg
*/

#include "FiveWin.Ch"
#include "XBrowse.Ch"


REQUEST DBFCDX
MEMVAR  cExpr

static oCon
static cPrg, cFunc

Function RddBrwRes()

   local oDlg, oBrw, oCol, cAlias := cGetNewAlias( "CUST" )
   local aGrad := {{ 0.50, CLR_RED, CLR_YELLOW }, { 0.50, CLR_YELLOW, CLR_RED }}

   cFunc := ProcName( 0 )

   USE CUSTOMER NEW ALIAS (cAlias) SHARED VIA "DBFCDX"
   SET ORDER TO TAG FIRST
   GO TOP

   DEFINE DIALOG oDlg RESOURCE "TEST" //FONT WndMain():oFont

   REDEFINE XBROWSE oBrw ID 101 OF oDlg ;
      COLUMNS "First", "Salary" ;
      FIELDS (cAlias)->State, (cAlias)->Age ;
      HEADERS nil, nil, "State", "AGE" ;
      JUSTIFY .F., nil, .F., .T. ;
      ALIAS cAlias AUTOSORT LINES CELL ;
      BACKGROUND aGrad HORIZONTAL

   ADD TO oBrw DATA (cAlias)->CITY HEADER "City" CARGO { 1, 2 }

   oBrw:bPopUp    := { |o| ColMenu( o ) }
   AEval( oBrw:aCols, { |o| o:cToolTip := { 'Column :' + CRLF + o:cHeader, 'ToolTip' } } )

   ACTIVATE DIALOG oDlg CENTERED ON INIT oBrw:SetFocus()

   (cAlias)->( dbCloseArea() )

return nil

//----------------------------------------------------------------------------//

static function ColMenu( ocol )

   local oPop

   MENU oPop POPUP 2007
      MENUITEM "Left Align" WHEN oCol:nDataStrAlign > 0 ;
         ACTION ( oCol:SetAlign( AL_LEFT ), oCol:oBrw:SetFocus() )
      MENUITEM "Center Align" WHEN oCol:nDataStrAlign != AL_CENTER ;
         ACTION ( oCol:SetAlign( AL_CENTER ), oCol:oBrw:SetFocus() )
      MENUITEM "Right Align" WHEN oCol:nDataStrAlign != AL_RIGHT ;
         ACTION ( oCol:SetAlign( AL_RIGHT ), oCol:oBrw:SetFocus() )
      MENUITEM "Freeze" ACTION ( oCol:oBrw:nFreeze := oCol:nPos, oCol:oBrw:Refresh(), oCol:oBrw:SetFocus() )
      MENUITEM "Stretch" ACTION ( oCol:oBrw:nStretchCol := oCol:nCreationOrder, oCol:oBrw:Refresh(), ;
                        oCol:oBrw:SetFocus() )

      MENUITEM 'Edit' ;
         WHEN { |o| o:SetCheck( oCol:nEditType > 0 ), .t. } ;
         ACTION ( oCol:nEditType := If( oCol:nEditType > 0, 0, 1 ), ;
                  oMenuItem:SetCheck( oCol:nEditType > 0 ), ;
                  oCol:oBrw:SetFocus() )

   ENDMENU

return oPop