Posts: 1286

Joined: Mon Feb 25, 2008 02:54 PM

Problema ao Abrir um SITE pelo FIVEWIN(Solucionado)
Posted: Fri Jan 20, 2017 07:11 PM

Amigos,

http://www.nfce.se.gov.br/portal/painelMonitor.jsp

Ao abrir este site pelo FIVEWIN não aparece completo como ao abrir pelo NAVEGADOR.

Alguem têm alguma ideia de como resolver?

PRG:

include "FiveWin.ch"

function Main()

local oWnd, oWndChild, oActiveX
local cEvents := ""

DEFINE WINDOW oWnd TITLE "FiveWin ActiveX Support" MDI

DEFINE WINDOW oWndChild MDICHILD OF oWnd

oActiveX = TActiveX():New( oWndChild, "Shell.Explorer.2" )

oWndChild:oClient = oActiveX // To fill the entire window surface
oWndChild:Resize()

oActiveX:Do( "Navigate2", "http://www.nfce.se.gov.br/portal/painelMonitor.jsp" )
oActiveX:Silent := .t.

ACTIVATE WINDOW oWnd
return nil

ubiratanmga@gmail.com

FWH24.04
BCC7.3
HARBOUR3.2
xMate
Pelles´C
TDolphin

karinha

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Fri Jan 20, 2017 07:32 PM

Code (fw): Select all Collapse

// ABRESITE.PRG By Joao Santos - 20/01/2017 - POWERED BY FWHX16.12.

#Include "FiveWin.ch"

MEMVAR oActiveX
MEMVAR cEvents

Function abresite(cSite)

   LOCAL oWnd

   IF(!IsInternet())

      MsgInfo("Necessário conexão com internet."+CRLF+"Operação cancelada", ;
              "Informação")

      RETURN NIL

   ENDIF

   cEvents := "Vidal"
   cSite := ( "http://www.nfce.se.gov.br/portal/painelMonitor.jsp" )

   DEFINE WINDOW oWnd TITLE " ..::" + "| Acessando: " + cSite /* ;
          MDI VSCROLL HSCROLL */

   oActiveX = TActiveX():New( oWnd, "Shell.Explorer" )

   oActivex:Silent := .T.

   oActivex:SetFocus()

   oWnd:oClient = oActiveX

   oActiveX:Navigate( cSite )

   ACTIVATE WINDOW oWnd MAXIMIZED

Return(nil)

// FIM DO PROGRAMA - By Joao Santos.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

MGA

Posts: 1286

Joined: Mon Feb 25, 2008 02:54 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Fri Jan 20, 2017 07:58 PM

Karinha,

abrindo o site pelo NAVEGADOR aparece completo com todos estados e imagens (mapa brasil).

abrindo pelo fivewin, não aparece completo pra mim, não aparece o resultado dos estados e nem as imagens.

att.

ubiratanmga@gmail.com

FWH24.04
BCC7.3
HARBOUR3.2
xMate
Pelles´C
TDolphin

karinha

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Fri Jan 20, 2017 08:15 PM

Ai, não use ACTIVEX dispare direto para pegar todo o código da página.

Code (fw): Select all Collapse

#Include "FiveWin.ch"

Function MostraSite( cSite )

   LOCAL oWnd

   IF(!IsInternet())

      MsgInfo("Necessário conexão com internet."+CRLF+"Operação cancelada", ;
              "Informação")

      RETURN NIL

   ENDIF

   cSite := ( "http://www.nfce.se.gov.br/portal/painelMonitor.jsp" )

   MOSTRA_SITE( cSite )

Return(nil)

FUNCTION MOSTRA_SITE( cSite )

   ShellExecute(GetActiveWindow(),"open",'"'+cSite+'"')

RETURN NIL

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

karinha

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Fri Jan 20, 2017 08:18 PM

Uma imagem fala por si.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

MGA

Posts: 1286

Joined: Mon Feb 25, 2008 02:54 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Sat Jan 21, 2017 12:14 AM

Obrigado amigo,

mais a intenção era ter esta consulta como uma JANELA do sistema(dialog ou window) .

ubiratanmga@gmail.com

FWH24.04
BCC7.3
HARBOUR3.2
xMate
Pelles´C
TDolphin

karinha

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Mon Jan 23, 2017 12:36 PM

O problema é que a página pelo que eu entendi, não aceita ACTIVEX do windows.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

MGA

Posts: 1286

Joined: Mon Feb 25, 2008 02:54 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Mon Jan 23, 2017 07:49 PM

Deve ser isso mesmo! Obrigado!

ubiratanmga@gmail.com

FWH24.04
BCC7.3
HARBOUR3.2
xMate
Pelles´C
TDolphin

Giovany Vecchi

Posts: 244

Joined: Mon Jun 05, 2006 09:39 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Tue Jan 24, 2017 12:13 AM

Quando um executável não informa o sistema operacional a versão do internet explorer, por padrão é definido a versão 8 de IE. e algumas paginas não funcionam corretamente com esta versão.
Para que o ambiente do navegador de IE seja definido para seu programa use esta função e escolha a versão do IE que voce desejar.
Teste em seu programa e poste aqui se resolver.

Ex: INTER_APP_WEB_CONFIG("MEU_APP.EXE",11000) // Internet explorer versão 11

Link: https://msdn.microsoft.com/en-us/library/ee330730(v=vs.85).aspx#browser_emulation

Code (fw): Select all Collapse

