FiveTech Support Forums

FiveWin / Harbour / xBase community
Board indexAll discussionsLogin (GitHub)
Board index FiveWin para Harbour/xHarbour Enviar Correos CDO con fwh2307
EASYSOFT
Posts: 195
Joined: Sat Oct 22, 2005 01:17 PM
Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 05:30 PM
Estimados buenas tardes.

Al actualizarme a la versión fwh2307 ya no se puede enviar los correos utilizando CDO
TRY
oMsg := CREATEOBJECT ( "CDO.Message" )
WITH OBJECT oMsg
:Configuration = oCfg
:From = cFrom
:To = cTo
:CC = cCC
:BCC = cBCC
:Subject = cSubject
:TextBody = cMsg
For x := 1 To Len( aAttach )
if aAttach[x] <> NIL
:AddAttachment(AllTrim(aAttach[x]))
endif
Next
:Send()
END WITH
lRet := .t.
CATCH
MsgInfo("No fue posible enviar el correo")
lRet := .f.
END

Es parte del codigo , si trato con la versión que tenia anteriormente si funciona.

Quiza me puedan ayudar

Saludos

Saludos

Oscar

Fwh 23.10, bcc55

karinha
Posts: 8515
Joined: Tue Dec 20, 2005 07:36 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 06:36 PM
Intente asi:
Code (fw): Select all Collapse
   oMsg:AddAttachment( AllTrim( aAttach[x] ) )
Regards, saludos.
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
EASYSOFT
Posts: 195
Joined: Sat Oct 22, 2005 01:17 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 07:20 PM

Karinha muchas gracias

Sigue igual no se envía el correo, quiza otra alternativa

Saludos

Saludos

Oscar

Fwh 23.10, bcc55

karinha
Posts: 8515
Joined: Tue Dec 20, 2005 07:36 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 07:25 PM
POST completo para pruebas.

Prueba con ACBRMAIL.DLL

https://mega.nz/file/ZY0lCC4b#J087eB2aPhfZiNynwgaEnkwvrPF2P6y7Pifxl_41Qco

Salu2
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 07:38 PM
Cual es el error que te da?
Que contiene a aAttach[x]? Solo el nombre del archivo o el path completo?
Code (fw): Select all Collapse
TRY
   oMsg := CREATEOBJECT ( "CDO.Message" )
   WITH OBJECT oMsg
       :Configuration = oCfg
       :From = cFrom
       :To = cTo
       :CC = cCC
       :BCC = cBCC
       :Subject = cSubject
       :TextBody = cMsg
       For x := 1 To Len( aAttach )
          if aAttach[x] <> NIL
             :AddAttachment(AllTrim(aAttach[x])) 
             // Si solo guardas el nombre y no el path completo del archivo puedes usar
             // :AddAttachment(TrueName( AllTrim(aAttach[x] ) ) )
          endif
       Next
       :Send()
   END WITH
   lRet := .t.
   CATCH oError
       MsgInfo("No fue posible enviar el correo"+CRLF+oError:Description,"Atencion") // Capura aqui el error que te da al enviar
       lRet := .f.
END
Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
karinha
Posts: 8515
Joined: Tue Dec 20, 2005 07:36 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 07:59 PM
Muestre esto:
Code (fw): Select all Collapse
  STATIC cAttach := ""
  STATIC aAttach := {}
¿Cómo estás "atrapando" los archivos adjuntos?

salud2
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
Jimmy
Posts: 1772
Joined: Thu Sep 05, 2019 05:32 AM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 08:13 PM
hi,

how does you oCfg look like :?:
Code (fw): Select all Collapse
Configuration = oCfg
greeting,

