FiveTech Support Forums

FiveWin / Harbour / xBase community
Board indexActive topicsAll discussionsLogin (GitHub)Last update on Sat Oct 17, 2026 02:08 PM UTC
Board index FiveWin para Harbour/xHarbour Cambiar icono carpeta desde codigo
leandro
Posts: 1828
Joined: Wed Oct 26, 2005 02:49 PM

Cambiar icono carpeta desde codigo

Posted: Wed Nov 03, 2021 02:49 PM
Buenos días para todos

Estuve buscando en el foro pero no encontré respuesta, es que deseo cambiar el icono de la carpeta de contiene nuestra aplicación, lo hice de manera manual, pero quiero saber si es posible hacerlo desde código.

Saludos
LEANDRO AREVALO
Bogotá (Colombia)
https://hymlyma.com
https://hymplus.com/
leandroalfonso111@gmail.com
leandroalfonso111@hotmail.com

[ Turbo Incremental Link64 6.98 Embarcadero 7.70 ] [ FiveWin 25.01 ] [ xHarbour 64 bits) ]
Antonio Linares
Posts: 44508
Joined: Thu Oct 06, 2005 05:47 PM

Re: Cambiar icono carpeta desde codigo

Posted: Wed Nov 03, 2021 03:37 PM

"Change Icon of EXE file through code extracting it from other EXE file | Go4Expert" https://www.go4expert.com/articles/chan ... ting-t643/

La clave es usar UpdateResource()

regards, saludos

Antonio Linares
www.fivetechsoft.com
nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM

Re: Cambiar icono carpeta desde codigo

Posted: Mon Nov 08, 2021 06:03 PM
Code (fw): Select all Collapse
function SetFolderIcon( cFolder, cFileIco, cInfoTip )

   local lSet  := .f.
   local oIni, cIni, cSec := ".ShellClassInfo"

   cFolder  := RemRight( cFolder, "\" )
   DEFAULT cInfoTip := ""

   if File( cFileIco ) .and. Lower( cFileExt( cFileIco ) ) == "ico" .and. ;
      !File( cFolder )

      if !lIsDir( cFolder )
         lMkFullPath( cFolder )
      endif

      if lIsDir( cFolder )
         SetFAttr( cFolder, 4 )
         cFileIco := cRelativePath( cFileIco, cFolder )
         cIni     := cFolder + "\desktop.ini"
         INI oIni FILE cIni
         SET SECTION cSec ENTRY "ConfirmFileOp" TO 0        OF oIni
         SET SECTION cSec ENTRY "NoSharing"     TO 1        OF oIni
         SET SECTION cSec ENTRY "IconFile"      TO cFileIco OF oIni
         SET SECTION cSec ENTRY "IconIndex"     TO 0        OF oIni
         SET SECTION cSec ENTRY "InfoTip"       TO cInfoTip OF oIni
         SetFAttr( cIni, 2 )
         lSet  := .t.
      endif
   endif

return lSet


This function is included in the next version of FWH

Test:
Code (fw): Select all Collapse
? SetFolderIcon( "c:\fwh\icofolder", "c:\fwh\icons\fivetech.ico", "FWH SetFolderIcon() function" )


Regards



G. N. Rao.

Hyderabad, India
leandro
Posts: 1828
Joined: Wed Oct 26, 2005 02:49 PM

Re: Cambiar icono carpeta desde codigo

Posted: Tue Nov 09, 2021 09:17 PM

Excelente Mr.Nages :D

Era lo que estaba buscando. Muchas gracias.

Saludos
LEANDRO AREVALO
Bogotá (Colombia)
https://hymlyma.com
https://hymplus.com/
leandroalfonso111@gmail.com
leandroalfonso111@hotmail.com

[ Turbo Incremental Link64 6.98 Embarcadero 7.70 ] [ FiveWin 25.01 ] [ xHarbour 64 bits) ]
acuellar
Posts: 1713
Joined: Tue Oct 28, 2008 06:26 PM

Re: Cambiar icono carpeta desde codigo

Posted: Mon Nov 15, 2021 08:23 PM

Buenas estimados

Y la función cRelativePath donde la encuentro?

Saludos,



Adhemar Cuéllar

karinha
Posts: 8716
Joined: Tue Dec 20, 2005 07:36 PM

