FiveTech Support Forums

FiveWin / Harbour / xBase community
Board indexActive topicsAll discussionsLogin (GitHub)
Board index FiveWin para Harbour/xHarbour Mostrar/ocultar consulta presionando/soltando boton de mouse
JoseAlvarez
Posts: 851
Joined: Sun Nov 09, 2014 05:01 PM
Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 01, 2021 12:35 PM

Hola a Todos.. saludos.

Mi consulta es la siguiente:

¿de que manera puedo hacer que al clickar sobre un boton, se muestre una consulta dentro de un dialogo, pero que al soltar el boton del mouse el dialogo desaparezca ?

o sea, mientras el boton este presionado veo la consulta, al soltarlo, desaparece la consulta.

¿habra alguna forma de hacerlo ?

Espero haberme explicado bien...

"Los errores en programación, siempre están entre la silla y el teclado..."



Fwh 19.06 32 bits + Harbour 3.2 + Borland 7.4 + MariaDB + TDolphin



Carora, Estado Lara, Venezuela.
karinha
Posts: 8523
Joined: Tue Dec 20, 2005 07:36 PM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 01, 2021 01:22 PM

Que tal un TIMER()?

Regards, saludos.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
JoseAlvarez
Posts: 851
Joined: Sun Nov 09, 2014 05:01 PM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 01, 2021 01:54 PM

Hola Joao..

¿de que manera se podria utilizar un timer? la idea es que mientras el usuario mantenga presionado el boton del mouse, la consulta se muestre en pantalla, y que al soltar el boton la consulta desaparezca.

Un timer funciona durante un tiempo determinado.

¿como podria usarse un timer en este caso?

No tengo idea...

"Los errores en programación, siempre están entre la silla y el teclado..."



Fwh 19.06 32 bits + Harbour 3.2 + Borland 7.4 + MariaDB + TDolphin



Carora, Estado Lara, Venezuela.
karinha
Posts: 8523
Joined: Tue Dec 20, 2005 07:36 PM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 01, 2021 02:45 PM

Hello my dear, mira \samples\MNUSELECT.PRG, creo sea el camiño.

Regards, saludos.

João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
karinha
Posts: 8523
Joined: Tue Dec 20, 2005 07:36 PM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 01, 2021 03:12 PM
http://wiki.fivetechsoft.com/doku.php?id=fivewin_pulldown_menu
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
JoseAlvarez
Posts: 851
Joined: Sun Nov 09, 2014 05:01 PM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 01, 2021 04:11 PM

Ok Amigo.

voy a probar eso y te comento...

"Los errores en programación, siempre están entre la silla y el teclado..."



Fwh 19.06 32 bits + Harbour 3.2 + Borland 7.4 + MariaDB + TDolphin



Carora, Estado Lara, Venezuela.
cnavarro
Posts: 6755
Joined: Wed Feb 15, 2012 08:25 PM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 01, 2021 04:20 PM
Y si investigas tambien con el

oControl:bLButtonUp = { | nRow, nCol | ....
Cristobal Navarro

Hay dos tipos de personas: las que te hacen perder el tiempo y las que te hacen perder la noción del tiempo

El secreto de la felicidad no está en hacer lo que te gusta, sino en que te guste lo que haces
karinha
Posts: 8523
Joined: Tue Dec 20, 2005 07:36 PM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 01, 2021 09:40 PM
cnavarro wrote:Y si investigas tambien con el

oControl:bLButtonUp = { | nRow, nCol | ....



\samples\TESTMOUS.PRG ?

Regards, saludos.
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Sat Sep 04, 2021 09:41 AM
Code (fw): Select all Collapse
function BtnUpDn()

   local oDlg, oBtn, oSay, oFont, oLarg

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE FONT oLarg NAME "TAHOMA" SIZE 0,-30

   DEFINE DIALOG oDlg SIZE 300,260 PIXEL TRUEPIXEL FONT oFont

   @ 160,20 BTNBMP oBtn ;
      PROMPT { || If( oBtn:lPressed, "DOWN", "UP" ) } ;
      SIZE 100,60 PIXEL OF oDlg FLAT
   oBtn:bPainted := { || oSay:Refresh() }

   @  20,20 SAY oSay PROMPT { || If( oBtn:lPressed, "BUTTON PRESSED", "" ) } ;
      SIZE 260,100 PIXEL OF oDlg CENTER VCENTER FONT oLarg UPDATE

   ACTIVATE DIALOG oDlg CENTERED

   RELEASE FONT oFont, oLarg

return nil


Regards



G. N. Rao.

Hyderabad, India
nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Sat Sep 04, 2021 03:18 PM
Another variation
Code (fw): Select all Collapse
function BtnUpDn()

   local oDlg, oBtn, oSay, oFont, oLarg
   local oMsgDlg

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE FONT oLarg NAME "TAHOMA" SIZE 0,-30

   DEFINE DIALOG oDlg SIZE 300,300 PIXEL TRUEPIXEL FONT oFont

   @ 200,20 BTNBMP oBtn ;
      PROMPT { || If( oBtn:lPressed, "DOWN", "UP" ) } ;
      SIZE 100,60 PIXEL OF oDlg FLAT
   oBtn:bPainted := <||
      if oBtn:lPressed
         if oMsgDlg == nil
            oMsgDlg  := ShowMessage()
         endif
      else
         if oMsgDlg != nil
            oMsgDlg:End()
            oMsgDlg  := nil
         endif
      endif
      return nil
      >

   ACTIVATE DIALOG oDlg CENTERED

   RELEASE FONT oFont, oLarg

return nil

//----------------------------------------------------------------------------//

static function ShowMessage()

   local oDlg

   DEFINE DIALOG oDlg SIZE 200,60 PIXEL TRUEPIXEL TITLE "DIALOG"
   @ 20,20 SAY "Button Pressed" SIZE 160,20 PIXEL OF oDlg ;
      CENTER VCENTER
   ACTIVATE DIALOG oDlg CENTERED NOMODAL

return oDlg

//----------------------------------------------------------------------------//


Regards



G. N. Rao.

Hyderabad, India
JoseAlvarez
Posts: 851
Joined: Sun Nov 09, 2014 05:01 PM
Re: Mostrar/ocultar consulta presionando/soltando boton de mouse
Posted: Wed Sep 08, 2021 02:48 AM

Hola amigos del foro...

Gracias a los que me ayudaron con mi consulta.

Por gusto personal me quede con la sugerencia de Mr. Nages, me funciono a la primera y perfectamente...

Muchas gracias de verdad...

Un abrazo a todos, agradezco siempre su buena dispocison a ayudar.

"Los errores en programación, siempre están entre la silla y el teclado..."



Fwh 19.06 32 bits + Harbour 3.2 + Borland 7.4 + MariaDB + TDolphin



Carora, Estado Lara, Venezuela.

Continue the discussion

Static archive · New replies & topics via GitHub Discussions