topic-43244

Posts: 1772

Joined: Thu Sep 05, 2019 05:32 AM

show DELETED Record in XBROWSE
Posted: Fri May 26, 2023 03:39 AM

hi,

i want to shsw DELETED Record so i use

    SET DELETED OFF
   BrowseDBF( cPath, cFile, cAlias, cRdd )
   SET DELETED ON

but when call

Code (fw): Select all Collapse

   oBrwDBF:Delete( .T. ) // what is Parameter .T. for ?

i got a "YesNo Box" and after "Yes" Record disappear in XBROWSE ... :?

so how configure XBROWSE to "show" DELETED Record which i can RECALL :?:

p.s. open DBF have no Index

greeting,

Jimmy

Jimmy

Posts: 1772

Joined: Thu Sep 05, 2019 05:32 AM

Re: show DELETED Record in XBROWSE
Posted: Fri May 26, 2023 02:17 PM

hi,

did nobody have a Solution to "show" DELETED Record in XBROWSE :?:

greeting,

Jimmy

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: show DELETED Record in XBROWSE
Posted: Fri May 26, 2023 02:44 PM

I am just starting my work.

Pls wait

Regards

G. N. Rao.

Hyderabad, India

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: show DELETED Record in XBROWSE
Posted: Fri May 26, 2023 03:16 PM

what is Parameter .T. for ?

Syntax:

Code (fw): Select all Collapse

oBrw:Delete( [lMessage] )

If the lMessage parameter is .T., a MsgeYesNo() box is displayed and only if the user selects "Yes", the Record is deleted()
Otherwise, the record is deleted without any message.

If SET DELETED IS ON, deleted records are not displayed and after deletion, the deleted record goes out sight.
If SET DELETED IS OFF, all deleted records appear and even after deletion, the record still appears.
We confirm this behavior.

If in your case, after deletion, the record disappears, Set Deleted might be ON at that time. We request you to recheck your program.

Regards

G. N. Rao.

Hyderabad, India

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: show DELETED Record in XBROWSE
Posted: Fri May 26, 2023 03:28 PM

Test Program

Code (fw): Select all Collapse

#include "fivewin.ch"
#include "set.ch"

function Main()

   local oDlg, oBrw, oBar, oChk

   COPY FILE STATES.DBF TO STATES2.DBF

   USE STATES2 NEW SHARED VIA "DBFNTX"
   SET DELETED OFF

   DEFINE DIALOG oDlg SIZE 400,400 PIXEL TRUEPIXEL
   DEFINE BUTTONBAR oBar OF oDlg SIZE 64,64 2007

   @ 80,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE "STATES2" ;
      COLUMNS "DELETED() AS DELETED","CODE","NAME" ;
      CELL LINES NOBORDER

   WITH OBJECT oBrw
      :RecSelShowRecNo()
      :Deleted:SetCheck(,.t.)
      :bClrStd := { || { CLR_BLACK, ;
            If( ( oBrw:cAlias )->( DELETED() ), CLR_HGRAY, CLR_WHITE ) } }

      //
      :CreateFromCode()
   END

   DEFINE BUTTON OF oBar PROMPT "Delete" CENTER ACTION oBrw:Delete()
   DEFINE BUTTON OF oBar PROMPT "Recall" CENTER ;
      ACTION ( ( oBrw:cAlias )->( If( DELETED() .and. oBrw:Lock(), ;
                  DBRECALL(), nil ) ), ;
                  oBrw:Refresh() )
   DEFINE BUTTON OF oBar PROMPT "SET DELETED" CENTER ;
      ACTION (Set(_SET_DELETED,!Set(_SET_DELETED)),;
      oBar:Refresh(),oBrw:GoTop(),oBrw:Refresh() )
   oBar:bPainted  := { || oBar:SayText( "DELETED " + ;
      If( Set(_SET_DELETED), "ON", "OFF" ),{,,,-30}, "R",,CLR_HRED ) }

   ACTIVATE DIALOG oDlg CENTERED

return nil

Regards

G. N. Rao.

Hyderabad, India

Jimmy

Posts: 1772

Joined: Thu Sep 05, 2019 05:32 AM

Re: show DELETED Record in XBROWSE
Posted: Fri May 26, 2023 04:40 PM

hi,

you Sample work

i saw these Line

Code (fw): Select all Collapse

    COLUMNS "DELETED() AS DELETED","CODE","NAME" ;

   :RecSelShowRecNo()
   :Deleted:SetCheck(,.t.)

Sample need COLUMNS "DELETED() AS DELETED" ... but i don´t know Column as i don´t have "fix" DBF

i do use

Code (fw): Select all Collapse

   COLUMNS ColsNumber( DBSTRUCT() ) ;

hm ... can i build a String of COLUMNS before create XBROWSE, will that work :?:

--

