Favor Consulta para Francisco J. Alegria. (FranciscoA)

Board index FiveWin para Harbour/xHarbour Favor Consulta para Francisco J. Alegria. (FranciscoA)

Posts: 719

Joined: Fri May 12, 2017 02:50 PM

Favor Consulta para Francisco J. Alegria. (FranciscoA)
Posted: Thu Sep 12, 2019 12:06 AM

Hola Francisco.

Como estas, espero que muy bien.

Necesito molestarte pro favor, el mes pasado me ayudaste con un tema de Validación de un Get para mostrar u ocultar Say y Get.

Use tu código y funciona perfecto, pero hoy tengo una nueva necesidad y es que debo cambiar el GET Por un ComboBox.

Disculpando la molestia, desde ya te doy las gracias.

Muchos Saludos.

Este código con ComboBox no realiza la validación para ocultar un grupo de SAY y GET.

Code (fw): Select all Collapse

        @ 57,05 GROUP oGroup228  TO 79,290 PIXEL   COLOR RGB(128, 0, 0), (128, 0, 0) FONT oFont222 OF oDlg22  TRANSPARENT
        @  65,10  SAY "Tipo de Atención"           PIXEL OF oDlg22   FONT oFont223   COLORS RGB(0, 60, 179)

        @ 64.9,75 ComboBox oTip_Ate1 Var nTipAte Items ArrTranspose(aTipAte)[2]    SIZE 95,150 PIXEL OF oDlg22       FONT oFont223   UPDATE;
                         ON CHANGE (Tip_Ate1:=ArrTranspose(aTipAte)[1][oTip_Ate1:nAt]);
                         VALID  Valida_Ate( oDlg22,Tip_Ate1,oTip_Ate1,oTruco ,;
                                            {oGroup221,oGroup222,oGroup225,oExa_Oto1, oExa_Vis1, oExa_Ele1,;
                                oExa_Gli1,oExa_Hem1,oExa_Ure1,oExa_Ori1,oSay1,oSay2,oSay3,oSay4,oSay5,oSay6,oSay7,oSay8} )

              @  65,-50 GET oTruco Var cTruco SIZE 10,10  PIXEL OF oDlg22 ;  //necesario cuando se ejecuta el valid y los demas objetos estan ocultos.
                              VALID .T.

              
            @  84,05 GROUP oGroup221  TO 144,290 PIXEL  PROMPT "EXAMEN  DE ALTURA FISICA" COLOR RGB(0, 77, 0), (128, 0, 0) FONT oFont222 OF oDlg22  TRANSPARENT

        @  97,10  SAY  oSay1 PROMPT  "Examen  Otoscopia"            PIXEL OF oDlg22   FONT oFont223
        @  97,160  SAY oSay2 PROMPT  "Examen  de Visión"           PIXEL OF oDlg22   FONT oFont223


        @  97,87  GET oExa_Oto1    Var Exa_Oto1  SIZE 54,10      PIXEL OF oDlg22   PICTURE "@!"    COLOR RGB(0,0,128)   FONT oFont223 UPDATE
        @ 97,227  GET oExa_Vis1    Var Exa_Vis1  SIZE 54,10      PIXEL OF oDlg22   PICTURE "@!"    COLOR RGB(0,0,128)   FONT oFont223 UPDATE


        ** Para Mayores de  45 Años

        @  117,10  SAY oSay3 PROMPT  "Electrocardiograma"           PIXEL OF oDlg22   FONT oFont223
        @  129,10  SAY oSay4 PROMPT  "Examen de Glicemia"           PIXEL OF oDlg22   FONT oFont223

        @ 114,87  GET oExa_Ele1    Var Exa_Ele1  SIZE 165,10      PIXEL OF oDlg22   PICTURE "@!"    COLOR RGB(0,0,128)   FONT oFont223 UPDATE
        @ 129,87  GET oExa_Gli1    Var Exa_Gli1  SIZE 165,10      PIXEL OF oDlg22   PICTURE "@!"    COLOR RGB(0,0,128)   FONT oFont223 UPDATE

        ***

            @ 150,05 GROUP oGroup222  TO 180,290 PIXEL  PROMPT "EXAMEN  PRE-OCUPACIONAL" COLOR RGB(0, 77, 0), (128, 0, 0) FONT oFont222 OF oDlg22  TRANSPARENT


        @  164,10    SAY  oSay5 PROMPT  "Hemograma"   PIXEL OF oDlg22   FONT oFont223
        @  164,120   SAY  oSay6 PROMPT  "Uremia"   PIXEL OF oDlg22   FONT oFont223
        @  164,210   SAY  oSay7 PROMPT  "Orina"   PIXEL OF oDlg22   FONT oFont223

        @ 164,56   GET oExa_Hem1    Var Exa_Hem1  SIZE 54,10      PIXEL OF oDlg22   PICTURE "@!"    COLOR RGB(0,0,128)   FONT oFont223 UPDATE
        @ 164,148  GET oExa_Ure1    Var Exa_Ure1  SIZE 54,10      PIXEL OF oDlg22   PICTURE "@!"    COLOR RGB(0,0,128)   FONT oFont223 UPDATE
        @ 164,233  GET oExa_Ori1    Var Exa_Ori1  SIZE 54,10      PIXEL OF oDlg22   PICTURE "@!"    COLOR RGB(0,0,128)   FONT oFont223 UPDATE

            ACTIVATE DIALOG oDlg22 CENTER;
                         ON INIT EVAL(oTip_Ate1:bValid)

              Return

