Treport de Tabla SQL con FWH nativo ( parte 3 ) (RESUELTO)

Board index FiveWin para Harbour/xHarbour Treport de Tabla SQL con FWH nativo ( parte 3 ) (RESUELTO)

Posts: 1279

Joined: Mon Feb 06, 2006 04:28 PM

Treport de Tabla SQL con FWH nativo ( parte 3 ) (RESUELTO)
Posted: Tue Mar 29, 2022 01:19 PM

Como que ya me siento mal de estar preguntando cosas que debería tener resueltas, pero lo cierto es que tengo un nuevo problema con treport y rowset que no he logrado resolver.

Code (fw): Select all Collapse

          PRINT oPrn FILE ".\PDFS\" + wfecha + "-" + whora + ".pdf"
          REPORT oReport ;
               TITLE  "*** Informe de Entrada al Desosado ***",;
                    wfecha + " de las " + wHorainic + " hasta las " + wHoraFin ;
               HEADER "Fecha: " + dtoc(date()),;
                    "Hora:  " + time() ;
                    RIGHT ;
                    FOOTER "Página: " + str(oReport:nPage,4) ;
                    CENTERED ;
                    SUMMARY ;
                    TO DEVICE oPrn 
           
          COLUMN TITLE "Cantidad" ;
               DATA oRs:Cantidad  ;
               PICTURE "99,999"   ;
               SIZE 14             ;
               FONT 1             ;
               TOTAL
     
          COLUMN TITLE "Peso Neto";   
               DATA oRs:PesoNeto  ;
               PICTURE "99,999.99";
               SIZE 12            ;           
               FONT 1             ;
               TOTAL
               
          COLUMN TITLE "Peso Promedio";   
               DATA ( oRs:PesoNeto / oRs:Cantidad ) ;
               PICTURE "999,999.99"   ;
               SIZE 12                ;           
               FONT 1        
     
     GROUP ON oRs:ProductoId ;
               HEADER "Producto: " + Alltrim( oRs:ProductoId ) + "-" + oRs:DescProd font 1
     
     END REPORT
     
     oReport:bInit :=  {|| oRs:movefirst()}
     oReport:bSkip :=  {|| oRs:movenext()}
    
     ACTIVATE REPORT oReport WHILE !oRs:Eof() ON STARTGROUP oReport:NewLine()  ;
                                              ON STARTPAGE  StartPage()

Este es el resultado, la ultima columna en blanco.

¿Que podrá ser?

Saludos/Regards,

José Murugosa

"Los errores en programación, siempre están entre la silla, el teclado y la IA!!"

cmsoft

Posts: 1344

Joined: Wed Nov 16, 2005 09:14 PM

Re: Treport de Tabla SQL con FWH nativo ( parte 3 )
Posted: Wed Mar 30, 2022 01:45 AM

José:
Al estar SUMMARY, y la columna 3 no tener TOTAL, es esperable que salga de esa manera.
Agrega la clausula TOTAL a la columna 3

Code (fw): Select all Collapse

COLUMN TITLE "Peso Promedio";  
               DATA ( oRs:PesoNeto / oRs:Cantidad ) ;
               PICTURE "999,999.99"   ;
               SIZE 12                ;          
               TOTAL;
               FONT 1

Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com

jose_murugosa

Posts: 1279

Joined: Mon Feb 06, 2006 04:28 PM

Re: Treport de Tabla SQL con FWH nativo ( parte 3 )
Posted: Wed Mar 30, 2022 12:11 PM

Muchas gracias por tu respuesta César.
Tienes razón, no me había dado cuenta.

Pero ahora el problema es otro, el total en la columna de peso neto me da igual que el de peso neto/cantidad.

Code (fw): Select all Collapse

          PRINT oPrn FILE ".\PDFS\" + wfecha + "-" + whora + ".pdf"
          REPORT oReport ;
               TITLE  "*** Informe de Entrada al Desosado ***",;
                    wfecha + " de las " + wHorainic + " hasta las " + wHoraFin ;
               HEADER "Fecha: " + dtoc(date()),;
                    "Hora:  " + time() ;
                    RIGHT ;
                    FOOTER "Página: " + str(oReport:nPage,4) ;
                    CENTERED ;
                    SUMMARY ;
                    TO DEVICE oPrn 
           
          COLUMN TITLE "Cantidad" ;
               DATA oRs:Cantidad  ;
               PICTURE "99,999"   ;
               SIZE 14            ;
               FONT 1             ;
               TOTAL
     
          COLUMN TITLE "Peso Neto";   
               DATA oRs:PesoNeto  ;
               PICTURE "99,999.99";
               SIZE 12            ;           
               FONT 1             ;
               TOTAL
          
          COLUMN TITLE "Peso Promedio";   
               DATA ( oRs:PesoNeto / oRs:Cantidad ) ;
               PICTURE "999,999.99"   ;
               SIZE 12                ;           
               FONT 1                 ;        
               TOTAL

OTRA PREGUNTA: EXISTE UNA CLAUSULA PARA QUE EN LUGAR DE TOTALIZAR SAQUE UN PROMEDIO

Saludos/Regards,

José Murugosa

"Los errores en programación, siempre están entre la silla, el teclado y la IA!!"

cmsoft

Posts: 1344

Joined: Wed Nov 16, 2005 09:14 PM

Re: Treport de Tabla SQL con FWH nativo ( parte 3 )
Posted: Wed Mar 30, 2022 08:02 PM

Segun lo que entiendo, debería darte la suma de los precios promedios...
Puedes cambiarle la formula de calculo del total a la columna 3,
oReport:aColumns[3]:btotalexpr = {|| Tufuncion()}
Pero nunca lo he hecho, habría que buscar en el foro a ver si hay ejemplos.

Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com

FranciscoA

Posts: 2170

Joined: Fri Jul 18, 2008 01:24 AM

Re: Treport de Tabla SQL con FWH nativo ( parte 3 )
Posted: Thu Mar 31, 2022 02:51 AM

José:
Nunca lo he hecho con SUMARY y SQL, pero intenta asi:

Code (fw): Select all Collapse

oReport:bEndGroup:={||  oReport:aGroups[1]:aTotal[3]:= (oReport:aGroups[1]:aTotal[2] / oReport:aGroups[1]:aTotal[1] )  }

Francisco J. Alegría P.

Chinandega, Nicaragua.

Fwxh-MySql-TMySql

jose_murugosa

Posts: 1279

Joined: Mon Feb 06, 2006 04:28 PM

Re: Treport de Tabla SQL con FWH nativo ( parte 3 )
Posted: Thu Mar 31, 2022 07:06 PM

Queridos Francisco y César

Gracias mil por vuestra ayuda!!!!!

Finalmente quedó con estos cambios:

Code (fw): Select all Collapse

          oReport:bEndGroup  := {|| oReport:aGroups[1]:aTotal[3]:= (oReport:aGroups[1]:aTotal[2] / oReport:aGroups[1]:aTotal[1] )  }
          oReport:bEnd           := {|| oReport:aColumns[3]:nTotal := oReport:aColumns[2]:nTotal / oReport:aColumns[1]:nTotal }
          oReport:bInit           := {|| oRs:movefirst()}
          oReport:bSkip          := {|| oRs:movenext()}
          oReport:lPageTotal  := .f.

Gracias por dedicarme tiempo para que pudiera salir del atolladero.

Saludos/Regards,

José Murugosa

"Los errores en programación, siempre están entre la silla, el teclado y la IA!!"

FiveTech Support Forums

Continue the discussion