i have add Msginfo(() before ACTIVATE

Code (fw): Select all Collapse

   Msginfo(" DETELED IS " + If( Set(_SET_DELETED), "ON", "OFF" ) )

   ACTIVATE WINDOW oWnd ;

just to be sure that DELETED if OFF

but still i do not seen any DELETED Record in XBROWSE ... :(

Code (fw): Select all Collapse

      @ nBhight,  2 XBROWSE oBrwDBF SIZE nWidth - 20, nHeight - 90 PIXEL OF oWnd ;
              DATASOURCE cAlias ;                 // ALIAS cAlias
              COLUMNS ColsNumber( DBSTRUCT() ) ;
              FONT oFontDefault ;
              COLOR BFcolor, BGcolor ;
              CELL LINES NOBORDER FASTEDIT AUTOCOLS AUTOSORT

      oBrwDBF:nStretchCol := STRETCHCOL_WIDEST

      oBrwDBF:lRecordSelector := .F.
      oBrwDBF:bChange := { || SayStatusDBF( oBrwDBF, oGet, @nVar ) }
      oBrwDBF:bOnSort := { || oBrwDBF:Refresh() }

      // oBrwDBF:bClrEdit     := { || { BFcolor, BGcolor } }
      oBrwDBF:bClrStd := { || { BFcolor, BGcolor } }
      // oBrwDBF:bClrSel      := { || { BFcolor, BGcolor } }
      oBrwDBF:bClrHeader := { || { BFcolor, BGcolor } }
      // oBrwDBF:bClrFooter   := { || { BFcolor, BGcolor } }
      // oBrwDBF:bClrSelFocus := { || { CLR_WHITE, GetSysColor( COLOR_MENUHILIGHT ) } }
      oBrwDBF:bClrGrad := bGradient

      // edit CELL
      // oBrwDBF:nEditTypes := EDIT_GET
      // override F2 CELL edit
      // oBrwDBF:lF2KeyToEdit := .T.

      * oBrwDBF:RecSelShowRecNo()
      * oBrwDBF:Deleted:SetCheck(,.t.) // COLUMNS "DELETED() AS DELETED",

      oBrwDBF:CreateFromCode()

what i´m doing wrong that DELETED Record are not show in XBROWSE

will try to make Sample

greeting,

Jimmy

Jimmy

Posts: 1772

Joined: Thu Sep 05, 2019 05:32 AM

Re: show DELETED Record in XBROWSE
Posted: Fri May 26, 2023 11:33 PM

hi,

found a Solution for "me" , but not able to make a Sample

in my MAIN i have

Code (fw): Select all Collapse

   SET DELETED ON

i have try this

Code (fw): Select all Collapse

   USE (cDBF)
   SET DELETED OFF

so it was AFTER open DBF ...
this make the funny Effect that MsgInfo say "OFF" but DBF "react" like "ON"

now when change to

Code (fw): Select all Collapse

   SET DELETED OFF 
   USE (cDBF)

it work :)

but as i say i can´t reproduce it in a small Sample

greeting,

Jimmy

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: show DELETED Record in XBROWSE
Posted: Sat May 27, 2023 09:40 AM

Whatever happens to your end, you should be able to reproduce with a sample.

Like whatever we said, we proved with a sample.

Regards

G. N. Rao.

Hyderabad, India

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: show DELETED Record in XBROWSE
Posted: Sat May 27, 2023 09:40 AM

Whatever happens to your end, you should be able to reproduce with a sample.

Like whatever we said, we proved with a sample.

Regards

G. N. Rao.

Hyderabad, India

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: show DELETED Record in XBROWSE
Posted: Sun May 28, 2023 02:32 AM

If you can please clarify my doubt, I am interested in knowing this:

In case of Clipper/Harbour, SET DELETED OFF/ON is a Global (application wide) setting, whereas in case of Dbase/FoxPro, this setting is a workarea wise setting.

That means, in this code:

Code (fw): Select all Collapse

SELECT 1
SET DELETED OFF
SELECT 2
SET DELETED ON
SELECT 1
// now whatis the status?
// In Clipper/Harbour, it is ON
// In DBase/FoxPrro is OFF
// In Xbase++ ???

Can you kindly clarify if XBase++ is compatible with Dbase/FoxPro behavior or Clipper/Harbour behavior?

Regards

G. N. Rao.

Hyderabad, India

Jimmy

Posts: 1772

Joined: Thu Sep 05, 2019 05:32 AM

Re: show DELETED Record in XBROWSE
Posted: Sun May 28, 2023 04:43 AM

hi,

Xbase++ SET DELETED OFF/ON are Global (application wide) setting, even in Thread which have a other "Workspacelist"

i can send you hole Project as i´mm not able (yet) to build a Sample which same Effect.

it doesn´t matter in "this" Project as DUALGRID but for other Project i have to find out what is going on

greeting,

Jimmy

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: show DELETED Record in XBROWSE
Posted: Sun May 28, 2023 06:35 AM

Yes, please.

Though I am not sure if can understand.

Regards

G. N. Rao.

Hyderabad, India

FiveTech Support Forums

Continue the discussion