#include "Fivewin.ch"
#include "TTitle.ch"
#include "Common.ch"
*--
#define COLOR_WINDOW 5
#define COLOR_WINDOWTEXT 8
*--
#define COLOR_DESKTOP GETSYSCOLOR( COLOR_WINDOWTEXT ), GETSYSCOLOR( COLOR_WINDOW )
*--
MEMVAR oApp
STATIC oProve
*--
PROCEDURE Main()
*--
PUBLIC oApp := TAplication():New()
oApp:Run()
RETURN
*--
*
*--
CLASS TAplication
*--
PROTECTED:
*--
DATA oMsgBar
DATA oIconApp
DATA oMenuApp
*--
DATA oFontApp AS OBJECT INIT TFont():New("Segoe UI", 0, -14)
DATA oFontTit AS OBJECT INIT TFont():New("Verdana", 0, -16,,TRUE)
*--
METHOD MenuApp()
*--
EXPORTED:
*--
DATA oWndMain
*--
METHOD New()
METHOD Run()
METHOD End()
*--
METHOD GetIconSys() INLINE ::oIconApp
METHOD GetFontTit() INLINE ::oFontTit
METHOD GetFontApp() INLINE ::oFontApp
*--
ENDCLASS
*--
*
*--
METHOD New() CLASS TAplication
*--
DEFINE ICON ::oIconApp FILE "C:\Fwh\icons\fivetech.ico"
*--
RETURN Self
*--
*
*--
METHOD Run() CLASS TAplication
*--
DEFINE WINDOW ::oWndMain ;
TITLE FWVERSION ;
ICON ::oIconApp ;
MENU ::MenuApp() ;
COLOR COLOR_DESKTOP MDI PIXEL
*--
::oWndMain:SetFont( ::oFontApp )
DEFINE MSGBAR ::oMsgBar OF ::oWndMain PROMPT FWDESCRIPTION + " " + HB_Compiler() 2010
*--
WITH OBJECT ::oWndMain
*--
:oMsgBar:KeybOn()
:oMsgBar:DateOn()
*--
:bValid := {|| ::End() }
END
*--
ACTIVATE WINDOW ::oWndMain MAXIMIZED
RETURN NIL
*--
*
*--
METHOD End() CLASS TAplication
*--
IF ! MsgYesNo("¿Seguro de Salir?",FWVERSION)
RETURN FALSE
ENDIF
*--
::oFontApp:End()
*--
RELEASE ALL
HB_SYMBOL_UNUSED( oApp )
*--
FreeResources()
Hb_GCall( TRUE )
*--
CLEAR MEMORY
*--
IF HB_FileExists("checkres.txt")
FErase("checkres.txt")
ENDIF
*--
CheckRes()
RETURN TRUE
*--
*
*--
METHOD MenuApp() CLASS TAplication
*--
LOCAL oMenu
*--
Menu oMenu
MenuItem "&Opciones"
Menu
MenuItem "Proveedores" ACTION Proveedores(Self)
Separator
MenuItem "Salir" ACTION ::oWndMain:End()
EndMenu
EndMenu
RETURN oMenu
*--
*
*--
PROCEDURE Proveedores(Self)
*--
oProve := ProveedoresController():New( ProveedorDAO():Default(), ProveedorView():New(), Self )
oProve:Run()
RETURN
*--
*
*--
CLASS ProveedoresController
*--
PROTECTED:
*--
METHOD UpdateValues()
*--
EXPORTED:
*--
DATA oCtrl
DATA oView
DATA oModel
DATA oParent
DATA oModelDAO
*--
METHOD New()
METHOD Run()
*--
METHOD Init()
METHOD Find()
METHOD Save()
*--
METHOD Delete()
METHOD GetModel() INLINE ::oModel
METHOD ValidaCodigo()
ENDCLASS
*--
*
*--
METHOD New(oModel, oView, oCtrl) CLASS ProveedoresController
*--
::oModel := oModel
::oView := oView
::oCtrl := oCtrl
*--
::oParent := oCtrl
::oModelDAO := ProveedorDAO():New()
RETURN Self
*--
*
*--
METHOD Run() CLASS ProveedoresController
*--
::oView:SetController(Self)
::oView:Show()
::UpdateValues()
RETURN NIL
*--
*
*--
METHOD Init() CLASS ProveedoresController
*--
::oModel := ::oModelDAO:Default()
::UpdateValues()
RETURN NIL
*--
*
*--
METHOD Find() CLASS ProveedoresController
*--
MsgInfo( "Aquí Muestra el buscador de datos",FWVERSION)
RETURN NIL
*--
*
*--
METHOD Save() CLASS ProveedoresController
*--
MsgInfo( "Aquí graba los datos",FWVERSION)
RETURN NIL
*--
*
*--
METHOD Delete() CLASS ProveedoresController
*--
MsgInfo( "Aquí eliina los datos",FWVERSION)
RETURN NIL
*--
*
*--
METHOD UpdateValues() CLASS ProveedoresController
*--
LOCAL sRecord := ""
*--
IF ( Empty( sRecord ) )
::oView:SetTitle(" Proveeores - [ Archivo Vacio ]" )
ELSE
::oView:SetTitle(" Proveedores - [ Ultimo " + sRecord + " ]")
ENDIF
*--
::oView:oGetCodigo:cText( ::oModel:GetCodigo() )
::oView:oGetNombre:cText( ::oModel:GetNombre() )
*--
::oView:oGetRif:cText( ::oModel:GetRif() )
::oView:oGetNit:cText( ::oModel:GetNit() )
*--
::oView:oGetRetiva:cText( ::oModel:GetRetencionIva() )
::oView:oGetRetIslr:cText( ::oModel:GetRetencionISLR() )
*--
::oView:oGetDias:cText( ::oModel:GetDiasdeCredito() )
::oView:oGetLimite:cText( ::oModel:GetLimitedeCredito() )
*--
::oView:oGetTelefonos:cText( ::oModel:GetTelefonos() )
*--
::oView:oGetDireccion:cText( ::oModel:GetDireccion() )
::oView:oGetEmail:cText( ::oModel:GetEmail() )
*--
::oView:oGetContacto:cText( ::oModel:GetContacto() )
*--
::oView:oGetRetiva:cText( ::oModel:GetRetencionIva() )
::oView:oGetRetislr:cText( ::oModel:GetRetencionISLR() )
*--
::oView:oGetDias:cText( ::oModel:GetDiasdecredito() )
::oView:oGetLimite:cText( ::oModel:GetLimitedecredito() )
*--
::oView:oGetActivo:SetCheck( ::oModel:GetActivo() )
*--
::oView:Refresh()
*--
IF ( ::oModel:GetId() == 0 .AND. Empty(::oView:oGetCodigo:GetText() ) )
::oView:oGetCodigo:SetFocus()
ELSE
::oView:oGetNombre:SetFocus()
ENDIF
RETURN NIL
*--
*
*--
METHOD ValidaCodigo() CLASS ProveedoresController
*--
RETURN TRUE
*--
*
*--
CLASS ProveedorDAO
*--
DATA sTablename
*--
METHOD New()
*--
METHOD Create()
METHOD Read()
METHOD Update()
METHOD Delete()
*--
METHOD Default()
METHOD FindById()
METHOD LastRecord(oController) INLINE ::Super:GetLastRecord(oController)
ENDCLASS
*--
*
*--
METHOD New() CLASS ProveedorDAO
*--
::sTableName := "proveedores"
RETURN Self
*--
*
*--
METHOD Create(oController,sCodigo) CLASS ProveedorDAO
*--
LOCAL oModel := ::Read(oController,sCodigo)
*--
IF ( Empty(oModel) )
*--
oModel := ::Default()
*--
IF ( ! Empty(sCodigo) )
oModel:SetCodigo(sCodigo)
ENDIF
*--
ENDIF
RETURN oModel
*--
*
*--
METHOD Read(oController,sCodigo) CLASS ProveedorDAO
*--
LOCAL oRs
LOCAL oError
LOCAL oModel := ""
RETURN oModel
*--
*
*--
METHOD Update(oController,oModel) CLASS ProveedorDAO
*--
LOCAL sQuery, oError
LOCAL lResult := TRUE
*--
RETURN lResult
*--
*
*--
METHOD Delete(oController,oModel) CLASS ProveedorDAO
*--
LOCAL oError
LOCAl lResult := TRUE
*--
RETURN lResult
*--
*
*--
METHOD Default() CLASS ProveedorDAO
*--
LOCAL oModel := Proveedor():New(;
0,;
Space(10),;
Space(80),;
Space(20),;
Space(20),;
Space(50),;
Space(200),;
Space(80),;
Space(80),;
0, 0, 0, 0,;
Space(25),;
TRUE,;
DateTime(),;
DateTime();
)
RETURN oModel
*--
*
*--
METHOD FindById(oController,nId) CLASS ProveedorDAO
*--
LOCAL oRs
LOCAL oError
LOCAL oModel := ""
*--
RETURN oModel
*--
*
*--
CLASS Proveedor
*--
PROTECTED:
*--
DATA id, codigo, nombre, rif, nit, telefonos, direccion, email
DATA retencioniva, retencionislr, diasdecredito, limitedecredito
DATA contacto, cuentacontable, activo, created, modified
*--
EXPORTED:
*--
METHOD New()
*--
METHOD SetId(nValue) INLINE ::id := nValue
METHOD GetId() INLINE ::id
*--
METHOD SetCodigo(sValue) INLINE ::codigo := sValue
METHOD GetCodigo() INLINE ::codigo
*--
METHOD SetNombre(sValue) INLINE ::nombre := sValue
METHOD GetNombre() INLINE ::nombre
*--
METHOD SetRif(sValue) INLINE ::rif := sValue
METHOD GetRif() INLINE ::rif
*--
METHOD SetNit(sValue) INLINE ::nit := sValue
METHOD GetNit() INLINE ::nit
*--
METHOD SetTelefonos(sValue) INLINE ::telefonos := sValue
METHOD GetTelefonos() INLINE ::telefonos
*--
METHOD SetDireccion(sValue) INLINE ::direccion := sValue
METHOD GetDireccion() INLINE ::direccion
*--
METHOD SetEmail(sValue) INLINE ::email := sValue
METHOD GetEmail() INLINE ::email
*--
METHOD SetContacto(sValue) INLINE ::contacto := sValue
METHOD GetContacto() INLINE ::contacto
*--
METHOD SetRetencionIva(nValue) INLINE ::retencioniva := nValue
METHOD GetRetencionIva() INLINE ::retencioniva
*--
METHOD SetRetencionISLR(nValue) INLINE ::retencionislr := nValue
METHOD GetRetencionISLR() INLINE ::retencionislr
*--
METHOD SetDiasdecredito(nValue) INLINE ::diasdecredito := nValue
METHOD GetDiasdecredito() INLINE ::diasdecredito
*--
METHOD SetLimitedecredito(nValue) INLINE ::limitedecredito := nValue
METHOD GetLimitedecredito() INLINE ::limitedecredito
*--
METHOD SetCuentaContable(sValue) INLINE ::cuentacontable := sValue
METHOD GetCuentaContable() INLINE ::cuentacontable
*--
METHOD SetActivo(lValue) INLINE ::activo := lValue
METHOD GetActivo() INLINE ::activo
*--
METHOD SetCreated(dValue) INLINE ::created := dValue
METHOD GetCreated() INLINE ::created
*--
METHOD SetModified(dValue) INLINE ::modified := dValue
METHOD GetModified() INLINE ::modified
*--
ENDCLASS
*--
*
*--
METHOD New(nId, sCodigo, sNombre,sRif, sNit, sTelefonos, sDireccion, sEmail,;
sContacto, nRetencionIva, nRetencionIslr, nDias, nLimite, sCuentaContable,;
lActivo,dCreated,dModified) CLASS Proveedor
*--
::id := IIF( HB_IsNIL(nId), 0, nId )
*--
::codigo := IIF( HB_IsNIL(sCodigo), Space(10), sCodigo )
::nombre := IIF( HB_IsNIL(sNombre), Space(80), sNombre )
*--
::rif := IIF( HB_IsNIL(sRif), Space(20), sRif )
::nit := IIF( HB_IsNIL(sNit), Space(20), sNit )
*--
::telefonos := IIF( HB_IsNIL(sTelefonos), Space(40), sTelefonos )
::direccion := IIF( HB_IsNIL(sDireccion), Space(200), sDireccion )
::email := IIF( HB_IsNIL(sEmail), Space(80), sEmail )
::contacto := IIF( HB_IsNIL(sContacto), Space(80), sContacto )
*--
::retencioniva := IIF( HB_IsNIL(nRetencionIva), 0, nRetencionIva )
::retencionislr := IIF( HB_IsNIL(nRetencionIslr), 0, nRetencionIslr )
*--
::diasdecredito := IIF( HB_IsNIL(nDias), 0, nDias )
::limitedecredito := IIF( HB_IsNIL(nLimite), 0, nLimite )
*--
::cuentacontable := IIF( HB_IsNIL(sCuentaContable), Space(25), sCuentaContable )
::activo := IIF( HB_IsNIL(lActivo), FALSE, lActivo )
*--
::created := IIF( HB_IsNIL(dCreated), DateTime(), dCreated )
::modified := IIF( HB_IsNIL(dModified), DateTime(), dModified )
RETURN Self
*--
*
CLASS ProveedorView
*--
PROTECTED:
*--
DATA oCtrl, oParent
DATA oTitle, oGroup
*--
DATA sCodigo, sNombre, sRif, sNit, sTelefonos, sDireccion, sEmail
DATA sContacto, nRetencionIva, nRetencionIslr, nDias, nLimite
DATA sCuentaContable, lActivo
*--
DATA aButtons
*--
EXPORTED:
*--
DATA oDlg, oMsgBar
DATA oGetCodigo, oGetNombre, oGetRif, oGetNit, oGetTelefonos
DATA oGetDireccion, oGetEmail, oGetContacto, oGetActivo
DATA oGetRetiva, oGetRetislr, oGetDias, oGetLimite, oGetCuentaContable
*--
METHOD New()
METHOD Show()
*--
METHOD SetController(oCtrl) INLINE ::oCtrl := oCtrl, ::oParent := oCtrl:oParent
METHOD GetController() INLINE ::oCtrl
*--
METHOD SetTitle(sTitle) INLINE ::oDlg:cTitle( sTitle )
METHOD Refresh() INLINE ::oDlg:Update()
ENDCLASS
*--
*
*--
METHOD New() CLASS ProveedorView
*--
::sCodigo := Space(10)
::sNombre := Space(80)
::sRif := Space(20)
::sNit := Space(20)
*--
::sTelefonos := Space(50)
::sDireccion := Space(200)
*--
::nDias := 0
::nLimite := 0
*--
::nRetencionIva := 0
::nRetencionIslr := 0
*--
::sEmail := Space(80)
*--
::sContacto := Space(80)
::aButtons := Array(4)
*--
::sCuentaContable := Space(25)
::lActivo := TRUE
RETURN Self
*--
*
*--
METHOD Show() CLASS ProveedorView
*--
LOCAL nSay
LOCAl sFileBmp := "c:\Fwh\bitmaps\32x32\fivetech.bmp"
*--
DEFINE DIALOG ::oDlg RESOURCE "D4100" ;
TITLE FWVERSION RESIZABLE ;
FONT ::oParent:GetFontApp() ;
ICON ::oParent:GetIconSys() OF ::oParent:oWndMain
*--
FOR nSay = 50 TO 64
REDEFINE SAY ID nSay OF ::oDlg TRANSPARENT
NEXT
*--
REDEFINE TITLE ::oTitle ID 101 OF ::oDlg
::oTitle:nShadow := 0
*--
@ 12,30 TITLETEXT OF ::oTitle TEXT "DATOS DE PROVEEDORES" FONT ::oParent:GetFontTit()
*--
REDEFINE SAY ID 200 OF ::oDlg FONT ::oParent:GetFontApp() TRANSPARENT
*--
REDEFINE GET ::oGetCodigo VAR ::sCodigo ID 201 OF ::oDlg PICTURE "@!,10" UPDATE
*--
::oGetCodigo:bValid := {|| ::oCtrl:ValidaCodigo() }
::oGetCodigo:bAction := {|| ::oCtrl:Find(), IIF( Empty( ::oGetCodigo:GetText() ), ::oGetCodigo:SetFocus(), SendKey( VK_TAB ) ) }
::oGetCodigo:bKeyDown := {|nKey| IIF( nKey == VK_F2, ::oGetCodigo:oBtn:Click(), ) }
*--
REDEFINE GET ::oGetNombre VAR ::sNombre ID 202 OF ::oDlg PICTURE "@!,80" UPDATE
*--
REDEFINE GET ::oGetRif VAR ::sRif ID 203 OF ::oDlg PICTURE "@!,20" UPDATE
REDEFINE GET ::oGetNit VAR ::sNit ID 204 OF ::oDlg PICTURE "@!,20" UPDATE
*--
REDEFINE GET ::oGetTelefonos VAR ::sTelefonos ID 205 OF ::oDlg PICTURE "@X,50" UPDATE
*--
REDEFINE GET ::oGetDireccion VAR ::sDireccion ID 206 OF ::oDlg MEMO UPDATE
*--
::oGetDireccion:LimitText( 200 )
*--
REDEFINE GET ::oGetEmail VAR ::sEmail ID 207 OF ::oDlg PICTURE "@X,80" UPDATE
*--
REDEFINE GET ::oGetContacto VAR ::sContacto ID 208 OF ::oDlg PICTURE "@!,80" UPDATE
*--
REDEFINE GET ::oGetRetiva VAR ::nRetencionIva ID 209 OF ::oDlg PICTURE "999.99"
REDEFINE GET ::oGetRetislr VAR ::nRetencionIslr ID 210 OF ::oDlg PICTURE "999.99"
*--
REDEFINE GET ::oGetDias VAR ::nDias ID 211 OF ::oDlg PICTURE "99" UPDATE
REDEFINE GET ::oGetLimite VAR ::nLimite ID 212 OF ::oDlg PICTURE "999999999.99" UPDATE
*--
REDEFINE GET ::oGetCuentaContable VAR ::sCuentaContable ID 213 OF ::oDlg PICTURE "@!,25" UPDATE
*--
REDEFINE CHECKBOX ::oGetActivo VAR ::lActivo ID 214 OF ::oDlg;
ON CHANGE IIF( ::oGetActivo:lChecked(),;
::oGetActivo:SetText( "Activo" ),::oGetActivo:SetText( "Inactivo" ) )
*--
REDEFINE BUTTON ::aButtons[ 1 ] ID 301 OF ::oDlg ACTION ::oCtrl:Save() CANCEL
*--
REDEFINE BUTTON ::aButtons[ 2 ] ID 302 OF ::oDlg ACTION ::oDlg:End() CANCEL
*--
REDEFINE BUTTON ::aButtons[ 3 ] ID 303 OF ::oDlg ACTION ::oCtrl:Init() CANCEL
*--
REDEFINE BUTTON ::aButtons[ 4 ] ID 304 OF ::oDlg ACTION ::oCtrl:Delete() ;
WHEN ::oCtrl:GetModel():GetId() > 0
*--
WITH OBJECT ::oDlg
:bStart := {|| ShowImageTitle(::oTitle,sFileBmp) }
:bInit := {|| StatusBar(::oDlg), SetResize( ::oDlg ) }
:bResized := {|| ResizeCtrls( ::oDlg ) }
*--
:lHelpIcon := FALSE
END
*--
ACTIVATE DIALOG ::oDlg CENTER NOMODAL
RETURN NIL
*--
*
*--
PROCEDURE ShowImageTitle(oTitle, sImage)
*--
LOCAL nPos := oTitle:nWidth - 60
*--
IF ( ! Empty( sImage) )
@ 05,nPos TITLEIMG OF oTitle RESNAME sImage SIZE 32,32 REFLEX
oTitle:nShadowIntensity = 70
ENDIF
*--
oTitle:Refresh()
RETURN
*--
*
*--
PROCEDURE StatusBar( oDlg )
*--
LOCAL oMsgBar
*--
DEFINE MSGBAR oMsgBar OF oDlg PROMPT FWDESCRIPTION 2015 FONT oApp:GetFontApp()
*--
oMsgBar:ClockOn()
oMsgBar:lPaint3L := FALSE
RETURN
*--
*
*--
PROCEDURE SetResize( oDlg )
*--
LOCAL oCtrl
*--
oDlg:Cargo := { oDlg:nWidth, oDlg:nHeight, oDlg:oFont:nInpHeight }
*--
FOR EACH oCtrl IN oDlg:aControls
WITH OBJECT oCtrl
:Cargo := { :nTop, :nLeft, :nWidth, :nHeight, :oFont:nInpHeight }
END
NEXT
RETURN
*--
*
*--
PROCEDURE ResizeCtrls( oDlg )
*--
LOCAL xRatio, yRatio
LOCAL oCtrl, h, f
*--
xRatio := oDlg:nWidth / oDlg:Cargo[ 1 ]
yRatio := oDlg:nHeight / oDlg:Cargo[ 2 ]
*--
FOR EACH oCtrl IN oDlg:aControls
WITH OBJECT oCtrl
:nTop := Int( yRatio * :Cargo[ 1 ] )
:nHeight := Int( yRatio * :Cargo[ 4 ] )
:nLeft := Int( xRatio * :Cargo[ 2 ] )
:nWidth := Int( xRatio * :Cargo[ 3 ] )
h := Int( :Cargo[ 5 ] * yRatio )
IF h != :oFont:nInpHeight
:SetFont( f := :oFont:Modify( h ) )
f:End()
ENDIF
END
NEXT
RETURN
*--
*
D4100 DIALOG DISCARDABLE 6, 18, 502, 212
STYLE WS_POPUP|DS_MODALFRAME|DS_3DLOOK|WS_THICKFRAME|WS_CAPTION|WS_SYSMENU|WS_VISIBLE
CAPTION "Proveedores"
FONT 10, "Tahoma"
{
CONTROL "", 201, "Edit", ES_NUMBER|ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 60, 32, 88, 12
CONTROL "", 202, "Edit", ES_AUTOHSCROLL|ES_UPPERCASE|WS_BORDER|WS_TABSTOP, 60, 52, 260, 12
CONTROL "", 203, "Edit", ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 60, 68, 88, 12
CONTROL "", 204, "Edit", ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 232, 68, 88, 12
CONTROL "", 205, "Edit", ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 60, 84, 260, 12
CONTROL "", 206, "Edit", ES_MULTILINE|ES_WANTRETURN|WS_VSCROLL|WS_BORDER|WS_TABSTOP, 60, 100, 260, 24
CONTROL "", 207, "Edit", ES_AUTOHSCROLL|ES_LOWERCASE|WS_BORDER|WS_TABSTOP, 60, 128, 260, 12
CONTROL "", 208, "Edit", ES_AUTOHSCROLL|ES_UPPERCASE|WS_BORDER|WS_TABSTOP, 60, 144, 260, 12
CONTROL "", 209, "Edit", ES_RIGHT|ES_NUMBER|ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 404, 52, 78, 12
CONTROL "", 210, "Edit", ES_RIGHT|ES_NUMBER|ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 404, 68, 78, 12
CONTROL "", 211, "Edit", ES_RIGHT|ES_NUMBER|ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 404, 84, 78, 12
CONTROL "", 212, "Edit", ES_RIGHT|ES_NUMBER|ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 404, 100, 78, 12
CONTROL "", 213, "Edit", ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 404, 116, 78, 12
CONTROL "Activo", 214, "Button", BS_AUTOCHECKBOX|WS_TABSTOP, 420, 32, 38, 10
CONTROL "&Grabar", 301, "Button", WS_TABSTOP, 364, 176, 58, 16
CONTROL "&Salir", 302, "Button", WS_TABSTOP, 424, 176, 58, 16
CONTROL "&Nuevo", 303, "Button", WS_TABSTOP, 20, 176, 54, 16
CONTROL "&Eliminar", 304, "Button", WS_TABSTOP, 76, 176, 54, 16
CONTROL "-", 50, "Static", SS_SUNKEN|WS_GROUP, 14, 164, 474, 1
CONTROL "Código:", 51, "Static", SS_CENTERIMAGE|WS_GROUP, 16, 32, 40, 10
CONTROL "-", 52, "Static", SS_SUNKEN|WS_GROUP, 14, 48, 474, 1
CONTROL "Nombre:", 53, "Static", SS_CENTERIMAGE|WS_GROUP, 16, 52, 40, 10
CONTROL "No R.I.F.:", 54, "Static", SS_CENTERIMAGE|WS_GROUP, 16, 68, 40, 10
CONTROL "No NIT.:", 55, "Static", SS_CENTER|SS_CENTERIMAGE|WS_GROUP, 188, 68, 40, 10
CONTROL "% Retencón I.V.A.", 60, "Static", SS_CENTERIMAGE|WS_GROUP, 332, 52, 68, 10
CONTROL "% Retencón I.S.L.R.", 61, "Static", SS_CENTERIMAGE|WS_GROUP, 332, 68, 68, 10
CONTROL "Días de Crédito:", 62, "Static", WS_GROUP, 332, 84, 68, 8
CONTROL "Limite de Crédito:", 63, "Static", SS_CENTERIMAGE|WS_GROUP, 332, 100, 68, 10
CONTROL "Teléfonos:", 56, "Static", SS_CENTERIMAGE|WS_GROUP, 16, 84, 40, 10
CONTROL "Dirección\r\nFíscal", 57, "Static", WS_GROUP, 16, 100, 40, 20
CONTROL "E-Mail:", 58, "Static", SS_CENTERIMAGE|WS_GROUP, 16, 128, 40, 10
CONTROL "Contacto:", 59, "Static", SS_CENTERIMAGE|WS_GROUP, 16, 144, 40, 10
CONTROL "TTitle", 101, "TTitle", 0x00000000, 0, 0, 502, 20
CONTROL "Ingresa el código o pulsa F2 para buscar...", 200, "Static", SS_CENTERIMAGE|WS_GROUP, 168, 32, 160, 10
CONTROL "Cuenta Contable:", 64, "Static", SS_CENTERIMAGE|WS_GROUP, 332, 116, 68, 10
}