Function Valida_Ate( oDlg22,Ate1,oAte1,oTruco,aObjs)
        Local n

        
        For n := 1 to len(aObjs)
            if Ate1 # "C"
                 aObjs[n]:Show()
            else
                 aObjs[n]:Hide()
            endif
        Next
        If Ate1="C"
             Stor Spac(7) to Alt_Pac1,Pul_Ate1
             Stor Spac(10) to Exa_Oto1,Exa_Vis1,Exa_Hem1,Exa_Ure1,Exa_Ori1
             Stor Spac(35) to Exa_Ele1,Exa_Gli1
             Eva_Med1:=" "
             Tip_Ate1="C"
             nTipAte:=1
        Endif
    oDlg22:Refresh()
Return .T.

Este es el Link del Codigo anterior para ocultar o mostrar con GET.

FWH 22.10 - HARBOUR - PELLES C

FranciscoA

Posts: 2170

Joined: Fri Jul 18, 2008 01:24 AM

Re: Favor Consulta para Francisco J. Alegria. (FranciscoA)
Posted: Thu Sep 12, 2019 06:49 PM

remtec.

Aqui tienes el ejemplo.
Se han tomado datos del ejemplo anterior y sus variables, agregándole las nuevas necesarias.
Espero te sea útil.

Code (fw): Select all Collapse

Function Prueba_2()
local dia_lic1 := 0, Nro_Lic1 := space(15), Tip_Lic1 := " " ,;
      Fec_Ini1 := ctod("  /  /  "),Fec_Fin1 := ctod("  /  /  ")
local oDlg99,oFont992,oFont993
local oTip_Lic1, oNro_Lic1, oFec_Ini1, oFec_Fin1, oDia_Lic1
local Lic1:="N",oLic1
local oSay1,oSay2,oSay3,oSay4,oSay5

Local oGroup992,oGroup993,oFont994
Local oPre_Pac1,oTem_Pac1,oFre_Car1,oFre_Res1,oPes_Pac1,oGet11,oNro_Bon1,oVal_Bon1
Local anm_1:= Spac(50), anm_2:= Spac(50), anm_3:= Spac(50), anm_4:= Spac(50), anm_5:= Spac(50), anm_6:= Spac(50)
Local Pes_Pac1:=space(20),Pre_Pac1:=space(20),Tem_Pac1:=space(20),Fre_Car1:=space(20),Fre_Res1:=space(20)
local oFont991
local oSay11,oSay12,oSay13,oSay14,oSay15
local oTip_Ate1, nTipAte:=1, aTipAte := {}
local Tip_Ate1 

