topic-35525

Board index FiveWin para Harbour/xHarbour Xbrowse multilinea

Posts: 234

Joined: Tue Sep 01, 2009 07:55 AM

Xbrowse multilinea
Posted: Tue Apr 17, 2018 08:16 AM

Buenos dias:
Por más que he buscado en el foro y en los samples, no lo acabo de encontrar, y creo haberlo visto en alguna ocasión.
Tengo dos tablas con una relación uno a varios y me gustaría mostrar en un Xbrowse las lineas de la principal pero que aparecieran las de la tabla hija agrupadas en una línea.
campo 1 tabla A - campo 2 tabla A - campo 1 tabla B - campo 2 tabla B
espacio en blanco espacio en blanco - campo 1 tabla B - campo 2 tabla B

Algo así, agradecería la orientación.
Muchas gracias.
Un saludo
José Luis

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: Xbrowse multilinea
Posted: Tue Apr 24, 2018 04:48 PM

Sample

Code (fw): Select all Collapse

#include "fivewin.ch"

REQUEST DBFCDX

function Main()

   field STATE
   local oDlg, oFont, oBrw

   // Preparing Indexes
   FERASE( "states.cdx" )
   USE STATES EXCLUSIVE VIA "DBFCDX"
   FW_CdxCreate()  // Create index on all fields
   CLOSE STATES

   FERASE( "customer.cdx" )
   USE CUSTOMER EXCLUSIVE VIA "DBFCDX"
   FW_CdxCreate()
   CLOSE CUSTOMER

   // Open and Join tables
   USE STATES NEW SHARED VIA "DBFCDX" // Parent table
   SET ORDER TO TAG CODE

   USE CUSTOMER NEW SHARED ALIAS CUST VIA "DBFCDX" // Child table
   SET ORDER TO TAG STATE
   SET RELATION TO STATE INTO STATES SCOPED
   GO TOP

   // Prepare the Browse
   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 800,600 PIXEL TRUEPIXEL FONT oFont

   @ 20,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE "CUST" ;
      COLUMNS "STATES->CODE", "STATES->NAME", "CITY", "FIRST" ;
      HEADERS "State", "StateName", "City", "Name" ;
      CELL LINES NOBORDER

   WITH OBJECT oBrw
      oBrw:aCols[ 1 ]:lMergeVert := .t.
      oBrw:aCols[ 2 ]:lMergeVert := .t.
      //
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

Regards

G. N. Rao.

Hyderabad, India

groiss

Posts: 234

Joined: Tue Sep 01, 2009 07:55 AM

Re: Xbrowse multilinea
Posted: Wed Apr 25, 2018 05:09 AM

Mr. Rao, muy agradecido, se de la tremenda potencia de XBROWSE y no quería desperdiciarlo, como siempre genial.
Thanks
José Luis

FiveTech Support Forums

Continue the discussion