Jimmy
karinha
Posts: 8515
Joined: Tue Dec 20, 2005 07:36 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 08:23 PM
Jimmy,
Code (fw): Select all Collapse
FUNCTION SendEmailLog( cErrorLog )

   LOCAL cEmailResp

   PUBLIC cEMailCli  // EMAIL PARA RESPOSTA DO CLIENTE

   cEmailResp := LOWER( cEMailCli )

   TRY
      oCfg := CREATEOBJECT( "CDO.Configuration" )

       WITH OBJECT oCfg:Fields

          :Item( "http://schemas.microsoft.com/cdo/configuration/smtpserver"       ):Value := "smtp.pleno.com.br"
          :Item( "http://schemas.microsoft.com/cdo/configuration/smtpserverport"   ):Value := 587
          :Item( "http://schemas.microsoft.com/cdo/configuration/sendusing"        ):Value := 2
          :Item( "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate" ):Value := .T.
          :Item( "http://schemas.microsoft.com/cdo/configuration/smtpusessl"       ):Value := .F.
          :Item( "http://schemas.microsoft.com/cdo/configuration/sendusername"     ):Value := "joao@pleno.com.br" //<seu_email>
          :Item( "http://schemas.microsoft.com/cdo/configuration/sendpassword"     ):Value := "password" // <sua_senha>
          :Item( "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout")   :Value = 30
          :Update()

       END WITH

   CATCH oError

      MsgInfo( "Não Foi possível Enviar o e-Mail!"                    +CRLF+ ;
               "Configure o Enviador de Email da Sua Empresa."        +CRLF+ ;
               "Error: "     + Transform(oError:GenCode,   nil) + ";" +CRLF+ ;
               "SubC: "      + Transform(oError:SubCode,   nil) + ";" +CRLF+ ;
               "OSCode: "    + Transform(oError:OsCode,    nil) + ";" +CRLF+ ;
               "SubSystem: " + Transform(oError:SubSystem, nil) + ";" +CRLF+ ;
               "Mensaje: "   + oError:Description, "CDO.Configuração" )
    
   END

   //aAttach := SetErrorPath() + SetErrorFileName()
   IF lErroVemFalhaXML

      aAttach := cDirPleno + "\VONFEUTIL2G.LOG"  // anexo do erro

      lErroVemFalhaXML := .F.

   ELSE

      aAttach := cDirPleno + "\ERROR.LOG"  // anexo do erro

   ENDIF

   TRY

      oMsg := CREATEOBJECT ( "CDO.Message" )

      WITH OBJECT oMsg

         :Configuration = oCfg

         :From = CHR(34) + "Envio Automático de Erro da NF-e" + CHR(34)+ "joao@pleno.com.br"

         IF .NOT. EMPTY( cEmailResp )

            :To = "contato@pleno.com.br; joao@pleno.com.br" + "; " + ;
                  ALLTRIM(cEmailResp)


         ELSE

            :To = "contato@pleno.com.br; joao@pleno.com.br"

         ENDIF

         :Subject = "Envio Automático de Erro da NF-e"

         :MDNRequested = .F.  // nao quero confirmacao sou eu enviando.

         :TextBody = cErrorLog

         :AddAttachment(aAttach)

         :Send()

      END WITH

      MsgInfo( "Email de Erro Enviado com Sucesso..." +CRLF+ ;
               "Tecle <Enter> Para Continuar...                        ",       ;
               "Atenção - Erro Enviado com Sucesso ao Suporte.         " )

   CATCH oError

      MsgInfo( "Não Foi possível Enviar o e-Mail!"                    +CRLF+ ;
               "Configure o Enviador de Email da Sua Empresa."        +CRLF+ ;
               "Error: "     + Transform(oError:GenCode,   nil) + ";" +CRLF+ ;
               "SubC: "      + Transform(oError:SubCode,   nil) + ";" +CRLF+ ;
               "OSCode: "    + Transform(oError:OsCode,    nil) + ";" +CRLF+ ;
               "SubSystem: " + Transform(oError:SubSystem, nil) + ";" +CRLF+ ;
               "Mensaje: "   + oError:Description, "CDO.Message" )
   END TRY