AAdd( aTipAte,{"A", "Atencion 1 Tipo A"} )
AAdd( aTipAte,{"B", "Atencion 2 Tipo B"} )
AAdd( aTipAte,{"C", "Atencion 3 Tipo C"} )
AAdd( aTipAte,{"A", "Atencion 4 Tipo D"} )
AAdd( aTipAte,{"C", "Atencion 5 Tipo C"} )

  DEFINE DIALOG oDlg99 SIZE 600,600 PIXEL TITLE "TIPO DE ATENCION" 

  DEFINE FONT oFont993 NAME "TAHOMA" SIZE 0,-14  BOLD
  DEFINE FONT oFont991 NAME "TAHOMA" SIZE 0,-18  BOLD
  DEFINE FONT oFont992 NAME 'TAHOMA' SIZE 0,-19  BOLD ITALIC
  DEFINE FONT oFont994 NAME "TAHOMA" SIZE 0,-14

  @  150,10 SAY "TIPO ATENCION" PIXEL OF oDlg99  COLOR RGB(0, 60, 179) FONT oFont993

  @ 150,73 COMBOBOX oTip_Ate1 VAR nTipAte ITEMS ArrTranspose(aTipAte)[2]  SIZE 95,150 PIXEL OF oDlg99 FONT oFont994  UPDATE;
           ON CHANGE ( Tip_Ate1:=ArrTranspose(aTipAte)[1][oTip_Ate1:nAt], EVAL(oTip_Ate1:bValid) );
           VALID  Valida_Ate( oDlg99,Tip_Ate1,oTip_Ate1 ,;
                     {oSay1,oSay2,oSay3,oSay4,oSay5,;
                      oSay11,oSay12,oSay13,oSay14,oSay15,;
                      oGroup992,oGroup993,;
                      oPre_Pac1,oFre_Res1,oFre_Car1,oTem_Pac1,oPes_Pac1,;
                      oTip_Lic1, oNro_Lic1, oFec_Ini1, oFec_Fin1, oDia_Lic1} )

  @ 165,05 GROUP oGroup992  TO 220,270 PIXEL OF oDlg99 PROMPT " ANTECEDENTES LICENCIA MEDICA " FONT oFont992 TRANSPARENT
  @ 185,010 SAY oSay1 PROMPT "Tipo Licencia" PIXEL OF oDlg99   FONT oFont993
  @ 185,130 SAY oSay2 PROMPT "Nro. Licencia" PIXEL OF oDlg99   FONT oFont993
  @ 200,010 SAY oSay3 PROMPT "Inicio"        PIXEL OF oDlg99   FONT oFont993
  @ 200,95  SAY oSay4 PROMPT "Término"       PIXEL OF oDlg99   FONT oFont993
  @ 200,185 SAY oSay5 PROMPT "Cant. Dias"    PIXEL OF oDlg99   FONT oFont993

  @ 185,58  GET oTip_Lic1 VAR Tip_Lic1 SIZE 50,10 PIXEL OF oDlg99 PICTURE "!"  COLOR RGB(0,0,128) FONT oFont993 UPDATE
  @ 185,180 GET oNro_Lic1 VAR Nro_Lic1 SIZE 66,10 PIXEL OF oDlg99 PICTURE "@!" COLOR RGB(0,0,128) FONT oFont993 UPDATE
  @ 200,32  GET oFec_Ini1 VAR Fec_Ini1 SIZE 50,10 PIXEL OF oDlg99 PICTURE "@d" COLOR RGB(0,0,128) FONT oFont993 UPDATE 
  @ 200,127 GET oFec_Fin1 VAR Fec_Fin1 SIZE 50,10 PIXEL OF oDlg99 PICTURE "@d" COLOR RGB(0,0,128) FONT oFont993 UPDATE;
            VALID  .T.  //Calcula_Dias(oDia_Lic1,oDlg99,Fec_Ini1,Fec_Fin1)
  @ 200,223 SAY oDia_Lic1 VAR Dia_Lic1 SIZE 24,10 PIXEL OF oDlg99 PICTURE "999" COLOR RGB(0,0,128) FONT oFont993 BORDER

  @ 228,05 GROUP oGroup993  TO 283,270 PIXEL OF oDlg99 PROMPT " PRUEBA GRUPO NUMERO DOS" FONT oFont992 TRANSPARENT
  @ 248,010 SAY oSay11 PROMPT "Pres. Arterial"       PIXEL OF oDlg99 FONT oFont993
  @ 248,120 SAY oSay12 PROMPT "Frec. Respiratoria"   PIXEL OF oDlg99 FONT oFont993
  @ 263,010 SAY oSay13 PROMPT "Frec. Cardiaca"       PIXEL OF oDlg99 FONT oFont993
  @ 263,120 SAY oSay14 PROMPT "Temp"                 PIXEL OF oDlg99 FONT oFont993
  @ 263,198 SAY oSay15 PROMPT "Peso"                 PIXEL OF oDlg99 FONT oFont993

  @ 248,60  GET oPre_Pac1 VAR Pre_Pac1 SIZE 40,10 PIXEL OF oDlg99 PICTURE "@!" COLOR RGB(0,0,128) FONT oFont993 UPDATE
  @ 248,190 GET oFre_Res1 VAR Fre_Res1 SIZE 40,10 PIXEL OF oDlg99 PICTURE "@!" COLOR RGB(0,0,128) FONT oFont993 UPDATE
  @ 263,60  GET oFre_Car1 VAR Fre_Car1 SIZE 40,10 PIXEL OF oDlg99 PICTURE "@!" COLOR RGB(0,0,128) FONT oFont993 UPDATE
  @ 263,145 GET oTem_Pac1 VAR Tem_Pac1 SIZE 40,10 PIXEL OF oDlg99 PICTURE "@!" COLOR RGB(0,0,128) FONT oFont993 UPDATE
  @ 263,218 GET oPes_Pac1 VAR Pes_Pac1 SIZE 33,10 PIXEL OF oDlg99 PICTURE "@!" COLOR RGB(0,0,128) FONT oFont993 UPDATE  

  ACTIVATE DIALOG oDlg99 CENTERED ;
           ON INIT EVAL(oTip_Ate1:bValid)

   oDlg99:End()

   oFont992:End()
   oFont993:End()

   oFont991:End()
   oFont994:End()

Return nil

//---------------------------------------------------//
Function Valida_Ate( oDlg,Ate1,oAte1,aObjs)
Local n
      
  For n := 1 to len(aObjs)
     if Ate1 # "C"
        aObjs[n]:Show()
     else
        aObjs[n]:Hide()
     endif
  Next

  oDlg:Refresh()
RETURN .T.

No es ninguna molestia, estamos para colaborar.
Saludos.

Francisco J. Alegría P.

Chinandega, Nicaragua.

Fwxh-MySql-TMySql

remtec

Posts: 719

Joined: Fri May 12, 2017 02:50 PM

Re: Favor Consulta para Francisco J. Alegria. (FranciscoA)
Posted: Thu Sep 12, 2019 07:10 PM

Francisco

Muy buenas tardes, deseo que estes muy bien.

Como siempre, funciono Perfecto.

Mil gracias, eternamente agradecido.

Muchos Saludos.

Antonio

FWH 22.10 - HARBOUR - PELLES C

FiveTech Support Forums

Continue the discussion