topic-33016

Posts: 9020

Joined: Thu Oct 06, 2005 08:17 PM

Valid, oJump and close
Posted: Fri Sep 30, 2016 09:17 PM

Dear friends, In the following sample try to click on Close button: the focus will go on the third GET. Instead, I need the button to close the dialog. Only on pressing Enter the focus should go to the third GET. How to get this? Any ideas?

Code (fw): Select all Collapse

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oDlg

    LOCAL oGet1, oGet3

    LOCAL nVar1 := 0
    LOCAL nVar2 := 0
    LOCAL nVar3 := 0

    DEFINE DIALOG oDlg;
           SIZE 800, 600

    @ 1, 1 GET oGet1 VAR nVar1;
           SIZE 100, 13;
           VALID ( IF( nVar1 = 0, oGet1:oJump := oGet3, ), .T. )

    @ 3, 1 GET nVar2;
           SIZE 100, 13

    @ 5, 1 GET oGet3 VAR nVar3;
           SIZE 100, 13

    @ 7, 1 BUTTON "Close";
           ACTION oDlg:End()

    ACTIVATE DIALOG oDlg;
             CENTER

    RETURN NIL

EMG

Enrico Maria Giordano

e.m.giordano@emagsoftware.it
http://www.emagsoftware.it
http://www.emagsoftware.it/emgmusic
http://www.emagsoftware.it/spectrum
http://www.emagsoftware.it/tbosg

dtussman

Posts: 102

Joined: Sat Jun 06, 2015 06:57 PM

Re: Valid, oJump and close
Posted: Fri Sep 30, 2016 10:29 PM

I think this might work.

Give the button a name, such as oBut1.

Then include the following line

oBut1:blclicked:= {||odlg:END()}

Gale FORd

Posts: 663

Joined: Mon Dec 05, 2005 11:22 PM

Re: Valid, oJump and close
Posted: Fri Sep 30, 2016 10:33 PM

You can add the Cancel clause to the Button but then the valid will not execute.

Code (fw): Select all Collapse

   @ 7, 1 BUTTON "Close";
           ACTION oDlg:End() CANCEL

Enrico Maria Giordano

Posts: 9020

Joined: Thu Oct 06, 2005 08:17 PM

Re: Valid, oJump and close
Posted: Sat Oct 01, 2016 08:19 AM

Thank you, but the valid is disable with both suggestions. :-(

EMG

Enrico Maria Giordano

e.m.giordano@emagsoftware.it
http://www.emagsoftware.it
http://www.emagsoftware.it/emgmusic
http://www.emagsoftware.it/spectrum
http://www.emagsoftware.it/tbosg

Enrico Maria Giordano

Posts: 9020

Joined: Thu Oct 06, 2005 08:17 PM

Re: Valid, oJump and close
Posted: Sat Oct 01, 2016 08:25 AM

Found!

Code (fw): Select all Collapse

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oDlg

    LOCAL oGet2, oGet4, oBtn1

    LOCAL nVar1 := 0
    LOCAL nVar2 := 0
    LOCAL nVar3 := 0
    LOCAL nVar4 := 0

    DEFINE DIALOG oDlg;
           SIZE 800, 600

    @ 1, 1 GET nVar1;
           SIZE 100, 13;
           VALID !EMPTY( nVar1 )

    @ 3, 1 GET oGet2 VAR nVar2;
           SIZE 100, 13;
           VALID ( IF( nVar2 = 0 .AND. !oBtn1:lFocused, oGet2:oJump := oGet4, ), .T. )

    @ 5, 1 GET nVar3;
           SIZE 100, 13

    @ 7, 1 GET oGet4 VAR nVar4;
           SIZE 100, 13

    @ 9, 1 BUTTON oBtn1 PROMPT "Close";
           ACTION oDlg:End()

    ACTIVATE DIALOG oDlg;
             CENTER

    RETURN NIL

EMG

Enrico Maria Giordano

e.m.giordano@emagsoftware.it
http://www.emagsoftware.it
http://www.emagsoftware.it/emgmusic
http://www.emagsoftware.it/spectrum
http://www.emagsoftware.it/tbosg

Rick Lipkin

Posts: 2706