Re: Cambiar icono carpeta desde codigo

Posted: Mon Nov 15, 2021 10:42 PM
acuellar wrote:Buenas estimados

Y la función cRelativePath donde la encuentro?


Borland shell32.lib


regards, saludos
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
acuellar
Posts: 1713
Joined: Tue Oct 28, 2008 06:26 PM

Re: Cambiar icono carpeta desde codigo

Posted: Tue Nov 16, 2021 08:35 PM

Gracias estimado Joao

Pero no está en en la Lib Shell32 :(

Saludos,



Adhemar Cuéllar

karinha
Posts: 8716
Joined: Tue Dec 20, 2005 07:36 PM

Re: Cambiar icono carpeta desde codigo

Posted: Tue Nov 16, 2021 10:16 PM
Mira estimado:

http://forums.fivetechsoft.com/viewtopic.php?p=219133&sid=45f46e346cd14b3af0b2efd091e281f1#p219133

Regards, saludos.
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
karinha
Posts: 8716
Joined: Tue Dec 20, 2005 07:36 PM

Re: Cambiar icono carpeta desde codigo

Posted: Tue Nov 16, 2021 10:37 PM
Code (fw): Select all Collapse
// \samples\CRELATIV.PRG

#Include "FiveWin.ch"

FUNCTION Main()

   ? SetFolderIcon( "c:\FWH1905\icofolder", "c:\FWH1905\icons\fivetech.ico", ;
      "FWH SetFolderIcon() function" )

RETURN NIL

FUNCTION SetFolderIcon( cFolder, cFileIco, cInfoTip )

   local lSet  := .f.
   local oIni, cIni, cSec := ".ShellClassInfo"

   cFolder  := RemRight( cFolder, "\" )

   DEFAULT cInfoTip := ""

   IF FILE( cFileIco ) .AND. Lower( cFileExt( cFileIco ) ) == "ico" .AND. ;
      .NOT. FILE( cFolder )

      IF .NOT. lIsDir( cFolder )

         lMkFullPath( cFolder )

      ENDIF

      IF lIsDir( cFolder )

         SetFAttr( cFolder, 4 )

         cFileIco := cRelativePath( cFileIco, cFolder )
         cIni     := cFolder + "\desktop.ini"

         INI oIni FILE cIni
         SET SECTION cSec ENTRY "ConfirmFileOp" TO 0        OF oIni
         SET SECTION cSec ENTRY "NoSharing"     TO 1        OF oIni
         SET SECTION cSec ENTRY "IconFile"      TO cFileIco OF oIni
         SET SECTION cSec ENTRY "IconIndex"     TO 0        OF oIni
         SET SECTION cSec ENTRY "InfoTip"       TO cInfoTip OF oIni

         SetFAttr( cIni, 2 )

         lSet  := .t.

      ENDIF

   ENDIF

   ? cIni // ??

RETURN( lSet )

// FIN / END


Regards, saludos.
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
acuellar
Posts: 1713
Joined: Tue Oct 28, 2008 06:26 PM

Re: Cambiar icono carpeta desde codigo

Posted: Tue Nov 16, 2021 10:39 PM

Gracias Estimado

Tengo FWH 18.04 :(

Saludos,



Adhemar Cuéllar

nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM

Re: Cambiar icono carpeta desde codigo

Posted: Wed Nov 17, 2021 02:24 PM
acuellar wrote:Buenas estimados

Y la función cRelativePath donde la encuentro?

You need to upgrade FWH
Regards



G. N. Rao.

Hyderabad, India
nageswaragunupudi
Posts: 10733
Joined: Sun Nov 19, 2006 05:22 AM

Re: Cambiar icono carpeta desde codigo

Posted: Wed Nov 17, 2021 02:24 PM
acuellar wrote:Buenas estimados

Y la función cRelativePath donde la encuentro?

You need to upgrade FWH
Regards



G. N. Rao.

Hyderabad, India
acuellar
Posts: 1713
Joined: Tue Oct 28, 2008 06:26 PM

Re: Cambiar icono carpeta desde codigo

Posted: Wed Nov 17, 2021 07:01 PM

Thanks Mr. Rao

Saludos,



Adhemar Cuéllar

Continue the discussion

Static archive · New replies & topics via GitHub Discussions