FiveTech Support Forums

FiveWin / Harbour / xBase community
Board indexAll discussionsLogin (GitHub)
Board index FiveWin para Harbour/xHarbour Seek en XBrowse con Dolphin texto con Ñ
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Thu Aug 18, 2016 08:16 PM
Si, solo con Dolphin
Probe este ejemplo que me paso Mr Rao: (Adaptado para mis tablas) y funciona bien con FWMYSQL y con ARRAY. No con Dolphin
Code (fw): Select all Collapse
#include "fivewin.ch"
#include "tdolphin.ch"

REQUEST HB_LANG_ES
REQUEST HB_CODEPAGE_ESWIN

static oCn, oServer
static cHost := "xxx", cUser := "xxx", cPwd := "xxx", cDB := "xxx"
static cCollate   := "utf8_spanish2_ci"

//----------------------------------------------------------------------------//

function Main()

   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES_ES" )

   FWMYSQL_test()
   Dolphin_test()

return nil

//----------------------------------------------------------------------------//

function FWMYSQL_test()

   local oRs
   FWCONNECT oCn HOST cHost USER cUser PASSWORD cPwd DATABASE cDB
   oRs   := oCn:RowSet( "test" )
   oRs:Sort := "nombre"  //Ordenado por nombre
   oRs:GoTop()

   xbrowser oRs TITLE "FWH " + cCollate AUTOSORT

return nil

//----------------------------------------------------------------------------//

function Dolphin_test()

   local oQry, aTabla := {}

   CONNECT oServer HOST cHost USER cUser PASSWORD cPwd DATABASE cDB

   oQry  := oServer:Query( "select * from test order by nombre" )
   XBROWSER oQry TITLE "Dolphin " + cCollate AUTOSORT

   oQry:GoTop()
   do while !oQry:Eof()
      AADD(aTabla,oQry:nombre)
      oQry:Skip()
   enddo
   
   XBROWSER aTabla TITLE "Array copiado de Dolphin " + cCollate AUTOSORT

return nil

Si no es mucho atrevimiento, puedo pasarte por mail el seteo de la base de datos que tengo colgada en un servidor y lo puedes ver.
Gracias por tu tiempo.
Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
MarioG
Posts: 1380
Joined: Fri Oct 14, 2005 01:28 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Thu Aug 18, 2016 10:22 PM

Gente:
Quizas no me exprese bien; pero yo, sin leer las particularidades de la collate, selccioné: latin1_spanish_ci. Y tanto el orden como la búsqueda resultan correctas
Uso TDophin, MariaDb y xBrowse

Resistencia - "Ciudad de las Esculturas"

Chaco - Argentina
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Thu Aug 18, 2016 10:48 PM

Mario:
Algun seteo particular de lenguage? Ya que vos usas Tdolphin y Xbrowse y te funciona.
Le asigne a la tabla la collation que me indicas y sigue sin funcionar.
Yo tengo (como puse en el codigo)

HB_CDPSELECT("ESWIN")
HB_LangSelect( "ES_ES" )
No se si es de Dolphin pero tenia en algun momento Set_MyLang( "es_es" ), pero lo pongo y tampoco me funciona.

Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
MarioG
Posts: 1380
Joined: Fri Oct 14, 2005 01:28 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Thu Aug 18, 2016 11:44 PM
CM;
Mi seteo inicial es:
Code (fw): Select all Collapse
REQUEST HB_Lang_ESWIN, HB_CODEPAGE_ESWIN // A decir verdad este lo tengo declarado con DBFs, y fue por "copiar y pegar"
...

INIT PROCEDURE Inicio()

   HB_LangSelect(  "ESWIN" )        // Al parecer ambos son distintos a los que vos declaras
   HB_SetCodePage( "ESWIN" )

   SET DATE TO BRITISH
   SET CENTURY ON
   SET EPOCH TO (Year( Date() )-99)
   Set(_SET_INSERT, .T.)
Resistencia - "Ciudad de las Esculturas"

Chaco - Argentina
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 12:43 AM

Mario:
Te envie un mail para que me hagas una prueba con mis datos.
Probé con tu seteo y tampoco anduvo
Muchas gracias por tu tiempo

Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 01:38 AM

You can send the data to me in dbf or excel format.

nageswaragunupudi@gmail.com

Regards



G. N. Rao.

Hyderabad, India
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 02:23 AM

Mr Rao:
Gracias por su interes. Le envie un mail con los datos de conexion y otro con el archivo excel exportado de la tabla
Saludos

Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 03:11 AM
Thank you.
I tried this program with your database
Code (fw): Select all Collapse
#include "fivewin.ch"

REQUEST HB_LANG_ES
REQUEST HB_CODEPAGE_ESWIN

static oCn
static cHost := "190.228.29.63", cUser := "gusano_admin", cPwd := "buitrox", cDB := "cgtest"

//----------------------------------------------------------------------------//

function Main()

   local oRs, cTable

   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES_ES" )

   FWCONNECT oCn HOST cHost USER cUser PASSWORD cPwd DATABASE cDB

   if oCn == nil
      ? "Not connected"
      return nil
   endif

   XBROWSER oCn:ListTables() SELECT ( cTable := oBrw:aCols[ 1 ]:Value )

   oRs   := oCn:RowSet( cTable )

   XBROWSER oRs TITLE cTable AUTOSORT

   oCn:Close()

return nil

//----------------------------------------------------------------------------//




I am using Spanish OS Keyboard downloaded.
Now that you have purchased FWH16.04, you better use FWRowSet. This works irrespective of the collation you used for the table.
Regards



