FiveTech Support Forums

#include "FiveWin.ch"

function DescargFichDesdeUrl()
local cFile, cUrl, aFich :={},aFiles:={}

   cFile := "c:\download\Fivetechv.png"      //pueden cambiar carpeta de descarga
   cUrl  := "https://bitbucket.org/fivetech/fivewin-contributions/downloads/Fivetechv.png"     // HTTPS
   aadd(aFich,{cUrl,cFile})

   cFile := "c:\download\PruebaGDI_.zip"   //pueden cambiar carpeta de descarga
   cUrl  := "http://www.Pflegeplus.com/DOWNLOADS/Gditest1.zip"    // http
   aadd(aFich,{cUrl,cFile})

   AEval(aFich,{|a,n| Descargando( aFich[n,1],aFich[n,2],aFiles ) })

   XBROWSE( aFiles, "DESCARGAS" )
RETURN NIL

//--------------------------------------------------------//
Function Descargando(cUrl,cFile,aFiles)
local nRet

   MsgRun("Aguarde por favor, descargando...",,{|| ;
           DELETEURLCACHEENTRY( cUrl ) ,;
           nRet := URLDOWNLOADTOFILE( 0, cUrl, cFile ), SysRefresh() })
   
   if nRet == 0
      aadd( aFiles,{cUrl, cFile} )
   else
      aadd( aFiles,{cUrl, "Descarga ha fallado" +"  INET_E_DOWNLOAD_FAILURE (0x800C0008L or -2146697208)" } )
      MsgInfo(nRet,"Error INET")
   endif 

RETURN NIL

DLL STATIC FUNCTION DELETEURLCACHEENTRY( cUrl AS LPSTR ) AS BOOL;
    PASCAL FROM "DeleteUrlCacheEntryA" LIB "wininet.dll"

DLL FUNCTION URLDOWNLOADTOFILE( pCaller AS LONG, cUrl AS LPSTR, cFileName AS LPSTR, nReserved AS DWORD, nFnCB AS LONG ) AS LONG;
    PASCAL FROM "URLDownloadToFileA" LIB "urlmon.dll"