topic-40078

Otto

Posts: 6983

Joined: Fri Oct 07, 2005 07:07 PM

DEFINE BUTTON OF oBar RESOURCE 0xE10A
Posted: Mon Mar 08, 2021 05:56 PM

Dear Mr. Rao,
Is it possible to use RESOURCE plus text for buttons?
Best regards,

Otto

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: DEFINE BUTTON OF oBar RESOURCE 0xE10A
Posted: Tue Mar 09, 2021 05:36 AM

Yes.
Please see
fwh\samples\lockscrn.prg

Regards

G. N. Rao.

Hyderabad, India

QAZWSX2K

Posts: 364

Joined: Tue Oct 25, 2005 07:06 PM

Re: DEFINE BUTTON OF oBar RESOURCE 0xE10A
Posted: Thu Apr 01, 2021 09:02 PM

lockscrn.prg don´t exist

Software especializado para oficinas contables con grandes volumenes de Informacion
Impresion de todos los formularios del Seniat, Dian

alex_patino74@hotmail.com
whatsapp 57+3214777217

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: DEFINE BUTTON OF oBar RESOURCE 0xE10A
Posted: Fri Apr 02, 2021 09:12 AM

lockscrn.prg is available from FWH2004 onwards.

Regards

G. N. Rao.

Hyderabad, India

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: DEFINE BUTTON OF oBar RESOURCE 0xE10A
Posted: Fri Apr 02, 2021 09:15 AM

This is lockscrn.prg.
To be run on Windows 10 only.
Also, I hope your FWH version is not too old.

Code (fw): Select all Collapse

/*
* Program to view and save Windows 10 LockScreen Images
*
*/

#include "fivewin.ch"

//----------------------------------------------------------------------------//

function Main()

   local cPath := GETENV( "userprofile" ) + "\AppData\Local\Packages\Microsoft.Windows.ContentDeliveryManager_cw5n1h2txyewy\LocalState\Assets\"
   local aImages  := {}
   local oWnd, oBar, oImage, cSave, nImages, n := 1

   AEval( DIRECTORY( cPath + "*.*", "H" ), { |a| If( a[ 2 ] < 200000,, ( a[ 1 ] := cPath + a[ 1 ], AAdd( aImages, a ) ) ) } )

   ASort( aImages,,,{ |x,y| x[ 2 ] > y[ 2 ] } )
   nImages  := Len( aImages )

   DEFINE WINDOW oWnd STYLE WS_POPUP + WS_MAXIMIZE

   DEFINE BUTTONBAR oBar SIZE 32,32 LEFT
   oBar:SetColor( CLR_BLACK, CLR_BLACK )

   DEFINE BUTTON RESOURCE 0xE112 OF oBar CENTER ACTION ( If( --n < 1, n := nImages, ), oWnd:Update() )
   DEFINE BUTTON RESOURCE 0xE111 OF oBar CENTER ACTION ( n := ( n % nImages ) + 1, oWnd:Update() )
   DEFINE BUTTON RESOURCE 0xE105 OF oBar CENTER ACTION ( ;
      If( !Empty( cSave := cGetFile( "Jpg file(*.jpg)|*.jpg|", ;
      "Select File to Save", CurDir(), .t. ) ), ;
      HB_MEMOWRIT( cFileSetExt( cSave, "jpg" ), MEMOREAD( aImages[ n, 1 ] ) ), MsgInfo( "Not selected" ) ) )
   DEFINE BUTTON RESOURCE FWBitmap( "exit2" ) OF oBar CENTER ACTION oWnd:End()

   oBar:Float()

   @ 0,0 XIMAGE oImage SOURCE MEMOREAD( aImages[ n, 1 ] ) SIZE 0, 0 OF oWnd NOBORDER UPDATE
   oImage:SetColor( CLR_WHITE, CLR_BLACK )
   oImage:bLClicked := { || n := ( n % nImages ) + 1, oWnd:Update() }
   oImage:bRClicked := { || If( MsgYesNo( "Exit program?" ), oWnd:End(), ) }

   oWnd:oClient := oImage

   ACTIVATE WINDOW oWnd MAXIMIZED

return nil

//----------------------------------------------------------------------------//

Regards

G. N. Rao.

Hyderabad, India

cnavarro

Posts: 6755

Joined: Wed Feb 15, 2012 08:25 PM

Re: DEFINE BUTTON OF oBar RESOURCE 0xE10A
Posted: Fri Apr 02, 2021 01:03 PM

Otto wrote:Dear Mr. Rao,
Is it possible to use RESOURCE plus text for buttons?
Best regards,

Otto

Dear Otto
Do you want to say something like this?

Cristobal Navarro

Hay dos tipos de personas: las que te hacen perder el tiempo y las que te hacen perder la noción del tiempo

El secreto de la felicidad no está en hacer lo que te gusta, sino en que te guste lo que haces

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: DEFINE BUTTON OF oBar RESOURCE 0xE10A
Posted: Fri Apr 02, 2021 02:10 PM

I understood from Mr. Cristobal's posting the I did not understand Mr. Otto's question correctly.

Answer to Mr. Ottos question is,

Yes.

Eg:

Code (fw): Select all Collapse

   @ 20,20 BTNBMP PROMPT "NEXT" RESOURCE 0xE111 SIZE 100,100 PIXEL 2007 OF oDlg

Regards

G. N. Rao.

Hyderabad, India

FiveTech Support Forums

Continue the discussion