G. N. Rao.

Hyderabad, India
nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 03:24 AM
In the earlier program, we used XBROWSER.
Now let us try with full xbrowse code.
Code (fw): Select all Collapse
#include "fivewin.ch"

REQUEST HB_LANG_ES
REQUEST HB_CODEPAGE_ESWIN

static oCn
static cHost := "190.228.29.63", cUser := "gusano_admin", cPwd := "buitrox", cDB := "cgtest"

//----------------------------------------------------------------------------//

function Main()

   local oRs, cTable

   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES_ES" )

   FWCONNECT oCn HOST cHost USER cUser PASSWORD cPwd DATABASE cDB

   if oCn == nil
      ? "Not connected"
      return nil
   endif

   XBROWSER oCn:ListTables() SELECT ( cTable := oBrw:aCols[ 1 ]:Value )

   oRs   := oCn:RowSet( cTable )

//   XBROWSER oRs TITLE cTable AUTOSORT

   BrowseTable( cTable )

   oCn:Close()

return nil

//----------------------------------------------------------------------------//

static function BrowseTable( cTable )

   local oRs, oDlg, oFont, oBrw

   oRs      := oCn:RowSet( cTable )
   oRs:Sort := "nombre"
   oRs:GoTop()

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 700,400 PIXEL TRUEPIXEL FONT oFont

   @ 60,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE oRs AUTOCOLS AUTOSORT CELL LINES NOBORDER

   oBrw:CreateFromCode()

   @ 20,20 SAY oBrw:oSeek VAR oBrw:cSeek SIZE 200,24 PIXEL OF oDlg ;
      COLOR CLR_HRED,CLR_YELLOW

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

//----------------------------------------------------------------------------//


Regards



G. N. Rao.

Hyderabad, India
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 03:30 AM

Estimado Mr Rao, en ambos caso ud esta usando FWMYSQL, yo uso Dolphin. Con Dolphin tengo problemas. Con ARRAY y con FWMYSQL funciona bien.

Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 03:33 AM
Puede proba este codigo:
Code (fw): Select all Collapse
#include "fivewin.ch"
#include "tdolphin.ch"

REQUEST HB_LANG_ES
REQUEST HB_CODEPAGE_ESWIN

static oCn, oServer
static cHost := "190.228.29.63", cUser := "gusano_admin", cPwd := "buitrox", cDB := "cgtest"
static cCollate   := "utf8_spanish2_ci"

//----------------------------------------------------------------------------//

function Main()

   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES_ES" )
   
   FWMYSQL_test()
   Dolphin_test()

return nil

//----------------------------------------------------------------------------//

function FWMYSQL_test()

   local oRs
   local aData := { { "CAMISA" }, { "CAÑA" },  { "CANDADO" }, { "CANILLA" }, ;
                  { "CAÑO" }, { "CANOBOTE" } }

   FWCONNECT oCn HOST cHost USER cUser PASSWORD cPwd DATABASE cDB
/*
   if oCn:TableExists( "cana" )
      ocn:DropTable( "cana" )
   endif
   oCn:CreateTable( "cana", { { "name", 'C', 20, 0, cCollate } }, .t., cCollate )

   oCn:Insert( "cana", { "name" }, aData )
*/
   oRs   := oCn:RowSet( "test" )
   oRs:Sort := "nombre"   
   oRs:GoTop()

   xbrowser oRs TITLE "FWH " + cCollate AUTOSORT

return nil

//----------------------------------------------------------------------------//

function Dolphin_test()

   local oQry, aTabla := {}

   CONNECT oServer HOST cHost USER cUser PASSWORD cPwd DATABASE cDB

   oQry  := oServer:Query( "select * from test order by nombre" )
   XBROWSER oQry TITLE "Dolphin " + cCollate AUTOSORT

   oQry:GoTop()
   do while !oQry:Eof()
      AADD(aTabla,oQry:nombre)
      oQry:Skip()
   enddo
   
   XBROWSER aTabla TITLE "Array  " + cCollate AUTOSORT

return nil

Vera que en el caso de dolphin (segundo browse) la busqueda funciona mal.
Gracias
Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 04:29 AM

We shall try to find solution for Dolphin incremental seek.
Incidentally let me say Incremental Filter is working with Dolphin.
We shall get back to you again on incremental seek with Dolphin

Regards



G. N. Rao.

Hyderabad, India
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 08:41 AM

Muchas gracias Mr. Rao!
Quedo a la espera de noticias suyas.
Por sierto, he verificado que si funciona el Filtro incremental, tanto con lWildSeek en .t. como en .f.
Saludos

Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
cnavarro
Posts: 6755
Joined: Wed Feb 15, 2012 08:25 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 08:48 AM
Cesar, prueba asi
A mi me funciona, acabo de probarlo con tu base de datos

Code (fw): Select all Collapse
   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES" )
   
   Set_MyLang( "esp" )    // Añade esto
Cristobal Navarro

Hay dos tipos de personas: las que te hacen perder el tiempo y las que te hacen perder la noción del tiempo

El secreto de la felicidad no está en hacer lo que te gusta, sino en que te guste lo que haces
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Seek en XBrowse con Dolphin texto con Ñ
Posted: Fri Aug 19, 2016 08:52 AM

Perfecto Cristobal!!!!
Funciona Ok!!
Muchisimas gracias por tu tiempo!!
Saludos!!

Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
Static archive · New replies & topics via GitHub Discussions