FUNCTION INTER_APP_WEB_CONFIG(f_cNameProg,f_nVersion_IE)
Local oRegKey, cRegProgGet
  
  Default f_nVersion_IE := 11001 // <!-- m --><a class="postlink" href="https://msdn.microsoft.com/en-us/library/ee330730(v=vs.85">https://msdn.microsoft.com/en-us/librar ... 30(v=vs.85</a><!-- m -->).aspx#browser_emulation

  if IsWow64() // Se for 64 bits 
    
    oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
         "SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION" )
    oRegKey:Set(f_cNameProg,f_nVersion_IE,4)
    oRegKey:Close()

    oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
         "SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BEHAVIORS" )
    oRegKey:Set(f_cNameProg,1,4)
    oRegKey:Close()

    oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
         "SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_ENABLE_WEB_CONTROL_VISUALS" )
    oRegKey:Set(f_cNameProg,1,4)
    oRegKey:Close()

  Else // se for 32 bits

    oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
         "SOFTWARE\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BEHAVIORS" )
    oRegKey:Set(f_cNameProg,1,4)
    oRegKey:Close()

    oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
         "SOFTWARE\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION" )
    oRegKey:Set(f_cNameProg,f_nVersion_IE,4)
    oRegKey:Close()

    oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
         "SOFTWARE\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_ENABLE_WEB_CONTROL_VISUALS" )
    oRegKey:Set(f_cNameProg,1,4)
    oRegKey:Close()

  EndIf

RETURN NIL

MGA

Posts: 1286

Joined: Mon Feb 25, 2008 02:54 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Tue Jan 24, 2017 01:16 AM

Giovany Vecchi,

Parabéns, funcionou perfeitamente!

muito obrigado

ubiratanmga@gmail.com

FWH24.04
BCC7.3
HARBOUR3.2
xMate
Pelles´C
TDolphin

karinha

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN
Posted: Tue Jan 24, 2017 12:06 PM

SGS wrote:Giovany Vecchi,

Parabéns, funcionou perfeitamente!

muito obrigado

SGS, mostre como ficou o código final para que os demais possam usar no futuro. Sinceramente não entendi essa mágica.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

MGA

Posts: 1286

Joined: Mon Feb 25, 2008 02:54 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN(Solucionado)
Posted: Tue Jan 24, 2017 07:36 PM

Karinha,

include "FiveWin.ch"

define HKEY_LOCAL_MACHINE 2147483650

function Main()

local oWnd, oWndChild, oActiveX
local cEvents := ""

INTER_APP_WEB_CONFIG("jsp.exe",11000)

DEFINE WINDOW oWnd TITLE "Support" MDI

DEFINE WINDOW oWndChild MDICHILD OF oWnd

oActiveX = TActiveX():New( oWndChild, "Shell.Explorer.2" )

oWndChild:oClient = oActiveX // To fill the entire window surface
oWndChild:Resize()

oActiveX:Do( "Navigate2", "http://www.nfce.se.gov.br/portal/painelMonitor.jsp" )
oActiveX:Silent := .t.

ACTIVATE WINDOW oWnd
return nil

FUNCTION INTER_APP_WEB_CONFIG(f_cNameProg,f_nVersion_IE)
Local oRegKey, cRegProgGet

Default f_nVersion_IE := 11001 // https://msdn.microsoft.com/en-us/librar ... 30(v=vs.85).aspx#browser_emulation

if IsWow64() // Se for 64 bits

oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
     &quot;SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION&quot; )
oRegKey:Set(f_cNameProg,f_nVersion_IE,4)
oRegKey:Close()

oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
     &quot;SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BEHAVIORS&quot; )
oRegKey:Set(f_cNameProg,1,4)
oRegKey:Close()

oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
     &quot;SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_ENABLE_WEB_CONTROL_VISUALS&quot; )
oRegKey:Set(f_cNameProg,1,4)
oRegKey:Close()

Else // se for 32 bits

oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
     &quot;SOFTWARE\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BEHAVIORS&quot; )
oRegKey:Set(f_cNameProg,1,4)
oRegKey:Close()

oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
     &quot;SOFTWARE\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION&quot; )
oRegKey:Set(f_cNameProg,f_nVersion_IE,4)
oRegKey:Close()

oRegKey := TReg32():New( HKEY_LOCAL_MACHINE,;
     &quot;SOFTWARE\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_ENABLE_WEB_CONTROL_VISUALS&quot; )
oRegKey:Set(f_cNameProg,1,4)
oRegKey:Close()

EndIf

RETURN NIL

ubiratanmga@gmail.com

FWH24.04
BCC7.3
HARBOUR3.2
xMate
Pelles´C
TDolphin

karinha

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN(Solucionado)
Posted: Tue Jan 24, 2017 07:47 PM

Estranho, aqui não funciona.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

Giovany Vecchi

Posts: 244

Joined: Mon Jun 05, 2006 09:39 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN(Solucionado)
Posted: Tue Jan 24, 2017 10:40 PM

karinha wrote:Estranho, aqui não funciona.

Verifica se voce tem instalado o internet explorer 10 ou 11 no seu computador.

karinha

Posts: 8515

Joined: Tue Dec 20, 2005 07:36 PM

Re: Problema ao Abrir um SITE pelo FIVEWIN(Solucionado)
Posted: Fri Jan 27, 2017 11:22 AM

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341

FiveTech Support Forums

include "FiveWin.ch"

include "FiveWin.ch"

define HKEY_LOCAL_MACHINE 2147483650