RETURN NIL
Regards, saludos.
João Santos - São Paulo - Brasil - Phone: +55(11)95150-7341
EASYSOFT
Posts: 195
Joined: Sat Oct 22, 2005 01:17 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 08:28 PM

Gracias

No da error sale este mensaje

MsgInfo("No fue posible enviar el correo")

Voy a probar las alternativas sugeridas y comentaré

Saludos

Saludos

Oscar

Fwh 23.10, bcc55

EASYSOFT
Posts: 195
Joined: Sat Oct 22, 2005 01:17 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 08:42 PM
Jimmy wrote:hi,

how does you oCfg look like :?:
Code (fw): Select all Collapse
Configuration = oCfg
Contiene lo siguiente :

CDO.Configuration

Saludos

Oscar

Fwh 23.10, bcc55

EASYSOFT
Posts: 195
Joined: Sat Oct 22, 2005 01:17 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 09:06 PM
Este es el error

https://ibb.co/vZnkWmJ

Saludos

Saludos

Oscar

Fwh 23.10, bcc55

cmsoft
Posts: 1344
Joined: Wed Nov 16, 2005 09:14 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 09:31 PM
Con que cuenta de correos envias ? (Gmail, yahoo, outlook?)
Por las dudas, mira este hilo en otro foro que habla del tema
http://hmgforum.com/viewtopic.php?t=3473&sid=0c209235f17e72220599b75a60092752
Salu2
Cesar Gomez
https://www.bcnsoft.com.ar
https://www.pedidosbcn.com
EASYSOFT
Posts: 195
Joined: Sat Oct 22, 2005 01:17 PM
Re: Enviar Correos CDO con fwh2307
Posted: Mon Aug 21, 2023 09:50 PM
cmsoft wrote:Con que cuenta de correos envias ? (Gmail, yahoo, outlook?)
Por las dudas, mira este hilo en otro foro que habla del tema
http://hmgforum.com/viewtopic.php?t=3473&sid=0c209235f17e72220599b75a60092752
Envio de gmail.

Voy a revisar el foro que me sugieres muchas gracias.

He revisado el foro y las sugerencias, parte de lo que comentan refieren al tema de seguridades que maneja gmail, todo ese tema lo tengo controlado como decía al inicio del post, el problema se me presenta solo con la nueva versión de fwh2307.

Saludos

Saludos

Oscar

Fwh 23.10, bcc55

EASYSOFT
Posts: 195
Joined: Sat Oct 22, 2005 01:17 PM
Re: Enviar Correos CDO con fwh2307 RESUELTO
Posted: Mon Aug 21, 2023 10:42 PM

Resuelto.

EL problema es la opción password del get, lo he comentado y se envió el mensaje, voy a inventigar que tiene de nuevo esta opción o si es algo Adicional

@ 030, 006 GET oGet[2] VAR cPass SIZE 80, 10 PIXEL OF oDlg Update

              * oGet[2]:lPassWord := .T.

Saludos

Oscar

Fwh 23.10, bcc55

EASYSOFT
Posts: 195
Joined: Sat Oct 22, 2005 01:17 PM
Re: Enviar Correos CDO con fwh2307 RESUELTO
Posted: Mon Aug 21, 2023 11:03 PM
EASYSOFT wrote:Resuelto.

EL problema es la opción password del get, lo he comentado y se envió el mensaje, voy a inventigar que tiene de nuevo esta opción o si es algo Adicional

@ 030, 006 GET oGet[2] VAR cPass SIZE 80, 10 PIXEL OF oDlg Update
* oGet[2]:lPassWord := .T.
Quedo de la siguiente manera

@ 030, 006 GET oGet[2] VAR cPass SIZE 90, 10 PIXEL OF oDlg password Update

Saludos

Oscar

Fwh 23.10, bcc55

Static archive · New replies & topics via GitHub Discussions