topic-43995

Board index FiveWin para Harbour/xHarbour Seleccion multiple automatica xBrowse

Posts: 851

Joined: Sun Nov 09, 2014 05:01 PM

Seleccion multiple automatica xBrowse
Posted: Fri Dec 08, 2023 10:37 AM

Saludos estimados amigos del foro.

Tengo un xBrowse con los 12 meses del año.

Necesito que al ingresar un dato numerico desde un get, por ejemplo 6, se seleccionen en el xBrowse las filas desde enero a junio.

Se que debe ser algo muy simple, pero no encuentro como hacerlo.

Gracias adelantadas por la Ayuda !!

"Los errores en programación, siempre están entre la silla y el teclado..."

Fwh 19.06 32 bits + Harbour 3.2 + Borland 7.4 + MariaDB + TDolphin

Carora, Estado Lara, Venezuela.

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: Seleccion multiple automatica xBrowse
Posted: Fri Dec 08, 2023 04:37 PM

Code (fw): Select all Collapse

function SelMonths1()

   local oDlg, oFont, oBrw
   local aData := Array( 12, 2 )
   local nMth  := 0

   AEval( aData, { |a,i| a[ 1 ] := NTOCMONTH( i ), a[ 2 ] := hb_RandomInt( 1000,9999 ) }  )

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 300,400 PIXEL TRUEPIXEL FONT oFont
   @ 20,20 SAY "Months :" GET nMth PICTURE "99" SIZE 100,24 PIXEL OF oDlg RIGHT ;
      VALID ( If( nMth < 0 .or. nMth > 12, .f., ( ;
         oBrw:aSelected := Array( nMth ), ;
         AEval( oBrw:aSelected, { |u,i| oBrw:aSelected[ i ] := i } ), ;
         oBrw:Refresh(), oBrw:SetFocus(), .t. ) ) )

   @ 50,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE aData AUTOCOLS LINES NOBORDER FOOTERS

   WITH OBJECT oBrw
      :nStretchCol   := 1
      :SetMultiSelectCol()
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

Regards

G. N. Rao.

Hyderabad, India

nageswaragunupudi

Posts: 10733

Joined: Sun Nov 19, 2006 05:22 AM

Re: Seleccion multiple automatica xBrowse
Posted: Fri Dec 08, 2023 05:15 PM

2nd alternative

Code (fw): Select all Collapse

function SelMonths2()

   local oDlg, oFont, oBrw
   local aData := Array( 12, 2 )
   local nMth  := 0

   AEval( aData, { |a,i| a[ 1 ] := NTOCMONTH( i ), a[ 2 ] := hb_RandomInt( 1000,9999 ) }  )

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 300,400 PIXEL TRUEPIXEL FONT oFont
   @ 20,20 SAY "Months :" GET nMth PICTURE "99" SIZE 100,24 PIXEL OF oDlg RIGHT ;
      VALID ( If( nMth < 0 .or. nMth > 12, .f., ( ;
         oBrw:aSelected := Array( nMth ), ;
         AEval( oBrw:aSelected, { |u,i| oBrw:aSelected[ i ] := i } ), ;
         oBrw:Refresh(), oBrw:SetFocus(), .t. ) ) )

   @ 50,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE aData AUTOCOLS LINES NOBORDER FOOTERS

   WITH OBJECT oBrw
      :nStretchCol   := 1
      :nMarqueeStyle := 6
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

Regards

G. N. Rao.

Hyderabad, India

JoseAlvarez

Posts: 851

Joined: Sun Nov 09, 2014 05:01 PM

Re: Seleccion multiple automatica xBrowse
Posted: Sat Dec 09, 2023 08:40 PM

Thansk a lot mr Rao.

Working perfect !

"Los errores en programación, siempre están entre la silla y el teclado..."

Fwh 19.06 32 bits + Harbour 3.2 + Borland 7.4 + MariaDB + TDolphin

Carora, Estado Lara, Venezuela.

FiveTech Support Forums

Continue the discussion