topic-32156

Posts: 3022

Joined: Fri Oct 07, 2005 01:45 PM

Spell Checker
Posted: Thu Mar 24, 2016 02:13 PM

For many years I have included the Wintertree spell checker in 32 bit applications. Now that I want to start working with 64 bit, I need the proper library. To upgrade that spell checker is $700 US and it simply is not in our budget.

Is anyone using a different spell checker in their FWH applications ? I'm looking for something more reasonably priced that has both a 32 bit and 64 bit library.

Thanks in advance for your input.

Tim

Tim Stone
http://www.MasterLinkSoftware.com
http://www.autoshopwriter.com
timstone@masterlinksoftware.com
Using: FWH 23.10 with Harbour 3.2.0 / Microsoft Visual Studio Community 2022-24 32/64 bit

Armando

Posts: 3358

Joined: Fri Oct 07, 2005 08:20 PM

Re: Spell Checker
Posted: Thu Mar 24, 2016 04:31 PM

Tim:

I use the spell checker included in MS-WORD.

Regards

SOI, s.a. de c.v.
estbucarm@gmail.com
http://www.soisa.mex.tl/
http://sqlcmd.blogspot.com/
Tel. (722) 174 44 45
Carpe diem quam minimum credula postero

Otto

Posts: 6983

Joined: Fri Oct 07, 2005 07:07 PM

Re: Spell Checker
Posted: Fri Mar 25, 2016 09:13 PM

Armando,
would you be so kind to show us how to use the word spell checker with Fivewin.
Thanks in advance
Otto

RAMESHBABU

Posts: 654

Joined: Fri Oct 21, 2005 05:54 AM

Re: Spell Checker
Posted: Sat Mar 26, 2016 01:14 AM

Mr.Otto,

I use MS Word spell checker using this Code.

Code (fw): Select all Collapse

#include "fivewin.ch"

STATIC oWord

FUNCTION main()

LOCAL cText := "Wouldd you be soo kind to showa us how to usea the word spelll checker with Fivewin. Thank s in advaance." 

MsgInfo(SpellCheck(cText))

RETURN nil

***********

STATIC FUNCTION SpellCheck(Texto)

LOCAL oDoc,oTexto
LOCAL cText:=Texto

IF .NOT. IsWord()
   MsgInfo("MS Word is not installed in your computer.")
   RETURN .F.
ENDIF


oWord := TOleAuto():New( "Word.Application" )

oWord:Visible := .F.
oWord:Documents:Add()

oDoc        := oWord:Get("ActiveDocument")
oTexto      := oWord:Selection()
oTexto:Text := Texto

oDoc:CheckSpelling()

cText := oTexto:Text

oDoc:Close(0)
oWord:Quit()

oTexto := NIL
oDoc   := NIL
oWord  := NIL

IF ! EMPTY(cText) // If ctext is empty that means that the process was canceled
    Texto := cText
ENDIF

RETURN(Texto)

************* 

FUNCTION isWord()

local lSuccess:=.F.
local oWord

TRY 
   oWord:= createObject("word.Application")
   lSuccess:=.T.
CATCH
   lSuccess:=.F.
END

RETURN lSuccess

***************

-Ramesh Babu

bpd2000

Posts: 153

Joined: Tue Aug 05, 2014 09:48 AM

Re: Spell Checker
Posted: Sat Mar 26, 2016 04:14 AM

Thank you Mr. Rameshbabu

Regards, Greetings

Try FWH. You will enjoy it's simplicity and power.!

Armando

Posts: 3358

Joined: Fri Oct 07, 2005 08:20 PM

Re: Spell Checker
Posted: Sat Mar 26, 2016 04:39 PM

Otto & Friends

Here is my code

Code (fw): Select all Collapse

STATIC FUNCTION SpellCheck(Texto)
    LOCAL oWord,oDoc,oTexto
    LOCAL cText := Texto

    TRY
        oWord:=TOleAuto():New( "Word.Application" )
    CATCH
        MsgInfo("MS-WORD no esta instalado en esta PC !",oApp:cAplicacion)
        RETURN(Texto)
    END

    oWord:Visible := (.F.)
    oWord:Documents:Add()
    oDoc := oWord:Get("ActiveDocument")

    oTexto := oWord:Selection()
    oTexto:Text := Texto

    oDoc:CheckSpelling()

    cText := oTexto:Text

    oDoc:Close(0)
    oWord:Quit()
    oTexto:=NIL
    oDoc:=NIL
    oWord:=NIL

    IF ! EMPTY(cText) // si cancelamos en el chequeo de ortografia, nos devuelve una cadena vacia
        Texto := cText
    ENDIF
RETURN(Texto)

Best regards

SOI, s.a. de c.v.
estbucarm@gmail.com
http://www.soisa.mex.tl/
http://sqlcmd.blogspot.com/
Tel. (722) 174 44 45
Carpe diem quam minimum credula postero

dtussman

Posts: 102

Joined: Sat Jun 06, 2015 06:57 PM

Re: Spell Checker
Posted: Tue Mar 29, 2016 06:13 PM

looks interesting, but how long does this process take? Opening Word takes forever on my computer.

FiveTech Support Forums

Continue the discussion