Como evitar abrir 2 veces la misma ventana child

Posts: 1279

Joined: Mon Feb 06, 2006 04:28 PM

Como evitar abrir 2 veces la misma ventana child
Posted: Tue Nov 28, 2023 02:58 PM

Buenas tardes, queridos amigos del foro.
Tengo una consulta:

Tengo una ventana mdi con menú.
Por medio del menú abro diferentes ventanas child que hacen cosas diferentes.
¿Cómo puedo hacer para que cuando selecciono del menú una opción elegida previamente en lugar de abrir una nueva ventana child con lo mismo, ponga foco en la ventana correspondiente que ya está abierta?
¿Es posible hacer esto?

Gracias desde ya por vuestra atención. :D

Saludos/Regards,

José Murugosa

"Los errores en programación, siempre están entre la silla, el teclado y la IA!!"

sysctrl2

Posts: 1144

Joined: Mon Feb 05, 2007 07:15 PM

Re: Como evitar abrir 2 veces la misma ventana child
Posted: Tue Nov 28, 2023 05:00 PM

a ver si es lo que buscas
saludos
https://forums.fivetechsupport.com/viewtopic.php?f=6&t=37823&hilit=oWnd+%3D+NIL

Cesar Cortes Cruz

SysCtrl Software

Mexico

' Sin +- FWH es mejor "

jvtecheto

Posts: 607

Joined: Mon Mar 04, 2013 04:32 PM

Re: Como evitar abrir 2 veces la misma ventana child
Posted: Tue Nov 28, 2023 07:36 PM

Hola Jose.

Yo lo que hago es que desabilito las opciones que abren la ventana, como normalmente lo tenemos en un menu y en un
boton de una barra.
En la funcion que llamo a la ventana hija ejemplo

Code (fw): Select all Collapse

ObrasBrw( oMenuObr, oObra )

las variables son estaticas y las tengo en el prg. principal
entonces dentro de la funcion las desabilito.

Code (fw): Select all Collapse

oMenuObr:Disable()
oObra:Disable()

y compruebo que quedaran activas cuando cerrare la ventana ...

Code (fw): Select all Collapse

ACTIVATE WINDOW OWndObr VALID ( oMenuObr:Enable(), oObra:Enable()....)

A mi me funciona bien.

Saludos.

Jose.

Fwh 24.07 64 bits + Harbour 64 bits 3.2dev(r2407221137) + MSVC64

Willi Quintana

Posts: 1054

Joined: Sun Oct 09, 2005 10:41 PM

Re: Como evitar abrir 2 veces la misma ventana child
Posted: Tue Nov 28, 2023 10:33 PM

Mi estimado,,,
Antes de abrir la ventana declara un variable static. espero que captes la idea

Code (fw): Select all Collapse

static nNumWin := 0

lSalir := .f.

If nNumWin > 0
   Return(Nil)
EndIf
DEFINE WINDOW oWndM MDI  ...............
           REDEFINE BTNBMP. oSalir ,,,,,,,,,,,,,, ACTION (lSalir := .t., oWndM:End())
ACTIVATE WINDOW ON INIT (nNumWin++) VALID lSalir
If lSalir
  nNUmWin := 0
EndIf
Return(NIl)

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: Como evitar abrir 2 veces la misma ventana child
Posted: Wed Nov 29, 2023 12:47 PM

Sample:

Code (fw): Select all Collapse

#include "fivewin.ch"

function Main()

   local oWnd, oBar

   DEFINE WINDOW oWnd MDI
   DEFINE BUTTONBAR oBar OF oWnd SIZE 100,32 2007
   DEFINE BUTTON OF oBar PROMPT "Child-1" CENTER ACTION Child1()
   DEFINE BUTTON OF oBar PROMPT "Child-2" CENTER ACTION Child2()
   ACTIVATE WINDOW oWnd

return nil

function Child1()

   static oWnd

   if oWnd != nil
      oWnd:Activate()
      return nil
   endif

   DEFINE WINDOW oWnd MDICHILD OF WndMain() TITLE "CHILD-1"
   oWnd:SetColor( 0, CLR_WHITE )
   oWnd:bPainted := { || oWnd:SayText( "CHILD WINDOW-1" ) }
   oWnd:bPostEnd := { || oWnd := nil }
   ACTIVATE WINDOW oWnd

return nil

function Child2()

   static oWnd

   if oWnd != nil
      oWnd:Activate()
      return nil
   endif

   DEFINE WINDOW oWnd MDICHILD OF WndMain() TITLE "CHILD-2"
   oWnd:SetColor( 0, CLR_WHITE )
   oWnd:bPainted := { || oWnd:SayText( "CHILD WINDOW-2" ) }
   oWnd:bPostEnd := { || oWnd := nil }
   ACTIVATE WINDOW oWnd

return nil

Regards

G. N. Rao.

Hyderabad, India

jose_murugosa

Posts: 1279

Joined: Mon Feb 06, 2006 04:28 PM

Re: Como evitar abrir 2 veces la misma ventana child
Posted: Wed Nov 29, 2023 04:49 PM

Muchisimas gracias a todos por sus sugerencias y soluciones.
He logrado el objetivo gracias a Uds.
Es hermoso contar con este foro de amigos que tanto tiempo dedican a ayudarnos.
Muchiiiiiisiiiiimmmmmaaaaaas GRACIAS!!!! :D

Saludos/Regards,

José Murugosa

"Los errores en programación, siempre están entre la silla, el teclado y la IA!!"

FiveTech Support Forums

Continue the discussion